Remove .move_* fields and MOVETYPE_PUSH logic (doesn't work)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / lib / csqcmodel / cl_player.qc
1 /*
2  * Copyright (c) 2011 Rudolf Polzer
3  * Copyright (c) 2015 Micah Talkiewicz
4  *
5  * Permission is hereby granted, free of charge, to any person obtaining a copy
6  * of this software and associated documentation files (the "Software"), to
7  * deal in the Software without restriction, including without limitation the
8  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
9  * sell copies of the Software, and to permit persons to whom the Software is
10  * furnished to do so, subject to the following conditions:
11  *
12  * The above copyright notice and this permission notice shall be included in
13  * all copies or substantial portions of the Software.
14  *
15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
18  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
21  * IN THE SOFTWARE.
22  */
23 #include "cl_player.qh"
24
25 #include "cl_model.qh"
26 #include "common.qh"
27 #include "interpolate.qh"
28 #include <client/defs.qh>
29 #include <client/main.qh>
30 #include <common/constants.qh>
31 #include <common/physics/player.qh>
32 #include <common/stats.qh>
33 #include <common/triggers/trigger/viewloc.qh>
34 #include <common/util.qh>
35 #include <common/viewloc.qh>
36
37 float autocvar_cl_movement_errorcompensation = 0;
38 bool autocvar_cl_movement_intermissionrunning = false;
39
40 // engine stuff
41 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
42
43 vector csqcplayer_origin, csqcplayer_velocity;
44 float csqcplayer_sequence;
45 int player_pmflags;
46 float csqcplayer_moveframe;
47 vector csqcplayer_predictionerroro;
48 vector csqcplayer_predictionerrorv;
49 float csqcplayer_predictionerrortime;
50 float csqcplayer_predictionerrorfactor;
51
52 vector CSQCPlayer_GetPredictionErrorO()
53 {
54         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
55         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
56 }
57
58 vector CSQCPlayer_GetPredictionErrorV()
59 {
60         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
61         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
62 }
63
64 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
65 {
66         // error too big to compensate, we LIKELY hit a teleport or a
67         // jumppad, or it's a jump time disagreement that'll get fixed
68         // next frame
69
70         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
71         /*
72         // commented out as this one did not help
73         if(onground_diff)
74         {
75                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
76                 return;
77         }
78         */
79         if(vdist(o, >, 32) || vdist(v, >, 192))
80         {
81                 //printf("TOO BIG: x=%v v=%v\n", o, v);
82                 return;
83         }
84
85         if(!autocvar_cl_movement_errorcompensation)
86         {
87                 csqcplayer_predictionerrorfactor = 0;
88                 return;
89         }
90
91         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
92         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
93         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ticrate;
94         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
95 }
96
97 void CSQCPlayer_Unpredict(entity this)
98 {
99         if (csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED) return;
100         if (csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED) LOG_FATALF("Cannot unpredict in current status (%d)\n", csqcplayer_status);
101         this.origin = csqcplayer_origin;
102         this.velocity = csqcplayer_velocity;
103         csqcplayer_moveframe = csqcplayer_sequence + 1; // + 1 because the recieved frame has the move already done (server side)
104         this.flags = player_pmflags;
105 }
106
107 void CSQCPlayer_SetMinsMaxs(entity this)
108 {
109         if ((this.flags & FL_DUCKED) || !this.isplayermodel)
110         {
111                 this.mins = STAT(PL_CROUCH_MIN, NULL);
112                 this.maxs = STAT(PL_CROUCH_MAX, NULL);
113                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, NULL);
114         }
115         else
116         {
117                 this.mins = STAT(PL_MIN, NULL);
118                 this.maxs = STAT(PL_MAX, NULL);
119                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
120         }
121 }
122
123 void CSQCPlayer_SavePrediction(entity this)
124 {
125         player_pmflags = this.flags;
126         csqcplayer_origin = this.origin;
127         csqcplayer_velocity = this.velocity;
128         csqcplayer_sequence = servercommandframe;
129         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
130 }
131
132 void CSQC_ClientMovement_PlayerMove_Frame(entity this);
133 void _Movetype_Physics_ClientFrame(entity this, float movedt);
134
135 void Movetype_Physics_Spam(entity this)  // optimized
136 {
137         _Movetype_Physics_ClientFrame(this, PHYS_INPUT_TIMELENGTH);
138         if(wasfreed(this))
139                 return;
140
141         setorigin(this, this.origin);
142 }
143
144 void CSQCPlayer_CheckWater(entity this)
145 {
146         _Movetype_CheckWater(this);
147 }
148
149 void CSQCPlayer_Physics(entity this)
150 {
151         if(autocvar_cl_movement)
152         {
153                 if(autocvar_cl_movement == 1)
154                         CSQCPlayer_CheckWater(this); // we apparently need to check water *before* physics so it can use this for water jump
155
156                 vector oldv_angle = this.v_angle;
157                 vector oldangles = this.angles; // we need to save these, as they're abused by other code
158                 this.v_angle = PHYS_INPUT_ANGLES(this);
159                 this.angles = PHYS_WORLD_ANGLES(this);
160
161                 CSQC_ClientMovement_PlayerMove_Frame(this);
162
163                 if(autocvar_cl_movement == 1)
164                         Movetype_Physics_Spam(this);
165
166                 view_angles = this.v_angle;
167                 input_angles = this.angles;
168                 this.v_angle = oldv_angle;
169                 this.angles = oldangles;
170
171                 this.pmove_flags =
172                                 ((this.flags & FL_DUCKED) ? PMF_DUCKED : 0) |
173                                 (!(this.flags & FL_JUMPRELEASED) ? PMF_JUMP_HELD : 0) |
174                                 ((IS_ONGROUND(this)) ? PMF_ONGROUND : 0);
175         }
176 }
177
178 void CSQCPlayer_PredictTo(entity this, float endframe, bool apply_error)
179 {
180         CSQCPlayer_Unpredict(this);
181         if (apply_error)
182         {
183                 this.origin += CSQCPlayer_GetPredictionErrorO();
184                 this.velocity += CSQCPlayer_GetPredictionErrorV();
185         }
186         CSQCPlayer_SetMinsMaxs(this);
187
188         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
189
190 #if 0
191         // we don't need this
192         // darkplaces makes servercommandframe == 0 in these cases anyway
193         if (STAT(HEALTH) <= 0)
194         {
195                 csqcplayer_moveframe = clientcommandframe;
196                 getinputstate(csqcplayer_moveframe-1);
197                 LOG_INFO("the Weird code path got hit\n");
198                 return;
199         }
200 #endif
201
202         if (csqcplayer_moveframe >= endframe)
203         {
204                 getinputstate(csqcplayer_moveframe - 1);
205         }
206         else
207         {
208                 do
209                 {
210                         if (!getinputstate(csqcplayer_moveframe)) break;
211                         CSQCPlayer_Physics(this);
212                         CSQCPlayer_SetMinsMaxs(this);
213                         ++csqcplayer_moveframe;
214                 }
215                 while (csqcplayer_moveframe < endframe);
216         }
217
218         // add in anything that was applied after (for low packet rate protocols)
219         input_angles = view_angles;
220 }
221
222 bool CSQCPlayer_IsLocalPlayer(entity this)
223 {
224         return (this == csqcplayer);
225 }
226
227 void CSQCPlayer_SetViewLocation()
228 {
229         viewloc_SetViewLocation();
230 }
231
232 /** Called once per CSQC_UpdateView() */
233 void CSQCPlayer_SetCamera()
234 {
235         const vector v0 = ((intermission && !autocvar_cl_movement_intermissionrunning) ? '0 0 0' : pmove_vel); // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
236         const float vh = STAT(VIEWHEIGHT);
237         const vector pl_viewofs = STAT(PL_VIEW_OFS, NULL);
238         const vector pl_viewofs_crouch = STAT(PL_CROUCH_VIEW_OFS, NULL);
239         const entity e = csqcplayer;
240         if (e)
241         {
242                 if (servercommandframe == 0 || clientcommandframe == 0)
243                 {
244                         InterpolateOrigin_Do(e);
245                         e.view_ofs = '0 0 1' * vh;
246
247                         // get crouch state from the server
248                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
249                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
250
251                         // get onground state from the server
252                         e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
253
254                         CSQCPlayer_SetMinsMaxs(e);
255
256                         // override it back just in case
257                         e.view_ofs = '0 0 1' * vh;
258
259                         // set velocity
260                         e.velocity = v0;
261                 }
262                 else
263                 {
264                         const int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
265                         InterpolateOrigin_Do(e);
266                         e.iflags = flg;
267
268                         if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
269                         {
270                                 const vector o = e.origin;
271                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
272                                 CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
273                                 CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - IS_ONGROUND(e));
274                                 e.origin = o;
275                                 e.velocity = v0;
276
277                                 // get crouch state from the server
278                                 if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
279                                 else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
280
281                                 // get onground state from the server
282                                 e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
283
284                                 CSQCPlayer_SavePrediction(e);
285                         }
286                         CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
287
288 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
289                         // get crouch state from the server (LAG)
290                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
291                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
292 #endif
293                         CSQCPlayer_SetMinsMaxs(e);
294
295                         e.angles_y = input_angles.y;
296                 }
297
298                 // relink
299                 setorigin(e, e.origin);
300         }
301
302         const entity view = CSQCModel_server2csqc(player_localentnum - 1);
303         if (view)
304         {
305                 if (view != csqcplayer)
306                 {
307                         InterpolateOrigin_Do(view);
308                         view.view_ofs = '0 0 1' * vh;
309                 }
310                 int refdefflags = 0;
311                 if (view.csqcmodel_teleported) refdefflags |= REFDEFFLAG_TELEPORTED;
312                 if (input_buttons & BIT(1)) refdefflags |= REFDEFFLAG_JUMPING;
313                 // note: these two only work in WIP2, but are harmless in WIP1
314                 if (STAT(HEALTH) <= 0 && STAT(HEALTH) != -666 && STAT(HEALTH) != -2342) refdefflags |= REFDEFFLAG_DEAD;
315                 if (intermission) refdefflags |= REFDEFFLAG_INTERMISSION;
316                 V_CalcRefdef(view, refdefflags);
317         }
318         else
319         {
320                 // FIXME by CSQC spec we have to do this:
321                 // but it breaks chase cam
322                 /*
323                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
324                 setproperty(VF_ANGLES, view_angles);
325                 */
326         }
327         CSQCPLAYER_HOOK_POSTCAMERASETUP();
328 }
329
330 void CSQCPlayer_Remove(entity this)
331 {
332         csqcplayer = NULL;
333         cvar_settemp("cl_movement_replay", "1");
334 }
335
336 bool CSQCPlayer_PreUpdate(entity this)
337 {
338         if (this != csqcplayer) return false;
339         if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
340         return true;
341 }
342
343 bool CSQCPlayer_PostUpdate(entity this)
344 {
345         if (this.entnum != player_localnum + 1) return false;
346         csqcplayer = this;
347         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
348         cvar_settemp("cl_movement_replay", "0");
349         this.entremove = CSQCPlayer_Remove;
350         return true;
351 }