qcsrc/lib/csqcmodel/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  * Copyright (c) 2015 Micah Talkiewicz
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy
   6  * of this software and associated documentation files (the "Software"), to
   7  * deal in the Software without restriction, including without limitation the
   8  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   9  * sell copies of the Software, and to permit persons to whom the Software is
  10  * furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice shall be included in
  13  * all copies or substantial portions of the Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  21  * IN THE SOFTWARE.
  22  */
  23 #include "cl_player.qh"
  24
  25 #include "cl_model.qh"
  26 #include "common.qh"
  27 #include "interpolate.qh"
  28 #include <client/defs.qh>
  29 #include <client/main.qh>
  30 #include <common/constants.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/stats.qh>
  33 #include <common/triggers/trigger/viewloc.qh>
  34 #include <common/util.qh>
  35 #include <common/viewloc.qh>
  36
  37 float autocvar_cl_movement_errorcompensation = 0;
  38 bool autocvar_cl_movement_intermissionrunning = false;
  39
  40 // engine stuff
  41 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  42
  43 vector csqcplayer_origin, csqcplayer_velocity;
  44 float csqcplayer_sequence;
  45 int player_pmflags;
  46 float csqcplayer_moveframe;
  47 vector csqcplayer_predictionerroro;
  48 vector csqcplayer_predictionerrorv;
  49 float csqcplayer_predictionerrortime;
  50 float csqcplayer_predictionerrorfactor;
  51
  52 vector CSQCPlayer_GetPredictionErrorO()
  53 {
  54         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  55         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  56 }
  57
  58 vector CSQCPlayer_GetPredictionErrorV()
  59 {
  60         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  61         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  62 }
  63
  64 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
  65 {
  66         // error too big to compensate, we LIKELY hit a teleport or a
  67         // jumppad, or it's a jump time disagreement that'll get fixed
  68         // next frame
  69
  70         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
  71         /*
  72         // commented out as this one did not help
  73         if(onground_diff)
  74         {
  75                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
  76                 return;
  77         }
  78         */
  79         if(vdist(o, >, 32) || vdist(v, >, 192))
  80         {
  81                 //printf("TOO BIG: x=%v v=%v\n", o, v);
  82                 return;
  83         }
  84
  85         if(!autocvar_cl_movement_errorcompensation)
  86         {
  87                 csqcplayer_predictionerrorfactor = 0;
  88                 return;
  89         }
  90
  91         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
  92         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
  93         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ticrate;
  94         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
  95 }
  96
  97 void CSQCPlayer_Unpredict(entity this)
  98 {
  99         if (csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED) return;
 100         if (csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED) LOG_FATALF("Cannot unpredict in current status (%d)", csqcplayer_status);
 101         this.origin = csqcplayer_origin;
 102         this.velocity = csqcplayer_velocity;
 103         csqcplayer_moveframe = csqcplayer_sequence + 1; // + 1 because the recieved frame has the move already done (server side)
 104         this.flags = player_pmflags;
 105 }
 106
 107 void CSQCPlayer_SetMinsMaxs(entity this)
 108 {
 109         if (IS_DUCKED(this) || !this.isplayermodel)
 110         {
 111                 this.mins = STAT(PL_CROUCH_MIN, NULL);
 112                 this.maxs = STAT(PL_CROUCH_MAX, NULL);
 113                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, NULL);
 114         }
 115         else
 116         {
 117                 this.mins = STAT(PL_MIN, NULL);
 118                 this.maxs = STAT(PL_MAX, NULL);
 119                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 120         }
 121 }
 122
 123 void CSQCPlayer_SavePrediction(entity this)
 124 {
 125         player_pmflags = this.flags;
 126         csqcplayer_origin = this.origin;
 127         csqcplayer_velocity = this.velocity;
 128         csqcplayer_sequence = servercommandframe;
 129         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 130 }
 131
 132 void CSQC_ClientMovement_PlayerMove_Frame(entity this);
 133
 134 void CSQCPlayer_Physics(entity this)
 135 {
 136         if(!autocvar_cl_movement) { return; }
 137
 138         _Movetype_CheckWater(this); // we apparently need to check water *before* physics so it can use this for water jump
 139
 140         vector oldv_angle = this.v_angle;
 141         vector oldangles = this.angles; // we need to save these, as they're abused by other code
 142         this.v_angle = PHYS_INPUT_ANGLES(this);
 143         this.angles = PHYS_WORLD_ANGLES(this);
 144
 145         CSQC_ClientMovement_PlayerMove_Frame(this);
 146
 147         Movetype_Physics_NoMatchTicrate(this, PHYS_INPUT_TIMELENGTH, true);
 148
 149         view_angles = this.v_angle;
 150         input_angles = this.angles;
 151         this.v_angle = oldv_angle;
 152         this.angles = oldangles;
 153
 154         this.pmove_flags =
 155                         ((IS_DUCKED(this)) ? PMF_DUCKED : 0) |
 156                         ((IS_JUMP_HELD(this)) ? PMF_JUMP_HELD : 0) |
 157                         ((IS_ONGROUND(this)) ? PMF_ONGROUND : 0);
 158 }
 159
 160 void CSQCPlayer_PredictTo(entity this, float endframe, bool apply_error)
 161 {
 162         CSQCPlayer_Unpredict(this);
 163         if (apply_error)
 164         {
 165                 this.origin += CSQCPlayer_GetPredictionErrorO();
 166                 this.velocity += CSQCPlayer_GetPredictionErrorV();
 167         }
 168         CSQCPlayer_SetMinsMaxs(this);
 169
 170         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 171
 172 #if 0
 173         // we don't need this
 174         // darkplaces makes servercommandframe == 0 in these cases anyway
 175         if (STAT(HEALTH) <= 0)
 176         {
 177                 csqcplayer_moveframe = clientcommandframe;
 178                 getinputstate(csqcplayer_moveframe-1);
 179                 LOG_INFO("the Weird code path got hit\n");
 180                 return;
 181         }
 182 #endif
 183
 184         if (csqcplayer_moveframe >= endframe)
 185         {
 186                 getinputstate(csqcplayer_moveframe - 1);
 187         }
 188         else
 189         {
 190                 do
 191                 {
 192                         if (!getinputstate(csqcplayer_moveframe)) break;
 193                         /*if (input_timelength > 0.0005)
 194                         {
 195                                 if (input_timelength > 0.05)
 196                                 {
 197                                         input_timelength /= 2;
 198                                         CSQCPlayer_Physics(this);
 199                                 }
 200                                 CSQCPlayer_Physics(this);
 201                         }*/
 202                         CSQCPlayer_Physics(this);
 203                         CSQCPlayer_SetMinsMaxs(this);
 204                         ++csqcplayer_moveframe;
 205                 }
 206                 while (csqcplayer_moveframe < endframe);
 207         }
 208
 209         // add in anything that was applied after (for low packet rate protocols)
 210         input_angles = view_angles;
 211 }
 212
 213 bool CSQCPlayer_IsLocalPlayer(entity this)
 214 {
 215         return (this == csqcplayer);
 216 }
 217
 218 void CSQCPlayer_SetViewLocation()
 219 {
 220         viewloc_SetViewLocation();
 221 }
 222
 223 /** Called once per CSQC_UpdateView() */
 224 void CSQCPlayer_SetCamera()
 225 {
 226         const vector v0 = ((intermission && !autocvar_cl_movement_intermissionrunning) ? '0 0 0' : pmove_vel); // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 227         const float vh = STAT(VIEWHEIGHT);
 228         const vector pl_viewofs = STAT(PL_VIEW_OFS, NULL);
 229         const vector pl_viewofs_crouch = STAT(PL_CROUCH_VIEW_OFS, NULL);
 230         const entity e = csqcplayer;
 231         if (e)
 232         {
 233                 if (servercommandframe == 0 || clientcommandframe == 0)
 234                 {
 235                         InterpolateOrigin_Do(e);
 236                         e.view_ofs = '0 0 1' * vh;
 237
 238                         // get crouch state from the server
 239                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 240                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 241
 242                         // get onground state from the server
 243                         e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 244
 245                         CSQCPlayer_SetMinsMaxs(e);
 246
 247                         // override it back just in case
 248                         e.view_ofs = '0 0 1' * vh;
 249
 250                         // set velocity
 251                         e.velocity = v0;
 252                 }
 253                 else
 254                 {
 255                         const int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
 256                         InterpolateOrigin_Do(e);
 257                         e.iflags = flg;
 258
 259                         if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 260                         {
 261                                 const vector o = e.origin;
 262                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 263                                 CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
 264                                 CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - IS_ONGROUND(e));
 265                                 e.origin = o;
 266                                 e.velocity = v0;
 267
 268                                 // get crouch state from the server
 269                                 if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 270                                 else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 271
 272                                 // get onground state from the server
 273                                 e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 274
 275                                 CSQCPlayer_SavePrediction(e);
 276                         }
 277                         CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
 278
 279 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
 280                         // get crouch state from the server (LAG)
 281                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 282                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 283 #endif
 284                         CSQCPlayer_SetMinsMaxs(e);
 285
 286                         e.angles_y = input_angles.y;
 287                 }
 288
 289                 // relink
 290                 setorigin(e, e.origin);
 291         }
 292
 293         const entity view = CSQCModel_server2csqc(player_localentnum - 1);
 294         if (view)
 295         {
 296                 if (view != csqcplayer)
 297                 {
 298                         InterpolateOrigin_Do(view);
 299                         view.view_ofs = '0 0 1' * vh;
 300                 }
 301                 int refdefflags = 0;
 302                 if (view.csqcmodel_teleported) refdefflags |= REFDEFFLAG_TELEPORTED;
 303                 if (input_buttons & BIT(1)) refdefflags |= REFDEFFLAG_JUMPING;
 304                 // note: these two only work in WIP2, but are harmless in WIP1
 305                 if (STAT(HEALTH) <= 0 && STAT(HEALTH) != -666 && STAT(HEALTH) != -2342) refdefflags |= REFDEFFLAG_DEAD;
 306                 if (intermission) refdefflags |= REFDEFFLAG_INTERMISSION;
 307                 V_CalcRefdef(view, refdefflags);
 308         }
 309         else
 310         {
 311                 // FIXME by CSQC spec we have to do this:
 312                 // but it breaks chase cam
 313                 /*
 314                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
 315                 setproperty(VF_ANGLES, view_angles);
 316                 */
 317         }
 318         CSQCPLAYER_HOOK_POSTCAMERASETUP();
 319 }
 320
 321 void CSQCPlayer_Remove(entity this)
 322 {
 323         csqcplayer = NULL;
 324         cvar_settemp("cl_movement_replay", "1");
 325 }
 326
 327 bool CSQCPlayer_PreUpdate(entity this)
 328 {
 329         if (this != csqcplayer) return false;
 330         if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
 331         return true;
 332 }
 333
 334 bool CSQCPlayer_PostUpdate(entity this)
 335 {
 336         if (this.entnum != player_localnum + 1) return false;
 337         csqcplayer = this;
 338         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 339         cvar_settemp("cl_movement_replay", "0");
 340         this.entremove = CSQCPlayer_Remove;
 341         return true;
 342 }