qcsrc/lib/csqcmodel/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  * Copyright (c) 2015 Micah Talkiewicz
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy
   6  * of this software and associated documentation files (the "Software"), to
   7  * deal in the Software without restriction, including without limitation the
   8  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   9  * sell copies of the Software, and to permit persons to whom the Software is
  10  * furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice shall be included in
  13  * all copies or substantial portions of the Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  21  * IN THE SOFTWARE.
  22  */
  23 #include "cl_player.qh"
  24
  25 #include "cl_model.qh"
  26 #include "common.qh"
  27 #include "interpolate.qh"
  28 #include "../../client/defs.qh"
  29 #include "../../client/main.qh"
  30 #include "../../common/constants.qh"
  31 #include "../../common/physics.qh"
  32 #include "../../common/stats.qh"
  33 #include "../../common/triggers/trigger/viewloc.qh"
  34 #include "../../common/util.qh"
  35 #include "../../common/viewloc.qh"
  36
  37 float autocvar_cl_movement_errorcompensation = 0;
  38
  39 // engine stuff
  40 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  41
  42 vector csqcplayer_origin, csqcplayer_velocity;
  43 float csqcplayer_sequence;
  44 int player_pmflags;
  45 float csqcplayer_moveframe;
  46 vector csqcplayer_predictionerroro;
  47 vector csqcplayer_predictionerrorv;
  48 float csqcplayer_predictionerrortime;
  49 float csqcplayer_predictionerrorfactor;
  50
  51 vector CSQCPlayer_GetPredictionErrorO()
  52 {
  53         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  54         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  55 }
  56
  57 vector CSQCPlayer_GetPredictionErrorV()
  58 {
  59         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  60         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  61 }
  62
  63 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
  64 {
  65         // error too big to compensate, we LIKELY hit a teleport or a
  66         // jumppad, or it's a jump time disagreement that'll get fixed
  67         // next frame
  68
  69         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
  70         /*
  71         // commented out as this one did not help
  72         if(onground_diff)
  73         {
  74                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
  75                 return;
  76         }
  77         */
  78         if(vlen(o) > 32 || vlen(v) > 192)
  79         {
  80                 //printf("TOO BIG: x=%v v=%v\n", o, v);
  81                 return;
  82         }
  83
  84         if(!autocvar_cl_movement_errorcompensation)
  85         {
  86                 csqcplayer_predictionerrorfactor = 0;
  87                 return;
  88         }
  89
  90         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
  91         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
  92         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ticrate;
  93         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
  94 }
  95
  96 void CSQCPlayer_Unpredict(entity this)
  97 {
  98         if (csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED) return;
  99         if (csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED) LOG_FATALF("Cannot unpredict in current status (%d)\n", csqcplayer_status);
 100         this.origin = csqcplayer_origin;
 101         this.velocity = csqcplayer_velocity;
 102         csqcplayer_moveframe = csqcplayer_sequence + 1; // + 1 because the recieved frame has the move already done (server side)
 103         this.flags = player_pmflags;
 104 }
 105
 106 void CSQCPlayer_SetMinsMaxs(entity this)
 107 {
 108         if (this.flags & FL_DUCKED)
 109         {
 110                 this.mins = PL_CROUCH_MIN;
 111                 this.maxs = PL_CROUCH_MAX;
 112                 this.view_ofs = PL_CROUCH_VIEW_OFS;
 113         }
 114         else
 115         {
 116                 this.mins = PL_MIN;
 117                 this.maxs = PL_MAX;
 118                 this.view_ofs = PL_VIEW_OFS;
 119         }
 120 }
 121
 122 void CSQCPlayer_SavePrediction(entity this)
 123 {
 124         player_pmflags = this.flags;
 125         csqcplayer_origin = this.origin;
 126         csqcplayer_velocity = this.velocity;
 127         csqcplayer_sequence = servercommandframe;
 128         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 129 }
 130
 131 void CSQC_ClientMovement_PlayerMove_Frame(entity this);
 132 void _Movetype_Physics_ClientFrame(entity this, float movedt);
 133
 134 void Movetype_Physics_Spam(entity this)  // optimized
 135 {
 136         _Movetype_Physics_ClientFrame(this, PHYS_INPUT_TIMELENGTH);
 137         if(wasfreed(this))
 138                 return;
 139
 140         this.avelocity = this.move_avelocity;
 141         this.velocity = this.move_velocity;
 142         this.angles = this.move_angles;
 143         this.flags = BITSET(this.flags, FL_ONGROUND, boolean(this.move_flags & FL_ONGROUND));
 144         this.flags = BITSET(this.flags, FL_WATERJUMP, boolean(this.move_flags & FL_WATERJUMP));
 145         this.waterlevel = this.move_waterlevel;
 146         this.watertype = this.move_watertype;
 147         setorigin(this, this.move_origin);
 148 }
 149
 150 void CSQCPlayer_Physics(entity this)
 151 {
 152         if(autocvar_cl_movement)
 153         {
 154                 CSQC_ClientMovement_PlayerMove_Frame(this);
 155
 156                 if(autocvar_cl_movement == 3)
 157                 {
 158                         this.move_origin = this.origin;
 159                         this.move_angles = this.angles;
 160                         //this.move_movetype = MOVETYPE_WALK; // temp
 161                         this.move_velocity = this.velocity;
 162                         this.move_avelocity = this.avelocity;
 163                         this.move_flags = BITSET(this.move_flags, FL_ONGROUND, boolean(this.flags & FL_ONGROUND));
 164                         this.move_flags = BITSET(this.move_flags, FL_WATERJUMP, boolean(this.flags & FL_WATERJUMP));
 165                         this.move_waterlevel = this.waterlevel;
 166                         this.move_watertype = this.watertype;
 167                         Movetype_Physics_Spam(this);
 168                 }
 169
 170                 this.pmove_flags =
 171                                 ((this.flags & FL_DUCKED) ? PMF_DUCKED : 0) |
 172                                 (!(this.flags & FL_JUMPRELEASED) ? PMF_JUMP_HELD : 0) |
 173                                 ((this.flags & FL_ONGROUND) ? PMF_ONGROUND : 0);
 174         }
 175 }
 176
 177 void CSQCPlayer_PredictTo(entity this, float endframe, bool apply_error)
 178 {
 179         CSQCPlayer_Unpredict(this);
 180         if (apply_error)
 181         {
 182                 this.origin += CSQCPlayer_GetPredictionErrorO();
 183                 this.velocity += CSQCPlayer_GetPredictionErrorV();
 184         }
 185         CSQCPlayer_SetMinsMaxs(this);
 186
 187         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 188
 189 #if 0
 190         // we don't need this
 191         // darkplaces makes servercommandframe == 0 in these cases anyway
 192         if (getstatf(STAT_HEALTH) <= 0)
 193         {
 194                 csqcplayer_moveframe = clientcommandframe;
 195                 getinputstate(csqcplayer_moveframe-1);
 196                 LOG_INFO("the Weird code path got hit\n");
 197                 return;
 198         }
 199 #endif
 200
 201         if (csqcplayer_moveframe >= endframe)
 202         {
 203                 getinputstate(csqcplayer_moveframe - 1);
 204         }
 205         else
 206         {
 207                 do
 208                 {
 209                         if (!getinputstate(csqcplayer_moveframe)) break;
 210                         CSQCPlayer_Physics(this);
 211                         CSQCPlayer_SetMinsMaxs(this);
 212                         ++csqcplayer_moveframe;
 213                 }
 214                 while (csqcplayer_moveframe < endframe);
 215         }
 216
 217         // add in anything that was applied after (for low packet rate protocols)
 218         input_angles = view_angles;
 219 }
 220
 221 bool CSQCPlayer_IsLocalPlayer(entity this)
 222 {
 223         return (this == csqcplayer);
 224 }
 225
 226 void CSQCPlayer_SetViewLocation()
 227 {
 228         viewloc_SetViewLocation();
 229 }
 230
 231 /** Called once per CSQC_UpdateView() */
 232 void CSQCPlayer_SetCamera()
 233 {
 234         const vector v0 = pmove_vel; // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 235         const float vh = getstati(STAT_VIEWHEIGHT);
 236         const vector pl_viewofs = PL_VIEW_OFS;
 237         const vector pl_viewofs_crouch = PL_CROUCH_VIEW_OFS;
 238         const entity e = csqcplayer;
 239         if (e)
 240         {
 241                 if (servercommandframe == 0 || clientcommandframe == 0)
 242                 {
 243                         InterpolateOrigin_Do(e);
 244                         e.view_ofs = '0 0 1' * vh;
 245
 246                         // get crouch state from the server
 247                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 248                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 249
 250                         // get onground state from the server
 251                         e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 252
 253                         CSQCPlayer_SetMinsMaxs(e);
 254
 255                         // override it back just in case
 256                         e.view_ofs = '0 0 1' * vh;
 257
 258                         // set velocity
 259                         e.velocity = v0;
 260                 }
 261                 else
 262                 {
 263                         const int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
 264                         InterpolateOrigin_Do(e);
 265                         e.iflags = flg;
 266
 267                         if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 268                         {
 269                                 const vector o = e.origin;
 270                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 271                                 CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
 272                                 CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - boolean(e.flags & FL_ONGROUND));
 273                                 e.origin = o;
 274                                 e.velocity = v0;
 275
 276                                 // get crouch state from the server
 277                                 if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 278                                 else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 279
 280                                 // get onground state from the server
 281                                 e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 282
 283                                 CSQCPlayer_SavePrediction(e);
 284                         }
 285                         CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
 286
 287 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
 288                         // get crouch state from the server (LAG)
 289                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 290                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 291 #endif
 292                         CSQCPlayer_SetMinsMaxs(e);
 293
 294                         e.angles_y = input_angles.y;
 295                 }
 296
 297                 // relink
 298                 setorigin(e, e.origin);
 299         }
 300
 301         const entity view = CSQCModel_server2csqc(player_localentnum - 1);
 302         if (view)
 303         {
 304                 if (view != csqcplayer)
 305                 {
 306                         InterpolateOrigin_Do(view);
 307                         view.view_ofs = '0 0 1' * vh;
 308                 }
 309                 int refdefflags = 0;
 310                 if (view.csqcmodel_teleported) refdefflags |= REFDEFFLAG_TELEPORTED;
 311                 if (input_buttons & BIT(1)) refdefflags |= REFDEFFLAG_JUMPING;
 312                 // note: these two only work in WIP2, but are harmless in WIP1
 313                 if (getstati(STAT_HEALTH) <= 0) refdefflags |= REFDEFFLAG_DEAD;
 314                 if (intermission) refdefflags |= REFDEFFLAG_INTERMISSION;
 315                 V_CalcRefdef(view, refdefflags);
 316         }
 317         else
 318         {
 319                 // FIXME by CSQC spec we have to do this:
 320                 // but it breaks chase cam
 321                 /*
 322                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
 323                 setproperty(VF_ANGLES, view_angles);
 324                 */
 325         }
 326         CSQCPLAYER_HOOK_POSTCAMERASETUP();
 327 }
 328
 329 void CSQCPlayer_Remove()
 330 {
 331         csqcplayer = NULL;
 332         cvar_settemp("cl_movement_replay", "1");
 333 }
 334
 335 bool CSQCPlayer_PreUpdate(entity this)
 336 {
 337         if (this != csqcplayer) return false;
 338         if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
 339         return true;
 340 }
 341
 342 bool CSQCPlayer_PostUpdate(entity this)
 343 {
 344         if (this.entnum != player_localnum + 1) return false;
 345         csqcplayer = this;
 346         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 347         cvar_settemp("cl_movement_replay", "0");
 348         this.entremove = CSQCPlayer_Remove;
 349         return true;
 350 }