qcsrc/ecs/systems/physics.qc

   1 #include "physics.qh"
   2 #include "input.qh"
   3
   4 .int disableclientprediction;
   5
   6 void sys_phys_simulate(entity this, float dt);
   7 void sys_phys_simulate_simple(entity this, float dt);
   8
   9 void sys_phys_postupdate(entity this);
  10
  11 void sys_phys_update(entity this, float dt)
  12 {
  13         if (!IS_CLIENT(this)) {
  14                 sys_phys_simulate_simple(this, dt);
  15                 return;
  16         }
  17         sys_in_update(this, dt);
  18
  19         sys_phys_fix(this, dt);
  20         if (sys_phys_override(this, dt))
  21                 return;
  22
  23         sys_phys_monitor(this, dt);
  24
  25         PHYS_CS(this).movement_old = PHYS_CS(this).movement;
  26         PHYS_CS(this).v_angle_old = this.v_angle;
  27         PHYS_CS(this).buttons_old = PHYS_INPUT_BUTTON_MASK(this);
  28
  29         sys_phys_ai(this);
  30
  31         sys_phys_pregame_hold(this);
  32
  33         if (IS_SVQC) {
  34                 if (this.move_movetype == MOVETYPE_NONE) { return; }
  35                 // when we get here, disableclientprediction cannot be 2
  36                 if(this.move_movetype == MOVETYPE_FOLLOW) // not compatible with prediction
  37                         this.disableclientprediction = 1;
  38                 else if(this.move_qcphysics)
  39                         this.disableclientprediction = -1;
  40                 else
  41                         this.disableclientprediction = 0;
  42         }
  43
  44         viewloc_PlayerPhysics(this);
  45
  46         PM_check_frozen(this);
  47
  48         PM_check_blocked(this);
  49
  50         float maxspeed_mod = 1;
  51
  52 // conveyors: first fix velocity
  53         if (this.conveyor.active) { this.velocity -= this.conveyor.movedir; }
  54         MUTATOR_CALLHOOK(PlayerPhysics, this, dt);
  55
  56         if (!IS_PLAYER(this)) {
  57                 sys_phys_spectator_control(this);
  58                 maxspeed_mod = STAT(SPECTATORSPEED, this);
  59         }
  60         sys_phys_fixspeed(this, maxspeed_mod);
  61
  62         if (IS_DEAD(this)) {
  63                 // handle water here
  64                 vector midpoint = ((this.absmin + this.absmax) * 0.5);
  65                 int cont = pointcontents(midpoint);
  66                 if (cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME) {
  67                         this.velocity = this.velocity * 0.5;
  68
  69                         // do we want this?
  70                         // if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
  71                         // { this.velocity_z = 70; }
  72                 }
  73                 sys_phys_postupdate(this);
  74                 return;
  75         }
  76
  77         PM_check_slick(this);
  78
  79         if (IS_SVQC && !PHYS_FIXANGLE(this)) { this.angles = '0 1 0' * this.v_angle.y; }
  80         if (IS_PLAYER(this)) {
  81                 if (IS_ONGROUND(this)) {
  82                         PM_check_hitground(this);
  83                         PM_Footsteps(this);
  84                 } else if (IsFlying(this)) {
  85                         this.wasFlying = true;
  86                 }
  87                 CheckPlayerJump(this);
  88         }
  89
  90         if (this.flags & FL_WATERJUMP) {
  91                 this.velocity_x = this.movedir.x;
  92                 this.velocity_y = this.movedir.y;
  93                 if (this.waterlevel == WATERLEVEL_NONE) {
  94                         this.flags &= ~FL_WATERJUMP;
  95                 }
  96         } else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod, dt)) {
  97                 // handled
  98         } else if (this.move_movetype == MOVETYPE_NOCLIP
  99             || this.move_movetype == MOVETYPE_FLY
 100             || this.move_movetype == MOVETYPE_FLY_WORLDONLY
 101             || MUTATOR_CALLHOOK(IsFlying, this)) {
 102                 this.com_phys_friction = PHYS_FRICTION(this);
 103                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 104                 this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
 105                 this.com_phys_friction_air = true;
 106                 sys_phys_simulate(this, dt);
 107                 this.com_phys_friction_air = false;
 108         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
 109                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 110                 this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
 111                 this.com_phys_water = true;
 112                 sys_phys_simulate(this, dt);
 113                 this.com_phys_water = false;
 114                 this.jumppadcount = 0;
 115         } else if (time < this.ladder_time) {
 116                 this.com_phys_friction = PHYS_FRICTION(this);
 117                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 118                 this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
 119                 this.com_phys_gravity = '0 0 -1' * PHYS_GRAVITY(this) * dt;
 120                 if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
 121                 this.com_phys_ladder = true;
 122                 this.com_phys_friction_air = true;
 123                 sys_phys_simulate(this, dt);
 124                 this.com_phys_friction_air = false;
 125                 this.com_phys_ladder = false;
 126                 this.com_phys_gravity = '0 0 0';
 127         } else if (ITEMS_STAT(this) & IT_USING_JETPACK) {
 128                 PM_jetpack(this, maxspeed_mod, dt);
 129         } else if (IS_ONGROUND(this) && (!IS_ONSLICK(this) || !PHYS_SLICK_APPLYGRAVITY(this))) {
 130                 if (!WAS_ONGROUND(this)) {
 131                         emit(phys_land, this);
 132                         if (this.lastground < time - 0.3) {
 133                                 this.velocity *= (1 - PHYS_FRICTION_ONLAND(this));
 134                         }
 135                 }
 136                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 137                 this.com_phys_gravity = '0 0 -1' * PHYS_GRAVITY(this) * dt;
 138                 if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
 139                 this.com_phys_ground = true;
 140                 this.com_phys_vel_2d = true;
 141                 sys_phys_simulate(this, dt);
 142                 this.com_phys_vel_2d = false;
 143                 this.com_phys_ground = false;
 144                 this.com_phys_gravity = '0 0 0';
 145         } else {
 146                 this.com_phys_acc_rate_air = PHYS_AIRACCELERATE(this) * min(maxspeed_mod, 1);
 147                 this.com_phys_acc_rate_air_stop = PHYS_AIRSTOPACCELERATE(this) * maxspeed_mod;
 148                 this.com_phys_acc_rate_air_strafe = PHYS_AIRSTRAFEACCELERATE(this) * maxspeed_mod;
 149                 this.com_phys_vel_max_air_strafe = PHYS_MAXAIRSTRAFESPEED(this) * maxspeed_mod;
 150                 this.com_phys_vel_max_air = PHYS_MAXAIRSPEED(this) * maxspeed_mod;
 151                 this.com_phys_vel_max = PHYS_MAXAIRSPEED(this) * min(maxspeed_mod, 1);
 152                 this.com_phys_air = true;
 153                 this.com_phys_vel_2d = true;
 154                 sys_phys_simulate(this, dt);
 155                 this.com_phys_vel_2d = false;
 156                 this.com_phys_air = false;
 157         }
 158
 159         sys_phys_postupdate(this);
 160 }
 161
 162 void sys_phys_postupdate(entity this)
 163 {
 164         if (IS_ONGROUND(this)) { this.lastground = time; }
 165 // conveyors: then break velocity again
 166         if (this.conveyor.active) { this.velocity += this.conveyor.movedir; }
 167         this.lastflags = this.flags;
 168
 169         this.lastclassname = this.classname;
 170 }
 171
 172 /** for players */
 173 void sys_phys_simulate(entity this, float dt)
 174 {
 175         if (!this.com_phys_ground && !this.com_phys_air) {
 176                 // noclipping
 177                 // flying
 178                 // on a spawnfunc_func_ladder
 179                 // swimming in spawnfunc_func_water
 180                 // swimming
 181                 UNSET_ONGROUND(this);
 182
 183                 if (this.com_phys_friction_air) {
 184                         const vector g = -this.com_phys_gravity;
 185                         this.velocity_z += g.z / 2;
 186                         this.velocity = this.velocity * (1 - dt * this.com_phys_friction);
 187                         this.velocity_z += g.z / 2;
 188                 }
 189         }
 190
 191         if (this.com_phys_water) {
 192                 // water jump only in certain situations
 193                 // this mimics quakeworld code
 194                 if (this.com_in_jump && this.waterlevel == WATERLEVEL_SWIMMING && this.velocity_z >= -180 && !this.viewloc && !PHYS_FROZEN(this)) {
 195                         vector yawangles = '0 1 0' * this.v_angle.y;
 196                         vector forward, right, up;
 197                         MAKE_VECTORS(yawangles, forward, right, up);
 198                         vector spot = this.origin + 24 * forward;
 199                         spot_z += 8;
 200                         traceline(spot, spot, MOVE_NOMONSTERS, this);
 201                         if (trace_startsolid) {
 202                                 spot_z += 24;
 203                                 traceline(spot, spot, MOVE_NOMONSTERS, this);
 204                                 if (!trace_startsolid) {
 205                                         this.velocity = forward * 50;
 206                                         this.velocity_z = 310;
 207                                         UNSET_ONGROUND(this);
 208                                         SET_JUMP_HELD(this);
 209                                 }
 210                         }
 211                 }
 212         }
 213
 214         vector forward, right, up;
 215         MAKE_VECTORS(vmul(this.v_angle, (this.com_phys_vel_2d ? '0 1 0' : '1 1 1')), forward, right, up);
 216         // wishvel = forward * PHYS_CS(this).movement.x + right * PHYS_CS(this).movement.y + up * PHYS_CS(this).movement.z;
 217         vector wishvel = forward * PHYS_CS(this).movement.x
 218             + right * PHYS_CS(this).movement.y
 219             + '0 0 1' * PHYS_CS(this).movement.z * (this.com_phys_vel_2d ? 0 : 1);
 220         if (this.com_phys_water && !PHYS_FROZEN(this)) {
 221                 if (PHYS_INPUT_BUTTON_CROUCH(this)) {
 222                         wishvel.z = -PHYS_MAXSPEED(this);
 223                 }
 224                 if (this.viewloc) {
 225                         wishvel.z = -160;    // drift anyway
 226                 } else if (wishvel == '0 0 0') {
 227                         wishvel = '0 0 -60'; // drift towards bottom
 228                 }
 229         }
 230         if (this.com_phys_ladder) {
 231                 if (this.viewloc) {
 232                         wishvel.z = PHYS_CS(this).movement_old.x;
 233                 }
 234                 if (this.ladder_entity.classname == "func_water") {
 235                         float f = vlen(wishvel);
 236                         if (f > this.ladder_entity.speed) {
 237                                 wishvel *= (this.ladder_entity.speed / f);
 238                         }
 239
 240                         this.watertype = this.ladder_entity.skin;
 241                         f = this.ladder_entity.origin_z + this.ladder_entity.maxs_z;
 242                         if ((this.origin_z + this.view_ofs_z) < f) {
 243                                 this.waterlevel = WATERLEVEL_SUBMERGED;
 244                         } else if ((this.origin_z + (this.mins_z + this.maxs_z) * 0.5) < f) {
 245                                 this.waterlevel = WATERLEVEL_SWIMMING;
 246                         } else if ((this.origin_z + this.mins_z + 1) < f) {
 247                                 this.waterlevel = WATERLEVEL_WETFEET;
 248                         } else {
 249                                 this.waterlevel = WATERLEVEL_NONE;
 250                                 this.watertype = CONTENT_EMPTY;
 251                         }
 252                 }
 253         }
 254         // acceleration
 255         const vector wishdir = normalize(wishvel);
 256         float wishspeed = min(vlen(wishvel), this.com_phys_vel_max);
 257
 258         if (this.com_phys_air) {
 259                 if (!(this.flags & FL_WATERJUMP)) {
 260                         // apply air speed limit
 261                         float airaccelqw = PHYS_AIRACCEL_QW(this);
 262                         float wishspeed0 = wishspeed;
 263                         const float maxairspd = this.com_phys_vel_max;
 264                         wishspeed = min(wishspeed, maxairspd);
 265                         if (IS_DUCKED(this)) {
 266                                 wishspeed *= 0.5;
 267                         }
 268                         float airaccel = this.com_phys_acc_rate_air;
 269
 270                         float accelerating = (this.velocity * wishdir > 0);
 271                         float wishspeed2 = wishspeed;
 272
 273                         // CPM: air control
 274                         if (PHYS_AIRSTOPACCELERATE(this)) {
 275                                 vector curdir = normalize(vec2(this.velocity));
 276                                 airaccel += (this.com_phys_acc_rate_air_stop - airaccel) * max(0, -(curdir * wishdir));
 277                         }
 278                         // note that for straight forward jumping:
 279                         // step = accel * dt * wishspeed0;
 280                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 281                         // -->
 282                         // dv/dt = accel * maxspeed (when slow)
 283                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
 284                         // log dv/dt = logaccel + logmaxspeed (when slow)
 285                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
 286                         float strafity = IsMoveInDirection(PHYS_CS(this).movement, -90) + IsMoveInDirection(PHYS_CS(this).movement, +90);  // if one is nonzero, other is always zero
 287                         if (PHYS_MAXAIRSTRAFESPEED(this)) {
 288                                 wishspeed =
 289                                     min(wishspeed,
 290                                         GeomLerp(this.com_phys_vel_max_air, strafity, this.com_phys_vel_max_air_strafe));
 291                         }
 292                         if (PHYS_AIRSTRAFEACCELERATE(this)) {
 293                                 airaccel = GeomLerp(airaccel, strafity, this.com_phys_acc_rate_air_strafe);
 294                         }
 295                         if (PHYS_AIRSTRAFEACCEL_QW(this)) {
 296                                 airaccelqw =
 297                                     (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(this) : PHYS_AIRACCEL_QW(this)) >= 0) ? +1 : -1)
 298                                     *
 299                                     (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(this)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(this))));
 300                         }
 301                         // !CPM
 302
 303                         if (PHYS_WARSOWBUNNY_TURNACCEL(this) && accelerating && PHYS_CS(this).movement.y == 0 && PHYS_CS(this).movement.x != 0) {
 304                                 PM_AirAccelerate(this, dt, wishdir, wishspeed2);
 305                         } else {
 306                                 float sidefric = maxairspd ? (PHYS_AIRACCEL_SIDEWAYS_FRICTION(this) / maxairspd) : 0;
 307                                 PM_Accelerate(this, dt, wishdir, wishspeed, wishspeed0, airaccel, airaccelqw,
 308                                         PHYS_AIRACCEL_QW_STRETCHFACTOR(this), sidefric, PHYS_AIRSPEEDLIMIT_NONQW(this));
 309                         }
 310
 311                         if (PHYS_AIRCONTROL(this)) {
 312                                 CPM_PM_Aircontrol(this, dt, wishdir, wishspeed2);
 313                         }
 314                 }
 315         } else {
 316                 if (this.com_phys_ground && IS_DUCKED(this)) { wishspeed *= 0.5; }
 317                 if (this.com_phys_water) {
 318                         wishspeed *= 0.7;
 319
 320                         //      if (!(this.flags & FL_WATERJUMP)) // TODO: use
 321                         {
 322                                 // water friction
 323                                 float f = 1 - dt * PHYS_FRICTION(this);
 324                                 f = min(max(0, f), 1);
 325                                 this.velocity *= f;
 326
 327                                 f = wishspeed - this.velocity * wishdir;
 328                                 if (f > 0) {
 329                                         float accelspeed = min(PHYS_ACCELERATE(this) * dt * wishspeed, f);
 330                                         this.velocity += accelspeed * wishdir;
 331                                 }
 332
 333                                 // holding jump button swims upward slowly
 334                                 if (this.com_in_jump && !this.viewloc && !PHYS_FROZEN(this)) {
 335                                         // was:
 336                                         // lava: 50
 337                                         // slime: 80
 338                                         // water: 100
 339                                         // idea: double those
 340                                         this.velocity_z = 200;
 341                                         if (this.waterlevel >= WATERLEVEL_SUBMERGED) {
 342                                                 this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 343                                         }
 344                                 }
 345                         }
 346                         if (this.viewloc) {
 347                                 const float addspeed = wishspeed - this.velocity * wishdir;
 348                                 if (addspeed > 0) {
 349                                         const float accelspeed = min(PHYS_ACCELERATE(this) * dt * wishspeed, addspeed);
 350                                         this.velocity += accelspeed * wishdir;
 351                                 }
 352                         } else {
 353                                 // water acceleration
 354                                 PM_Accelerate(this, dt, wishdir, wishspeed, wishspeed, this.com_phys_acc_rate, 1, 0, 0, 0);
 355                         }
 356                         return;
 357                 }
 358                 if (this.com_phys_ground) {
 359                         // apply edge friction
 360                         const float f2 = vlen2(vec2(this.velocity));
 361                         if (f2 > 0) {
 362                                 // TODO: apply edge friction
 363                                 // apply ground friction
 364                                 const int realfriction = (IS_ONSLICK(this))
 365                                     ? PHYS_FRICTION_SLICK(this)
 366                                         : PHYS_FRICTION(this);
 367
 368                                 float f = sqrt(f2);
 369                                 f = 1 - dt * realfriction
 370                                     * ((f < PHYS_STOPSPEED(this)) ? (PHYS_STOPSPEED(this) / f) : 1);
 371                                 f = max(0, f);
 372                                 this.velocity *= f;
 373                                 /*
 374                                    Mathematical analysis time!
 375
 376                                    Our goal is to invert this mess.
 377
 378                                    For the two cases we get:
 379                                     v = v0 * (1 - dt * (PHYS_STOPSPEED(this) / v0) * PHYS_FRICTION(this))
 380                                       = v0 - dt * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
 381                                     v0 = v + dt * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
 382                                    and
 383                                     v = v0 * (1 - dt * PHYS_FRICTION(this))
 384                                     v0 = v / (1 - dt * PHYS_FRICTION(this))
 385
 386                                    These cases would be chosen ONLY if:
 387                                     v0 < PHYS_STOPSPEED(this)
 388                                     v + dt * PHYS_STOPSPEED(this) * PHYS_FRICTION(this) < PHYS_STOPSPEED(this)
 389                                     v < PHYS_STOPSPEED(this) * (1 - dt * PHYS_FRICTION(this))
 390                                    and, respectively:
 391                                     v0 >= PHYS_STOPSPEED(this)
 392                                     v / (1 - dt * PHYS_FRICTION(this)) >= PHYS_STOPSPEED(this)
 393                                     v >= PHYS_STOPSPEED(this) * (1 - dt * PHYS_FRICTION(this))
 394                                  */
 395                         }
 396                         const float addspeed = wishspeed - this.velocity * wishdir;
 397                         if (addspeed > 0) {
 398                                 const float accelspeed = min(PHYS_ACCELERATE(this) * dt * wishspeed, addspeed);
 399                                 this.velocity += accelspeed * wishdir;
 400                         }
 401                         return;
 402                 }
 403
 404                 if (!(this.flags & FL_WATERJUMP)) {
 405                         PM_Accelerate(this, dt, wishdir, wishspeed, wishspeed, this.com_phys_acc_rate, 1, 0, 0, 0);
 406                 }
 407         }
 408 }
 409
 410 .entity groundentity;
 411 /** for other entities */
 412 void sys_phys_simulate_simple(entity this, float dt)
 413 {
 414         vector mn = this.mins;
 415         vector mx = this.maxs;
 416
 417         vector g = '0 0 0';
 418         if (this.com_phys_gravity_factor && !g) g = '0 0 -1' * PHYS_GRAVITY(NULL);
 419
 420         vector acc = this.com_phys_acc;
 421         vector vel = this.com_phys_vel;
 422         vector pos = this.com_phys_pos;
 423
 424         // SV_Physics_Toss
 425
 426         vel += g * dt;
 427
 428         this.angles += dt * this.avelocity;
 429         float movetime = dt;
 430         for (int i = 0; i < MAX_CLIP_PLANES && movetime > 0; i++) {
 431                 vector push = vel * movetime;
 432                 vector p0 = pos;
 433                 vector p1 = p0 + push;
 434                 // SV_PushEntity
 435                 tracebox(p0, mn, mx, p1, MOVE_NORMAL, this);
 436                 if (!trace_startsolid) {
 437                         bool hit = trace_fraction < 1;
 438                         pos = trace_endpos;
 439                         entity ent = trace_ent;
 440                         // SV_LinkEdict_TouchAreaGrid
 441                         if (this.solid != SOLID_NOT) {
 442                                 FOREACH_ENTITY_RADIUS_ORDERED(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
 443                                         if (it.solid != SOLID_TRIGGER || it == this) continue;
 444                                         if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax)) {
 445                                             // SV_LinkEdict_TouchAreaGrid_Call
 446                                             trace_allsolid = false;
 447                                             trace_startsolid = false;
 448                                             trace_fraction = 1;
 449                                             trace_inwater = false;
 450                                             trace_inopen = true;
 451                                             trace_endpos = it.origin;
 452                                             trace_plane_normal = '0 0 1';
 453                                             trace_plane_dist = 0;
 454                                             trace_ent = this;
 455                                             trace_dpstartcontents = 0;
 456                                             trace_dphitcontents = 0;
 457                                             trace_dphitq3surfaceflags = 0;
 458                                             trace_dphittexturename = string_null;
 459                                             gettouch(it)(this, it);
 460                                             vel = this.velocity;
 461                                         }
 462                                 });
 463                         }
 464                         if (hit && this.solid >= SOLID_TRIGGER && (!IS_ONGROUND(this) || this.groundentity != ent)) {
 465                                 // SV_Impact (ent, trace);
 466                                 tracebox(p0, mn, mx, p1, MOVE_NORMAL, this);
 467                                 void(entity, entity) touched = gettouch(this);
 468                                 if (touched && this.solid != SOLID_NOT) {
 469                                         touched(ent, this);
 470                                 }
 471                                 void(entity, entity) touched2 = gettouch(ent);
 472                                 if (this && ent && touched2 && ent.solid != SOLID_NOT) {
 473                                         trace_endpos = ent.origin;
 474                                         trace_plane_normal *= -1;
 475                                         trace_plane_dist *= -1;
 476                                         trace_ent = this;
 477                                         trace_dpstartcontents = 0;
 478                                         trace_dphitcontents = 0;
 479                                         trace_dphitq3surfaceflags = 0;
 480                                         trace_dphittexturename = string_null;
 481                                         touched2(this, ent);
 482                                 }
 483                         }
 484                 }
 485                 // end SV_PushEntity
 486                 if (wasfreed(this)) { return; }
 487                 tracebox(p0, mn, mx, p1, MOVE_NORMAL, this);
 488                 if (trace_fraction == 1) { break; }
 489                 movetime *= 1 - min(1, trace_fraction);
 490                 ClipVelocity(vel, trace_plane_normal, vel, 1);
 491         }
 492
 493         this.com_phys_acc = acc;
 494         this.com_phys_vel = vel;
 495         this.com_phys_pos = pos;
 496         setorigin(this, this.com_phys_pos);
 497 }
 498
 499 void sys_phys_update_single(entity this)
 500 {
 501         sys_phys_simulate_simple(this, frametime);
 502 }