qcsrc/csqcmodellib/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22 #if defined(CSQC)
  23         #include "../dpdefs/csprogsdefs.qh"
  24         #include "../client/defs.qh"
  25         #include "../common/constants.qh"
  26         #include "../common/stats.qh"
  27         #include "../common/util.qh"
  28         #include "interpolate.qh"
  29         #include "../client/main.qh"
  30         #include "common.qh"
  31         #include "cl_model.qh"
  32         #include "cl_player.qh"
  33 #elif defined(MENUQC)
  34 #elif defined(SVQC)
  35 #endif
  36
  37 float autocvar_cl_movement_errorcompensation = 0;
  38 int autocvar_cl_movement = 1;
  39
  40 // engine stuff
  41 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  42
  43 vector csqcplayer_origin, csqcplayer_velocity;
  44 float csqcplayer_sequence;
  45 int player_pmflags;
  46 float csqcplayer_moveframe;
  47 vector csqcplayer_predictionerroro;
  48 vector csqcplayer_predictionerrorv;
  49 float csqcplayer_predictionerrortime;
  50 float csqcplayer_predictionerrorfactor;
  51
  52 vector CSQCPlayer_GetPredictionErrorO()
  53 {
  54         if(time >= csqcplayer_predictionerrortime)
  55                 return '0 0 0';
  56         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  57 }
  58
  59 vector CSQCPlayer_GetPredictionErrorV()
  60 {
  61         if(time >= csqcplayer_predictionerrortime)
  62                 return '0 0 0';
  63         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  64 }
  65
  66 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
  67 {
  68         // error too big to compensate, we LIKELY hit a teleport or a
  69         // jumppad, or it's a jump time disagreement that'll get fixed
  70         // next frame
  71
  72         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
  73         /*
  74         // commented out as this one did not help
  75         if(onground_diff)
  76         {
  77                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
  78                 return;
  79         }
  80         */
  81         if(vlen(o) > 32 || vlen(v) > 192)
  82         {
  83                 //printf("TOO BIG: x=%v v=%v\n", o, v);
  84                 return;
  85         }
  86
  87         if(!autocvar_cl_movement_errorcompensation)
  88         {
  89                 csqcplayer_predictionerrorfactor = 0;
  90                 return;
  91         }
  92
  93         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
  94         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
  95         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ticrate;
  96         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
  97 }
  98
  99 void CSQCPlayer_Unpredict()
 100 {
 101         if(csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED)
 102                 return;
 103         if(csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED)
 104                 error("Cannot unpredict in current status");
 105         self.origin = csqcplayer_origin;
 106         self.velocity = csqcplayer_velocity;
 107         csqcplayer_moveframe = csqcplayer_sequence+1; //+1 because the recieved frame has the move already done (server side)
 108         self.flags = player_pmflags;
 109 }
 110
 111 void CSQCPlayer_SetMinsMaxs()
 112 {
 113         if(self.flags & FL_DUCKED)
 114         {
 115                 self.mins = PL_CROUCH_MIN;
 116                 self.maxs = PL_CROUCH_MAX;
 117                 self.view_ofs = PL_CROUCH_VIEW_OFS;
 118         }
 119         else
 120         {
 121                 self.mins = PL_MIN;
 122                 self.maxs = PL_MAX;
 123                 self.view_ofs = PL_VIEW_OFS;
 124         }
 125 }
 126
 127 void CSQCPlayer_SavePrediction()
 128 {
 129         player_pmflags = self.flags;
 130         csqcplayer_origin = self.origin;
 131         csqcplayer_velocity = self.velocity;
 132         csqcplayer_sequence = servercommandframe;
 133         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 134 }
 135
 136 void CSQC_ClientMovement_PlayerMove_Frame();
 137
 138 void PM_Movement_Move()
 139 {
 140         runstandardplayerphysics(self);
 141 #ifdef CSQC
 142         self.flags =
 143                         ((self.pmove_flags & PMF_DUCKED) ? FL_DUCKED : 0) |
 144                         (!(self.pmove_flags & PMF_JUMP_HELD) ? FL_JUMPRELEASED : 0) |
 145                         ((self.pmove_flags & PMF_ONGROUND) ? FL_ONGROUND : 0);
 146 #endif
 147 }
 148
 149 void CSQCPlayer_Physics(void)
 150 {
 151         switch(autocvar_cl_movement)
 152         {
 153                 case 1: CSQC_ClientMovement_PlayerMove_Frame(); break;
 154                 case 2: PM_Movement_Move(); break;
 155         }
 156 }
 157
 158 void CSQCPlayer_PredictTo(float endframe, float apply_error)
 159 {
 160         CSQCPlayer_Unpredict();
 161         if(apply_error)
 162         {
 163                 self.origin += CSQCPlayer_GetPredictionErrorO();
 164                 self.velocity += CSQCPlayer_GetPredictionErrorV();
 165         }
 166         CSQCPlayer_SetMinsMaxs();
 167
 168         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 169
 170 #if 0
 171         // we don't need this
 172         // darkplaces makes servercommandframe == 0 in these cases anyway
 173         if (getstatf(STAT_HEALTH) <= 0)
 174         {
 175                 csqcplayer_moveframe = clientcommandframe;
 176                 getinputstate(csqcplayer_moveframe-1);
 177                 print("the Weird code path got hit\n");
 178                 return;
 179         }
 180 #endif
 181
 182         if(csqcplayer_moveframe >= endframe)
 183         {
 184                 getinputstate(csqcplayer_moveframe - 1);
 185         }
 186         else
 187         {
 188                 do
 189                 {
 190                         if (!getinputstate(csqcplayer_moveframe))
 191                                 break;
 192                         CSQCPlayer_Physics();
 193                         CSQCPlayer_SetMinsMaxs();
 194                         csqcplayer_moveframe++;
 195                 }
 196                 while(csqcplayer_moveframe < endframe);
 197         }
 198
 199         //add in anything that was applied after (for low packet rate protocols)
 200         input_angles = view_angles;
 201 }
 202
 203 bool CSQCPlayer_IsLocalPlayer()
 204 {
 205         return (self == csqcplayer);
 206 }
 207
 208 void CSQCPlayer_SetCamera()
 209 {
 210         vector v0;
 211         v0 = pmove_vel; // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 212
 213         if(csqcplayer)
 214         {
 215                 entity oldself;
 216                 oldself = self;
 217                 self = csqcplayer;
 218
 219                 if(servercommandframe == 0 || clientcommandframe == 0)
 220                 {
 221                         InterpolateOrigin_Do();
 222                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 223
 224                         // get crouch state from the server
 225                         if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS.z)
 226                                 self.flags &= ~FL_DUCKED;
 227                         else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS.z)
 228                                 self.flags |= FL_DUCKED;
 229
 230                         // get onground state from the server
 231                         if(pmove_onground)
 232                                 self.flags |= FL_ONGROUND;
 233                         else
 234                                 self.flags &= ~FL_ONGROUND;
 235
 236                         CSQCPlayer_SetMinsMaxs();
 237
 238                         // override it back just in case
 239                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 240
 241                         // set velocity
 242                         self.velocity = v0;
 243                 }
 244                 else
 245                 {
 246                         float flg = self.iflags;
 247                         self.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
 248                         InterpolateOrigin_Do();
 249                         self.iflags = flg;
 250
 251                         if(csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 252                         {
 253                                 vector o, v;
 254                                 o = self.origin;
 255                                 v = v0;
 256                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 257                                 CSQCPlayer_PredictTo(servercommandframe + 1, false);
 258                                 CSQCPlayer_SetPredictionError(self.origin - o, self.velocity - v, pmove_onground - !!(self.flags & FL_ONGROUND));
 259                                 self.origin = o;
 260                                 self.velocity = v;
 261
 262                                 // get crouch state from the server
 263                                 if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS.z)
 264                                         self.flags &= ~FL_DUCKED;
 265                                 else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS.z)
 266                                         self.flags |= FL_DUCKED;
 267
 268                                 // get onground state from the server
 269                                 if(pmove_onground)
 270                                         self.flags |= FL_ONGROUND;
 271                                 else
 272                                         self.flags &= ~FL_ONGROUND;
 273
 274                                 CSQCPlayer_SavePrediction();
 275                         }
 276                         CSQCPlayer_PredictTo(clientcommandframe + 1, true);
 277
 278 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
 279                         // get crouch state from the server (LAG)
 280                         if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS.z)
 281                                 self.flags &= ~FL_DUCKED;
 282                         else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS.z)
 283                                 self.flags |= FL_DUCKED;
 284 #endif
 285
 286                         CSQCPlayer_SetMinsMaxs();
 287
 288                         self.angles_y = input_angles.y;
 289                 }
 290
 291                 // relink
 292                 setorigin(self, self.origin);
 293
 294                 self = oldself;
 295         }
 296
 297         entity view;
 298         view = CSQCModel_server2csqc(player_localentnum);
 299
 300         if(view && view != csqcplayer)
 301         {
 302                 entity oldself = self;
 303                 self = view;
 304                 InterpolateOrigin_Do();
 305                 self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 306                 self = oldself;
 307         }
 308
 309         if(view)
 310         {
 311                 int refdefflags = 0;
 312
 313                 if(view.csqcmodel_teleported)
 314                         refdefflags |= REFDEFFLAG_TELEPORTED;
 315
 316                 if(input_buttons & 4)
 317                         refdefflags |= REFDEFFLAG_JUMPING;
 318
 319                 // note: these two only work in WIP2, but are harmless in WIP1
 320                 if(getstati(STAT_HEALTH) <= 0)
 321                         refdefflags |= REFDEFFLAG_DEAD;
 322
 323                 if(intermission)
 324                         refdefflags |= REFDEFFLAG_INTERMISSION;
 325
 326                 V_CalcRefdef(view, refdefflags);
 327         }
 328         else
 329         {
 330                 // FIXME by CSQC spec we have to do this:
 331                 // but it breaks chase cam
 332                 /*
 333                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT));
 334                 setproperty(VF_ANGLES, view_angles);
 335                 */
 336         }
 337
 338         { CSQCPLAYER_HOOK_POSTCAMERASETUP }
 339 }
 340
 341 void CSQCPlayer_Remove()
 342 {
 343         csqcplayer = world;
 344         cvar_settemp("cl_movement_replay", "1");
 345 }
 346
 347 float CSQCPlayer_PreUpdate()
 348 {
 349         if(self != csqcplayer)
 350                 return 0;
 351         if(csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER)
 352                 CSQCPlayer_Unpredict();
 353         return 1;
 354 }
 355
 356 float CSQCPlayer_PostUpdate()
 357 {
 358         if(self.entnum != player_localnum + 1)
 359                 return 0;
 360         csqcplayer = self;
 361         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 362         cvar_settemp("cl_movement_replay", "0");
 363         self.entremove = CSQCPlayer_Remove;
 364         return 1;
 365 }