qcsrc/lib/csqcmodel/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  * Copyright (c) 2015 Micah Talkiewicz
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy
   6  * of this software and associated documentation files (the "Software"), to
   7  * deal in the Software without restriction, including without limitation the
   8  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   9  * sell copies of the Software, and to permit persons to whom the Software is
  10  * furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice shall be included in
  13  * all copies or substantial portions of the Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  21  * IN THE SOFTWARE.
  22  */
  23 #include "cl_player.qh"
  24
  25 #include "cl_model.qh"
  26 #include "common.qh"
  27 #include "interpolate.qh"
  28
  29 float autocvar_cl_movement_errorcompensation = 0;
  30 bool autocvar_cl_movement_intermissionrunning = false;
  31
  32 // engine stuff
  33 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  34
  35 vector csqcplayer_origin, csqcplayer_velocity;
  36 float csqcplayer_sequence;
  37 int player_pmflags;
  38 float csqcplayer_moveframe;
  39 vector csqcplayer_predictionerroro;
  40 vector csqcplayer_predictionerrorv;
  41 float csqcplayer_predictionerrortime;
  42 float csqcplayer_predictionerrorfactor;
  43
  44 vector CSQCPlayer_GetPredictionErrorO()
  45 {
  46         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  47         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  48 }
  49
  50 vector CSQCPlayer_GetPredictionErrorV()
  51 {
  52         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  53         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  54 }
  55
  56 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
  57 {
  58         // error too big to compensate, we LIKELY hit a teleport or a
  59         // jumppad, or it's a jump time disagreement that'll get fixed
  60         // next frame
  61
  62         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
  63         /*
  64         // commented out as this one did not help
  65         if(onground_diff)
  66         {
  67                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
  68                 return;
  69         }
  70         */
  71         if(vdist(o, >, 32) || vdist(v, >, 192))
  72         {
  73                 //printf("TOO BIG: x=%v v=%v\n", o, v);
  74                 return;
  75         }
  76
  77         if(!autocvar_cl_movement_errorcompensation)
  78         {
  79                 csqcplayer_predictionerrorfactor = 0;
  80                 return;
  81         }
  82
  83         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
  84         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
  85         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ticrate;
  86         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
  87 }
  88
  89 void CSQCPlayer_Unpredict(entity this)
  90 {
  91         if (csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED) return;
  92         if (csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED) LOG_FATALF("Cannot unpredict in current status (%d)", csqcplayer_status);
  93         this.origin = csqcplayer_origin;
  94         this.velocity = csqcplayer_velocity;
  95         csqcplayer_moveframe = csqcplayer_sequence + 1; // + 1 because the recieved frame has the move already done (server side)
  96         this.flags = player_pmflags;
  97 }
  98
  99 void CSQCPlayer_SetMinsMaxs(entity this)
 100 {
 101         if (IS_DUCKED(this) || !(this.isplayermodel & ISPLAYER_PLAYER))
 102         {
 103                 this.mins = PHYS_PL_CROUCH_MIN(this);
 104                 this.maxs = PHYS_PL_CROUCH_MAX(this);
 105                 this.view_ofs = PHYS_PL_CROUCH_VIEWOFS(this);
 106         }
 107         else
 108         {
 109                 this.mins = PHYS_PL_MIN(this);
 110                 this.maxs = PHYS_PL_MAX(this);
 111                 this.view_ofs = PHYS_PL_VIEWOFS(this);
 112         }
 113 }
 114
 115 void CSQCPlayer_SavePrediction(entity this)
 116 {
 117         player_pmflags = this.flags;
 118         csqcplayer_origin = this.origin;
 119         csqcplayer_velocity = this.velocity;
 120         csqcplayer_sequence = servercommandframe;
 121         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 122 }
 123
 124 void CSQC_ClientMovement_PlayerMove_Frame(entity this);
 125
 126 void CSQCPlayer_Physics(entity this)
 127 {
 128         if(!autocvar_cl_movement) { return; }
 129
 130         _Movetype_CheckWater(this); // we apparently need to check water *before* physics so it can use this for water jump
 131
 132         vector oldv_angle = this.v_angle;
 133         vector oldangles = this.angles; // we need to save these, as they're abused by other code
 134         this.v_angle = PHYS_INPUT_ANGLES(this);
 135         this.angles = PHYS_WORLD_ANGLES(this);
 136
 137         CSQC_ClientMovement_PlayerMove_Frame(this);
 138
 139         Movetype_Physics_NoMatchTicrate(this, PHYS_INPUT_TIMELENGTH, true);
 140
 141         view_angles = this.v_angle;
 142         input_angles = this.angles;
 143         this.v_angle = oldv_angle;
 144         this.angles = oldangles;
 145
 146         this.pmove_flags =
 147                         ((IS_DUCKED(this)) ? PMF_DUCKED : 0) |
 148                         ((IS_JUMP_HELD(this)) ? PMF_JUMP_HELD : 0) |
 149                         ((IS_ONGROUND(this)) ? PMF_ONGROUND : 0);
 150 }
 151
 152 void CSQCPlayer_PredictTo(entity this, float endframe, bool apply_error)
 153 {
 154         CSQCPlayer_Unpredict(this);
 155         if (apply_error)
 156         {
 157                 this.origin += CSQCPlayer_GetPredictionErrorO();
 158                 this.velocity += CSQCPlayer_GetPredictionErrorV();
 159         }
 160         CSQCPlayer_SetMinsMaxs(this);
 161
 162         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 163
 164 #if 0
 165         // we don't need this
 166         // darkplaces makes servercommandframe == 0 in these cases anyway
 167         if (STAT(HEALTH) <= 0)
 168         {
 169                 csqcplayer_moveframe = clientcommandframe;
 170                 getinputstate(csqcplayer_moveframe-1);
 171                 LOG_INFO("the Weird code path got hit");
 172                 return;
 173         }
 174 #endif
 175
 176         if (csqcplayer_moveframe >= endframe)
 177         {
 178                 getinputstate(csqcplayer_moveframe - 1);
 179         }
 180         else
 181         {
 182                 do
 183                 {
 184                         if (!getinputstate(csqcplayer_moveframe)) break;
 185                         /*if (input_timelength > 0.0005)
 186                         {
 187                                 if (input_timelength > 0.05)
 188                                 {
 189                                         input_timelength /= 2;
 190                                         CSQCPlayer_Physics(this);
 191                                 }
 192                                 CSQCPlayer_Physics(this);
 193                         }*/
 194                         CSQCPlayer_Physics(this);
 195                         CSQCPlayer_SetMinsMaxs(this);
 196                         ++csqcplayer_moveframe;
 197                 }
 198                 while (csqcplayer_moveframe < endframe);
 199         }
 200
 201         // add in anything that was applied after (for low packet rate protocols)
 202         input_angles = view_angles;
 203 }
 204
 205 bool CSQCPlayer_IsLocalPlayer(entity this)
 206 {
 207         return (this == csqcplayer);
 208 }
 209
 210 float stairsmoothz;
 211 float autocvar_cl_stairsmoothspeed;
 212 float autocvar_cl_smoothviewheight;
 213 float smooth_prevtime;
 214 float viewheightavg;
 215 vector CSQCPlayer_ApplySmoothing(entity this, vector v)
 216 {
 217         if(this.csqcmodel_teleported || !IS_ONGROUND(this) || autocvar_cl_stairsmoothspeed <= 0)
 218                 stairsmoothz = v.z;
 219         else
 220         {
 221                 if(v.z > stairsmoothz)
 222                         v.z = stairsmoothz = bound(v.z - PHYS_STEPHEIGHT(this), stairsmoothz + frametime * autocvar_cl_stairsmoothspeed, v.z);
 223                 else if(v.z < stairsmoothz)
 224                         v.z = stairsmoothz = bound(v.z, stairsmoothz - frametime * autocvar_cl_stairsmoothspeed, v.z + PHYS_STEPHEIGHT(this));
 225         }
 226
 227         float viewheight = bound(0, (time - smooth_prevtime) / max(0.0001, autocvar_cl_smoothviewheight), 1);
 228         viewheightavg = viewheightavg * (1 - viewheight) + this.view_ofs.z * viewheight;
 229         v.z += viewheightavg;
 230
 231         smooth_prevtime = time;
 232
 233         return v;
 234 }
 235
 236 bool autocvar_v_deathtilt;
 237 float autocvar_v_deathtiltangle;
 238 void CSQCPlayer_ApplyDeathTilt(entity this)
 239 {
 240         if(!IS_DEAD(this) || !autocvar_v_deathtilt)
 241                 return;
 242         view_angles.y = autocvar_v_deathtiltangle;
 243 }
 244
 245 float autocvar_v_idlescale;
 246 float autocvar_v_ipitch_cycle;
 247 float autocvar_v_iyaw_cycle;
 248 float autocvar_v_iroll_cycle;
 249 float autocvar_v_ipitch_level;
 250 float autocvar_v_iyaw_level;
 251 float autocvar_v_iroll_level;
 252 void CSQCPlayer_ApplyIdleScaling(entity this)
 253 {
 254         if(!autocvar_v_idlescale)
 255                 return;
 256         view_angles.x += autocvar_v_idlescale * sin(time * autocvar_v_ipitch_cycle) * autocvar_v_ipitch_level;
 257         view_angles.y += autocvar_v_idlescale * sin(time * autocvar_v_iyaw_cycle) * autocvar_v_iyaw_level;
 258         view_angles.z += autocvar_v_idlescale * sin(time * autocvar_v_iroll_cycle) * autocvar_v_iroll_level;
 259         //setproperty(VF_CL_VIEWANGLES, view_angles); // update view angles as well so we can aim
 260 }
 261
 262 float autocvar_cl_bob;
 263 float autocvar_cl_bobcycle;
 264 float autocvar_cl_bob_limit;
 265 float autocvar_cl_bob_limit_heightcheck;
 266 float autocvar_cl_bob_velocity_limit;
 267 float autocvar_cl_bobup;
 268 float autocvar_cl_bobfall;
 269 float autocvar_cl_bobfallcycle;
 270 float autocvar_cl_bobfallminspeed;
 271 float autocvar_cl_bob2;
 272 float autocvar_cl_bob2cycle;
 273 float autocvar_cl_bob2smooth;
 274 float bobfall_swing;
 275 float bobfall_speed;
 276 float bob2_smooth;
 277 vector CSQCPlayer_ApplyBobbing(entity this, vector v)
 278 {
 279         if(IS_DEAD(this))
 280                 return v;
 281
 282         // bounded XY speed, used by several effects below
 283         float xyspeed = bound(0, sqrt(this.velocity.x * this.velocity.x + this.velocity.y * this.velocity.y), autocvar_cl_bob_velocity_limit);
 284         float bob, cycle;
 285
 286         // vertical view bobbing code
 287         if(autocvar_cl_bob && autocvar_cl_bobcycle)
 288         {
 289                 float bob_limit = autocvar_cl_bob_limit;
 290
 291                 if(autocvar_cl_bob_limit_heightcheck)
 292                 {
 293                         // use traces to determine what range the view can bob in, and scale down the bob as needed
 294                         vector bob_height_check_dest = v;
 295                         bob_height_check_dest.z += autocvar_cl_bob_limit * 1.1;
 296                         traceline(v, bob_height_check_dest, MOVE_NOMONSTERS, NULL);
 297                         float trace1fraction = trace_fraction;
 298
 299                         bob_height_check_dest = v;
 300                         bob_height_check_dest.z += autocvar_cl_bob_limit * -0.5;
 301                         traceline(v, bob_height_check_dest, MOVE_NOMONSTERS, NULL);
 302                         float trace2fraction = trace_fraction;
 303
 304                         bob_limit *= min(trace1fraction, trace2fraction);
 305                 }
 306
 307                 // LordHavoc: figured out bobup: the time at which the sin is at 180
 308                 // degrees (which allows lengthening or squishing the peak or valley)
 309                 cycle = time / autocvar_cl_bobcycle;
 310                 cycle -= rint(cycle);
 311                 if(cycle < autocvar_cl_bobup)
 312                         cycle = sin(M_PI * cycle / autocvar_cl_bobup);
 313                 else
 314                         cycle = sin(M_PI + M_PI * (cycle - autocvar_cl_bobup) / (1.0 - autocvar_cl_bobup));
 315                 // bob is proportional to velocity in the xy plane
 316                 // (don't count Z, or jumping messes it up)
 317                 bob = xyspeed * autocvar_cl_bob;
 318                 bob = bound(0, bob, bob_limit);
 319                 bob = bob * 0.3 + bob * 0.7 * cycle;
 320                 v.z += bob;
 321         }
 322
 323         // horizontal view bobbing code
 324         if(autocvar_cl_bob2 && autocvar_cl_bob2cycle)
 325         {
 326                 cycle = time / autocvar_cl_bob2cycle;
 327                 cycle -= rint(cycle);
 328                 if(cycle < 0.5)
 329                         cycle = cos(M_PI * cycle / 0.5); // cos looks better here with the other view bobbing using sin
 330                 else
 331                         cycle = cos(M_PI + M_PI * (cycle - 0.5) / 0.5);
 332                 bob = autocvar_cl_bob2 * cycle;
 333
 334                 // this value slowly decreases from 1 to 0 when we stop touching the ground.
 335                 // The cycle is later multiplied with it so the view smooths back to normal
 336                 if(IS_ONGROUND(this) && !(input_buttons & BIT(1))) // also block the effect while the jump button is pressed, to avoid twitches when bunny-hopping
 337                         bob2_smooth = 1;
 338                 else
 339                 {
 340                         if(bob2_smooth > 0)
 341                                 bob2_smooth -= bound(0, autocvar_cl_bob2smooth, 1);
 342                         else
 343                                 bob2_smooth = 0;
 344                 }
 345
 346                 // calculate the front and side of the player between the X and Y axes
 347                 makevectors(view_angles);
 348                 // now get the speed based on those angles. The bounds should match the same value as xyspeed's
 349                 float side = bound(-autocvar_cl_bob_velocity_limit, (this.velocity * v_right) * bob2_smooth, autocvar_cl_bob_velocity_limit);
 350                 float front = bound(-autocvar_cl_bob_velocity_limit, (this.velocity * v_forward) * bob2_smooth, autocvar_cl_bob_velocity_limit);
 351                 v_forward = v_forward * bob;
 352                 v_right = v_right * bob;
 353                 // we use side with forward and front with right, so the bobbing goes
 354                 // to the side when we walk forward and to the front when we strafe
 355                 vector bob2vel;
 356                 bob2vel.x = side * v_forward.x + front * v_right.x + 0 * v_up.x;
 357                 bob2vel.y = side * v_forward.y + front * v_right.y + 0 * v_up.y;
 358                 bob2vel.z = side * v_forward.z + front * v_right.z + 0 * v_up.z;
 359                 v.x += bob2vel.x;
 360                 v.y += bob2vel.y;
 361         }
 362
 363         // fall bobbing code
 364         // causes the view to swing down and back up when touching the ground
 365         if(autocvar_cl_bobfall && autocvar_cl_bobfallcycle)
 366         {
 367                 if(!IS_ONGROUND(this))
 368                 {
 369                         bobfall_speed = bound(-400, this.velocity.z, 0) * bound(0, autocvar_cl_bobfall, 0.1);
 370                         if(this.velocity.z < -autocvar_cl_bobfallminspeed)
 371                                 bobfall_swing = 1;
 372                         else
 373                                 bobfall_swing = 0; // really?
 374                 }
 375                 else
 376                 {
 377                         bobfall_swing = max(0, bobfall_swing - autocvar_cl_bobfallcycle * frametime);
 378                         float bobfall = sin(M_PI * bobfall_swing) * bobfall_speed;
 379                         v.z += bobfall;
 380                 }
 381         }
 382
 383         return v;
 384 }
 385
 386 float autocvar_cl_rollangle;
 387 float autocvar_cl_rollspeed;
 388 float CSQCPlayer_CalcRoll(entity this)
 389 {
 390         makevectors(view_angles);
 391         float side = (this.velocity * v_right);
 392         float sign = (side < 0) ? -1 : 1;
 393         side = fabs(side);
 394
 395         if(side < autocvar_cl_rollspeed)
 396                 side = side * autocvar_cl_rollangle / autocvar_cl_rollspeed;
 397         else
 398                 side = autocvar_cl_rollangle;
 399
 400         return side * sign;
 401 }
 402
 403 float autocvar_chase_back;
 404 float autocvar_chase_up;
 405 bool autocvar_chase_overhead;
 406 float autocvar_chase_pitchangle;
 407 vector CSQCPlayer_ApplyChase(entity this, vector v)
 408 {
 409         // don't need to do offset for view height here, it's done in smoothing!
 410         //v += this.view_ofs;
 411         vector forward;
 412         vector chase_dest;
 413
 414         if(autocvar_chase_overhead)
 415         {
 416                 view_angles.x = 0;
 417                 makevectors(view_angles);
 418                 forward = v_forward;
 419                 vector up = v_up;
 420                 // trace a little further so it hits a surface more consistently (to avoid 'snapping' on the edge of the range)
 421                 chase_dest.x = v.x - forward.x * autocvar_chase_back + up.x * autocvar_chase_up;
 422                 chase_dest.y = v.y - forward.y * autocvar_chase_back + up.y * autocvar_chase_up;
 423                 chase_dest.z = v.z - forward.z * autocvar_chase_back + up.z * autocvar_chase_up;
 424
 425                 // trace from first person view location to our chosen third person view location
 426                 traceline(v, chase_dest, MOVE_NOMONSTERS, NULL);
 427
 428                 vector bestvieworg = trace_endpos;
 429                 vector offset = '0 0 0';
 430                 for(offset.x = -16; offset.x <= 16; offset.x += 8)
 431                 {
 432                         for(offset.y = -16; offset.y <= 16; offset.y += 8)
 433                         {
 434                                 makevectors(view_angles);
 435                                 up = v_up;
 436                                 chase_dest.x = v.x - forward.x * autocvar_chase_back + up.x * autocvar_chase_up + offset.x;
 437                                 chase_dest.y = v.y - forward.y * autocvar_chase_back + up.y * autocvar_chase_up + offset.y;
 438                                 chase_dest.z = v.z - forward.z * autocvar_chase_back + up.z * autocvar_chase_up + offset.z;
 439                                 traceline(v, chase_dest, MOVE_NOMONSTERS, NULL);
 440                                 if(bestvieworg.z > trace_endpos.z)
 441                                         bestvieworg.z = trace_endpos.z;
 442                         }
 443                 }
 444                 bestvieworg.z -= 8;
 445                 v = bestvieworg;
 446
 447                 view_angles.x = autocvar_chase_pitchangle;
 448                 //setproperty(VF_CL_VIEWANGLES, view_angles); // update view angles as well so we can aim
 449         }
 450         else
 451         {
 452                 makevectors(view_angles);
 453                 forward = v_forward;
 454                 // trace a little further so it hits a surface more consistently (to avoid 'snapping' on the edge of the range)
 455                 float cdist = -autocvar_chase_back - 8;
 456                 chase_dest.x = v.x + forward.x * cdist;
 457                 chase_dest.y = v.y + forward.y * cdist;
 458                 chase_dest.z = v.z + forward.z * cdist + autocvar_chase_up;
 459                 traceline(v, chase_dest, MOVE_NOMONSTERS, NULL);
 460                 v.x = 1 * trace_endpos.x + 8 * forward.x + 4 * trace_plane_normal.x;
 461                 v.y = 1 * trace_endpos.y + 8 * forward.y + 4 * trace_plane_normal.y;
 462                 v.z = 1 * trace_endpos.z + 8 * forward.z + 4 * trace_plane_normal.z;
 463         }
 464
 465 #if 0
 466         tracebox(v, '-4 -4 -4', '4 4 4', v - v_forward * autocvar_chase_back, MOVE_NORMAL, this);
 467         v = trace_endpos;
 468         tracebox(v, '-4 -4 -4', '4 4 4', v + v_up * autocvar_chase_up, MOVE_NORMAL, this);
 469         v = trace_endpos;
 470 #endif
 471         return v;
 472 }
 473
 474 bool autocvar_cl_useenginerefdef;
 475
 476 /** Called once per CSQC_UpdateView() */
 477 void CSQCPlayer_SetCamera()
 478 {
 479         vector v0 = ((intermission && !autocvar_cl_movement_intermissionrunning) ? '0 0 0' : pmove_vel); // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 480         float vh = PHYS_VIEWHEIGHT(NULL);
 481         vector pl_viewofs = PHYS_PL_VIEWOFS(NULL);
 482         vector pl_viewofs_crouch = PHYS_PL_CROUCH_VIEWOFS(NULL);
 483         entity e = csqcplayer;
 484         if (e)
 485         {
 486                 if (servercommandframe == 0 || clientcommandframe == 0)
 487                 {
 488                         InterpolateOrigin_Do(e);
 489                         e.view_ofs = '0 0 1' * vh;
 490
 491                         // get crouch state from the server
 492                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 493                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 494
 495                         // get onground state from the server
 496                         e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 497
 498                         CSQCPlayer_SetMinsMaxs(e);
 499
 500                         // override it back just in case
 501                         e.view_ofs = '0 0 1' * vh;
 502
 503                         // set velocity
 504                         e.velocity = v0;
 505                 }
 506                 else
 507                 {
 508                         int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
 509                         InterpolateOrigin_Do(e);
 510                         e.iflags = flg;
 511
 512                         if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 513                         {
 514                                 vector o = e.origin;
 515                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 516                                 CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
 517                                 CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - IS_ONGROUND(e));
 518                                 e.origin = o;
 519                                 e.velocity = v0;
 520
 521                                 // get crouch state from the server
 522                                 if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 523                                 else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 524
 525                                 // get onground state from the server
 526                                 e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 527
 528                                 CSQCPlayer_SavePrediction(e);
 529                         }
 530                         CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
 531
 532 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
 533                         // get crouch state from the server (LAG)
 534                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 535                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 536 #endif
 537                         CSQCPlayer_SetMinsMaxs(e);
 538
 539                         e.angles_y = input_angles.y;
 540                 }
 541
 542                 // relink
 543                 setorigin(e, e.origin);
 544         }
 545
 546         const entity view = CSQCModel_server2csqc(player_localentnum - 1);
 547         if (view)
 548         {
 549                 if (view != csqcplayer)
 550                 {
 551                         InterpolateOrigin_Do(view);
 552                         view.view_ofs = '0 0 1' * vh;
 553                 }
 554                 if(autocvar_cl_useenginerefdef)
 555                 {
 556                         int refdefflags = 0;
 557                         if (view.csqcmodel_teleported) refdefflags |= REFDEFFLAG_TELEPORTED;
 558                         if (input_buttons & BIT(1)) refdefflags |= REFDEFFLAG_JUMPING;
 559                         // note: these two only work in WIP2, but are harmless in WIP1
 560                         if (PHYS_HEALTH(NULL) <= 0 && PHYS_HEALTH(NULL) != -666 && PHYS_HEALTH(NULL) != -2342) refdefflags |= REFDEFFLAG_DEAD;
 561                         if (intermission) refdefflags |= REFDEFFLAG_INTERMISSION;
 562                         V_CalcRefdef(view, refdefflags); // TODO? uses .health stat in the engine when this isn't called here, may be broken!
 563                 }
 564                 else
 565                 {
 566                         vector vieworg = view.origin;
 567                         vieworg = CSQCPlayer_ApplySmoothing(view, vieworg);
 568                         if(autocvar_chase_active)
 569                                 vieworg = CSQCPlayer_ApplyChase(view, vieworg);
 570                         else
 571                         {
 572                                 // angles
 573                                 CSQCPlayer_ApplyDeathTilt(view);
 574                                 view_angles = view_angles + view_punchangle;
 575                                 view_angles.z += CSQCPlayer_CalcRoll(view);
 576                                 // TODO? we don't have damage time accessible here
 577                                 // origin
 578                                 vieworg = vieworg + view_punchvector;
 579                                 vieworg = CSQCPlayer_ApplyBobbing(view, vieworg);
 580                                 CSQCPlayer_ApplyIdleScaling(view);
 581                         }
 582                         setproperty(VF_ORIGIN, vieworg);
 583                         setproperty(VF_ANGLES, view_angles);
 584                 }
 585
 586         }
 587         else
 588         {
 589                 // FIXME by CSQC spec we have to do this:
 590                 // but it breaks chase cam
 591                 /*
 592                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
 593                 setproperty(VF_ANGLES, view_angles);
 594                 */
 595         }
 596         CSQCPLAYER_HOOK_POSTCAMERASETUP();
 597 }
 598
 599 void CSQCPlayer_Remove(entity this)
 600 {
 601         csqcplayer = NULL;
 602         cvar_settemp("cl_movement_replay", "1");
 603 }
 604
 605 bool CSQCPlayer_PreUpdate(entity this)
 606 {
 607         if (this != csqcplayer) return false;
 608         if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
 609         return true;
 610 }
 611
 612 bool CSQCPlayer_PostUpdate(entity this)
 613 {
 614         if (this.entnum != player_localnum + 1) return false;
 615         csqcplayer = this;
 616         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 617         cvar_settemp("cl_movement_replay", "0");
 618         this.entremove = CSQCPlayer_Remove;
 619         return true;
 620 }