qcsrc/common/weapons/weapons.qc

   1 #ifndef MENUQC
   2 #include "calculations.qc"
   3 #endif
   4 #include "all.qh"
   5
   6 // WEAPON PLUGIN SYSTEM
   7 entity weapon_info[WEP_MAXCOUNT];
   8 entity dummy_weapon_info;
   9
  10 void register_weapon(float id, float(float) func, float ammotype, float i, float weapontype, float pickupbasevalue, string modelname, string shortname, string wname)
  11 {
  12         entity e;
  13         weapon_info[id - 1] = e = spawn();
  14         e.classname = "weapon_info";
  15         e.weapon = id;
  16         WEPSET_COPY_EW(e, id);
  17         e.netname = shortname;
  18         e.message = wname;
  19         e.items = ammotype;
  20         e.weapon_func = func;
  21         e.mdl = modelname;
  22         e.model = strzone(strcat("models/weapons/g_", modelname, ".md3"));
  23         e.spawnflags = weapontype;
  24         e.model2 = strzone(strcat("wpn-", e.mdl));
  25         e.impulse = i;
  26         e.bot_pickupbasevalue = pickupbasevalue;
  27         if(ammotype & IT_SHELLS)
  28                 e.ammo_field = ammo_shells;
  29         else if(ammotype & IT_NAILS)
  30                 e.ammo_field = ammo_nails;
  31         else if(ammotype & IT_ROCKETS)
  32                 e.ammo_field = ammo_rockets;
  33         else if(ammotype & IT_CELLS)
  34                 e.ammo_field = ammo_cells;
  35         else if(ammotype & IT_FUEL)
  36                 e.ammo_field = ammo_fuel;
  37         else
  38                 e.ammo_field = ammo_batteries;
  39
  40         #ifndef MENUQC
  41         func(WR_INIT);
  42         #endif
  43 }
  44 float w_null(float dummy)
  45 {
  46         return 0;
  47 }
  48 void register_weapons_done()
  49 {
  50         dummy_weapon_info = spawn();
  51         dummy_weapon_info.classname = "weapon_info";
  52         dummy_weapon_info.weapon = 0; // you can recognize dummies by this
  53         WEPSET_CLEAR_E(dummy_weapon_info);
  54         dummy_weapon_info.netname = "";
  55         dummy_weapon_info.message = "AOL CD Thrower";
  56         dummy_weapon_info.items = 0;
  57         dummy_weapon_info.weapon_func = w_null;
  58         dummy_weapon_info.mdl = "";
  59         dummy_weapon_info.model = "";
  60         dummy_weapon_info.spawnflags = 0;
  61         dummy_weapon_info.model2 = "";
  62         dummy_weapon_info.impulse = -1;
  63         dummy_weapon_info.bot_pickupbasevalue = 0;
  64
  65         float i;
  66         weaponorder_byid = "";
  67         for(i = WEP_MAXCOUNT; i >= 1; --i)
  68                 if(weapon_info[i-1])
  69                         weaponorder_byid = strcat(weaponorder_byid, " ", ftos(i));
  70         weaponorder_byid = strzone(substring(weaponorder_byid, 1, strlen(weaponorder_byid) - 1));
  71 }
  72 entity get_weaponinfo(float id)
  73 {
  74         entity w;
  75         if(id < WEP_FIRST || id > WEP_LAST)
  76                 return dummy_weapon_info;
  77         w = weapon_info[id - 1];
  78         if(w)
  79                 return w;
  80         return dummy_weapon_info;
  81 }
  82 string W_FixWeaponOrder(string order, float complete)
  83 {
  84         return fixPriorityList(order, WEP_FIRST, WEP_LAST, 230 - WEP_FIRST, complete);
  85 }
  86 string W_NameWeaponOrder_MapFunc(string s)
  87 {
  88         entity wi;
  89         if(s == "0" || stof(s))
  90         {
  91                 wi = get_weaponinfo(stof(s));
  92                 if(wi != dummy_weapon_info)
  93                         return wi.netname;
  94         }
  95         return s;
  96 }
  97 string W_NameWeaponOrder(string order)
  98 {
  99         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 100 }
 101 string W_NumberWeaponOrder_MapFunc(string s)
 102 {
 103         float i;
 104         if(s == "0" || stof(s))
 105                 return s;
 106         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 107                 if(s == get_weaponinfo(i).netname)
 108                         return ftos(i);
 109         return s;
 110 }
 111 string W_NumberWeaponOrder(string order)
 112 {
 113         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 114 }
 115
 116 float W_FixWeaponOrder_BuildImpulseList_buf[WEP_MAXCOUNT];
 117 string W_FixWeaponOrder_BuildImpulseList_order;
 118 void W_FixWeaponOrder_BuildImpulseList_swap(float i, float j, entity pass)
 119 {
 120         float h;
 121         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 122         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 123         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 124 }
 125 float W_FixWeaponOrder_BuildImpulseList_cmp(float i, float j, entity pass)
 126 {
 127         entity e1, e2;
 128         float d;
 129         e1 = get_weaponinfo(W_FixWeaponOrder_BuildImpulseList_buf[i]);
 130         e2 = get_weaponinfo(W_FixWeaponOrder_BuildImpulseList_buf[j]);
 131         d = mod(e1.impulse + 9, 10) - mod(e2.impulse + 9, 10);
 132         if(d != 0)
 133                 return -d; // high impulse first!
 134         return
 135                 strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "), sprintf(" %d ", W_FixWeaponOrder_BuildImpulseList_buf[i]), 0)
 136                 -
 137                 strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "), sprintf(" %d ", W_FixWeaponOrder_BuildImpulseList_buf[j]), 0)
 138                 ; // low char index first!
 139 }
 140 string W_FixWeaponOrder_BuildImpulseList(string o)
 141 {
 142         float i;
 143         W_FixWeaponOrder_BuildImpulseList_order = o;
 144         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 145                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 146         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp, world);
 147         o = "";
 148         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 149                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 150         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 151         return substring(o, 1, -1);
 152 }
 153
 154 string W_FixWeaponOrder_AllowIncomplete(string order)
 155 {
 156         return W_FixWeaponOrder(order, 0);
 157 }
 158
 159 string W_FixWeaponOrder_ForceComplete(string order)
 160 {
 161         if(order == "")
 162                 order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 163         return W_FixWeaponOrder(order, 1);
 164 }
 165
 166 void W_RandomWeapons(entity e, float n)
 167 {
 168         float i, j;
 169         WEPSET_DECLARE_A(remaining);
 170         WEPSET_DECLARE_A(result);
 171         WEPSET_COPY_AE(remaining, e);
 172         WEPSET_CLEAR_A(result);
 173         for(i = 0; i < n; ++i)
 174         {
 175                 RandomSelection_Init();
 176                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 177                         if(WEPSET_CONTAINS_AW(remaining, j))
 178                                 RandomSelection_Add(world, j, string_null, 1, 1);
 179                 WEPSET_OR_AW(result, RandomSelection_chosen_float);
 180                 WEPSET_ANDNOT_AW(remaining, RandomSelection_chosen_float);
 181         }
 182         WEPSET_COPY_EA(e, result);
 183 }
 184
 185 string W_Name(float weaponid)
 186 {
 187         return (get_weaponinfo(weaponid)).message;
 188 }
 189
 190 float W_AmmoItemCode(float wpn)
 191 {
 192         return (get_weaponinfo(wpn)).items & IT_AMMO;
 193 }