Merge remote-tracking branch 'origin/divVerent/allow-override-item-model'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / csqcmodellib / cl_player.qc
1 /*
2  * Copyright (c) 2011 Rudolf Polzer
3  *
4  * Permission is hereby granted, free of charge, to any person obtaining a copy
5  * of this software and associated documentation files (the "Software"), to
6  * deal in the Software without restriction, including without limitation the
7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
8  * sell copies of the Software, and to permit persons to whom the Software is
9  * furnished to do so, subject to the following conditions:
10  *
11  * The above copyright notice and this permission notice shall be included in
12  * all copies or substantial portions of the Software.
13  *
14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
20  * IN THE SOFTWARE.
21  */
22
23 var float autocvar_cl_predictionerrorcompensation = 0;
24
25 // engine stuff
26 .float pmove_flags;
27 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
28 #define PMF_JUMP_HELD 1
29 #define PMF_DUCKED 4
30 #define PMF_ONGROUND 8
31 #define REFDEFFLAG_TELEPORTED 1
32 #define REFDEFFLAG_JUMPING 2
33
34 entity csqcplayer;
35 vector csqcplayer_origin, csqcplayer_velocity;
36 float csqcplayer_sequence, player_pmflags;
37 float csqcplayer_moveframe;
38 vector csqcplayer_predictionerror;
39 float csqcplayer_predictionerrortime;
40
41 vector CSQCPlayer_GetPredictionError()
42 {
43         if(!autocvar_cl_predictionerrorcompensation)
44                 return '0 0 0';
45         if(time < csqcplayer_predictionerrortime)
46                 return csqcplayer_predictionerror * (csqcplayer_predictionerrortime - time) * autocvar_cl_predictionerrorcompensation;
47         return '0 0 0';
48 }
49
50 void CSQCPlayer_SetPredictionError(vector v)
51 {
52         if(!autocvar_cl_predictionerrorcompensation)
53                 return;
54         csqcplayer_predictionerror = (csqcplayer_predictionerrortime - time) * autocvar_cl_predictionerrorcompensation * csqcplayer_predictionerror + v;
55         csqcplayer_predictionerrortime = time + 1.0 / autocvar_cl_predictionerrorcompensation;
56 }
57
58 void CSQCPlayer_Unpredict()
59 {
60         if(csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED)
61                 return;
62         if(csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED)
63                 error("Cannot unpredict in current status");
64         self.origin = csqcplayer_origin;
65         self.velocity = csqcplayer_velocity;
66         csqcplayer_moveframe = csqcplayer_sequence+1; //+1 because the recieved frame has the move already done (server side)
67         self.pmove_flags = player_pmflags;
68 }
69
70 void CSQCPlayer_SetMinsMaxs()
71 {
72         if(self.pmove_flags & PMF_DUCKED)
73         {
74                 self.mins = PL_CROUCH_MIN;
75                 self.maxs = PL_CROUCH_MAX;
76                 self.view_ofs = PL_CROUCH_VIEW_OFS;
77         }
78         else
79         {
80                 self.mins = PL_MIN;
81                 self.maxs = PL_MAX;
82                 self.view_ofs = PL_VIEW_OFS;
83         }
84 }
85
86 void CSQCPlayer_SavePrediction()
87 {
88         player_pmflags = self.pmove_flags;
89         csqcplayer_origin = self.origin;
90         csqcplayer_velocity = self.velocity;
91         csqcplayer_sequence = servercommandframe;
92         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
93 }
94
95 void CSQCPlayer_PredictTo(float endframe)
96 {
97         CSQCPlayer_Unpredict();
98         CSQCPlayer_SetMinsMaxs();
99
100         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
101
102         // FIXME do we really NEED this? dead players have servercommandframe
103         // == 0 and thus won't predict
104         if (getstatf(STAT_HEALTH) <= 0)
105         {
106                 csqcplayer_moveframe = clientcommandframe;
107                 getinputstate(csqcplayer_moveframe-1);
108                 print("the Weird code path got hit\n");
109                 return;
110         }
111
112         if(csqcplayer_moveframe >= endframe)
113         {
114                 getinputstate(csqcplayer_moveframe - 1);
115         }
116         else
117         {
118                 do
119                 {
120                         if (!getinputstate(csqcplayer_moveframe))
121                                 break;
122                         runstandardplayerphysics(self);
123                         CSQCPlayer_SetMinsMaxs();
124                         csqcplayer_moveframe++;
125                 }
126                 while(csqcplayer_moveframe < endframe);
127         }
128
129         //add in anything that was applied after (for low packet rate protocols)
130         input_angles = view_angles;
131 }
132
133 float CSQCPlayer_IsLocalPlayer()
134 {
135         return (self == csqcplayer);
136 }
137
138 void(entity e, float fl) V_CalcRefdef = #640; // DP_CSQC_V_CALCREFDEF
139
140 void CSQCPlayer_SetCamera()
141 {
142         vector v0;
143         v0 = pmove_vel; // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
144
145         if(csqcplayer)
146         {
147                 entity oldself;
148                 oldself = self;
149                 self = csqcplayer;
150
151 #ifdef COMPAT_XON050_ENGINE
152                 if(servercommandframe == 0 || clientcommandframe == 0 || !(checkextension("DP_CSQC_V_CALCREFDEF") || checkextension("DP_CSQC_V_CALCREFDEF_WIP1")))
153 #else
154                 if(servercommandframe == 0 || clientcommandframe == 0)
155 #endif
156                 {
157                         InterpolateOrigin_Do();
158                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
159
160                         // get crouch state from the server
161                         if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS_z)
162                                 self.pmove_flags &~= PMF_DUCKED;
163                         else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS_z)
164                                 self.pmove_flags |= PMF_DUCKED;
165
166                         // get onground state from the server
167                         if(pmove_onground)
168                                 self.pmove_flags |= PMF_ONGROUND;
169                         else
170                                 self.pmove_flags &~= PMF_ONGROUND;
171
172                         CSQCPlayer_SetMinsMaxs();
173
174                         // override it back just in case
175                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
176
177                         // set velocity
178                         self.velocity = v0;
179                 }
180                 else
181                 {
182                         if(csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
183                         {
184                                 vector o, v;
185                                 o = self.origin;
186                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
187                                 CSQCPlayer_PredictTo(servercommandframe + 1);
188                                 CSQCPlayer_SetPredictionError(o - self.origin);
189                                 self.origin = o;
190                                 self.velocity = v0;
191
192                                 // get crouch state from the server
193                                 if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS_z)
194                                         self.pmove_flags &~= PMF_DUCKED;
195                                 else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS_z)
196                                         self.pmove_flags |= PMF_DUCKED;
197
198                                 // get onground state from the server
199                                 if(pmove_onground)
200                                         self.pmove_flags |= PMF_ONGROUND;
201                                 else
202                                         self.pmove_flags &~= PMF_ONGROUND;
203
204                                 CSQCPlayer_SavePrediction();
205                         }
206                         CSQCPlayer_PredictTo(clientcommandframe + 1);
207
208                         CSQCPlayer_SetMinsMaxs();
209
210                         self.angles_y = input_angles_y;
211                 }
212
213                 // relink
214                 setorigin(self, self.origin);
215
216                 self = oldself;
217         }
218
219         entity view;
220 #ifdef COMPAT_XON050_ENGINE
221         view = CSQCModel_server2csqc((spectatee_status > 0) ? spectatee_status : player_localentnum);
222 #else
223         view = CSQCModel_server2csqc(player_localentnum);
224 #endif
225
226         if(view && view != csqcplayer)
227         {
228                 entity oldself = self;
229                 self = view;
230                 InterpolateOrigin_Do();
231                 self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
232                 self = oldself;
233         }
234
235 #ifdef COMPAT_XON050_ENGINE
236         if(view && !(checkextension("DP_CSQC_V_CALCREFDEF") || checkextension("DP_CSQC_V_CALCREFDEF_WIP1")))
237         {
238                 // legacy code, not totally correct, but good enough for not having V_CalcRefdef
239                 setproperty(VF_ORIGIN, view.origin + '0 0 1' * getstati(STAT_VIEWHEIGHT));
240                 setproperty(VF_ANGLES, view_angles);
241         }
242         else
243 #endif
244         if(view)
245         {
246                 var float refdefflags = 0;
247
248                 if(view.csqcmodel_teleported)
249                         refdefflags |= REFDEFFLAG_TELEPORTED;
250
251                 if(input_buttons & 4)
252                         refdefflags |= REFDEFFLAG_JUMPING;
253
254                 // note: these two only work in WIP2, but are harmless in WIP1
255                 if(getstati(STAT_HEALTH) <= 0)
256                         refdefflags |= REFDEFFLAG_DEAD;
257
258                 if(intermission)
259                         refdefflags |= REFDEFFLAG_INTERMISSION;
260
261                 V_CalcRefdef(view, refdefflags);
262         }
263         else
264         {
265                 // FIXME by CSQC spec we have to do this:
266                 // but it breaks chase cam
267                 /*
268                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT));
269                 setproperty(VF_ANGLES, view_angles);
270                 */
271         }
272
273         { CSQCPLAYER_HOOK_POSTCAMERASETUP }
274 }
275
276 void CSQCPlayer_Remove()
277 {
278         csqcplayer = world;
279         cvar_settemp("cl_movement_replay", "1");
280 }
281
282 float CSQCPlayer_PreUpdate()
283 {
284         if(self != csqcplayer)
285                 return 0;
286         if(csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER)
287                 CSQCPlayer_Unpredict();
288         return 1;
289 }
290
291 float CSQCPlayer_PostUpdate()
292 {
293         if(self.entnum != player_localnum + 1)
294                 return 0;
295         csqcplayer = self;
296         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
297         cvar_settemp("cl_movement_replay", "0");
298         self.entremove = CSQCPlayer_Remove;
299         return 1;
300 }