qcsrc/csqcmodellib/sv_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22
  23 // generic CSQC model code
  24
  25 float CSQCModel_Send(entity to, float sf)
  26 {
  27         // some nice flags for CSQCMODEL_IF
  28         float isplayer = (self.flags & FL_CLIENT);
  29         float islocalplayer = (self == to);
  30         float isnolocalplayer = (isplayer && (self != to));
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_MODEL);
  33         WriteShort(MSG_ENTITY, sf);
  34
  35 #define CSQCMODEL_IF(cond) if(cond) {
  36 #define CSQCMODEL_ENDIF }
  37 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  38         if(sf & flag) \
  39         { \
  40                 w(MSG_ENTITY, self.csqcmodel_##f); \
  41         }
  42 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,t,r,w,f)
  43         ALLPROPERTIES
  44 #undef CSQCMODEL_PROPERTY_SCALED
  45 #undef CSQCMODEL_PROPERTY
  46 #undef CSQCMODEL_ENDIF
  47 #undef CSQCMODEL_IF
  48
  49         return TRUE;
  50 }
  51
  52 #ifdef CSQCPLAYER_FORCE_UPDATES
  53 .float csqcmodel_nextforcedupdate;
  54 #endif
  55 void CSQCModel_CheckUpdate()
  56 {
  57         // some nice flags for CSQCMODEL_IF
  58         float isplayer = (self.flags & FL_CLIENT);
  59         float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  60         float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  61
  62 #ifdef CSQCPLAYER_FORCE_UPDATES
  63         if(isplayer && time > self.csqcmodel_nextforcedupdate)
  64         {
  65                 self.SendFlags |= CSQCMODEL_PROPERTY_ORIGIN;
  66                 self.csqcmodel_nextforcedupdate = time + CSQCPLAYER_FORCE_UPDATES * (0.5 + random()); // ensure about 4 origin sends per sec
  67         }
  68 #endif
  69
  70         if(self.effects & EF_RESTARTANIM_BIT)
  71         {
  72                 self.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
  73                 self.effects &~= EF_RESTARTANIM_BIT;
  74         }
  75
  76         if(self.effects & EF_TELEPORT_BIT)
  77         {
  78                 self.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
  79                 self.effects &~= EF_TELEPORT_BIT;
  80         }
  81
  82 #define CSQCMODEL_IF(cond) if(cond) {
  83 #define CSQCMODEL_ENDIF }
  84 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  85         { \
  86                 t tmp = self.f; \
  87                 if(tmp != self.csqcmodel_##f) \
  88                 { \
  89                         self.csqcmodel_##f = tmp; \
  90                         self.SendFlags |= flag; \
  91                 } \
  92         }
  93 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
  94         { \
  95                 t tmp = bound(mi, s * self.f, ma); \
  96                 if(tmp != self.csqcmodel_##f) \
  97                 { \
  98                         self.csqcmodel_##f = tmp; \
  99                         self.SendFlags |= flag; \
 100                 } \
 101         }
 102         ALLPROPERTIES
 103 #undef CSQCMODEL_PROPERTY_SCALED
 104 #undef CSQCMODEL_PROPERTY
 105 #undef CSQCMODEL_ENDIF
 106 #undef CSQCMODEL_IF
 107 }
 108
 109 void CSQCModel_LinkEntity()
 110 {
 111         self.SendEntity = CSQCModel_Send;
 112         self.SendFlags = 0xFFFFFF;
 113         CSQCModel_CheckUpdate();
 114 }
 115
 116 void CSQCModel_UnlinkEntity()
 117 {
 118         self.SendEntity = func_null;
 119 }