207647e0d171af30736e100c76e13d434cb88dab
[xonotic/xonotic-data.pk3dir.git] / qcsrc / lib / csqcmodel / sv_model.qc
1 /*
2  * Copyright (c) 2011 Rudolf Polzer
3  *
4  * Permission is hereby granted, free of charge, to any person obtaining a copy
5  * of this software and associated documentation files (the "Software"), to
6  * deal in the Software without restriction, including without limitation the
7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
8  * sell copies of the Software, and to permit persons to whom the Software is
9  * furnished to do so, subject to the following conditions:
10  *
11  * The above copyright notice and this permission notice shall be included in
12  * all copies or substantial portions of the Software.
13  *
14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
20  * IN THE SOFTWARE.
21  */
22 #include "sv_model.qh"
23
24 #include "common.qh"
25 #include "../../common/animdecide.qh"
26 #include "../../common/constants.qh"
27 #include "../../common/util.qh"
28 #include "../../server/constants.qh"
29 #include "../../server/defs.qh"
30
31 // generic CSQC model code
32
33 bool CSQCModel_Send(entity to, int sf)
34 {SELFPARAM();
35         // some nice flags for CSQCMODEL_IF
36         float isplayer = (IS_CLIENT(self));
37         float islocalplayer = (self == to);
38         float isnolocalplayer = (isplayer && (self != to));
39
40         unused_float = isplayer;
41         unused_float = islocalplayer;
42         unused_float = isnolocalplayer;
43
44         WriteHeader(MSG_ENTITY, ENT_CLIENT_MODEL);
45         WriteInt24_t(MSG_ENTITY, sf);
46
47 #define CSQCMODEL_IF(cond) if(cond) {
48 #define CSQCMODEL_ENDIF }
49 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
50         if(sf & flag) \
51         { \
52                 w(MSG_ENTITY, self.csqcmodel_##f); \
53         }
54 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,t,r,w,f)
55         ALLPROPERTIES
56 #undef CSQCMODEL_PROPERTY_SCALED
57 #undef CSQCMODEL_PROPERTY
58 #undef CSQCMODEL_ENDIF
59 #undef CSQCMODEL_IF
60
61         return true;
62 }
63
64 #if CSQCPLAYER_FORCE_UPDATES
65 .float csqcmodel_nextforcedupdate;
66 #endif
67 void CSQCModel_CheckUpdate(entity e)
68 {
69         // some nice flags for CSQCMODEL_IF
70         float isplayer = (IS_CLIENT(e));
71         float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
72         float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
73
74         unused_float = isplayer;
75         unused_float = islocalplayer;
76         unused_float = isnolocalplayer;
77
78 #if CSQCPLAYER_FORCE_UPDATES
79         if(isplayer && time > e.csqcmodel_nextforcedupdate)
80         {
81                 e.SendFlags |= CSQCMODEL_PROPERTY_ORIGIN;
82                 e.csqcmodel_nextforcedupdate = time + (1 / (CSQCPLAYER_FORCE_UPDATES)) * (0.5 + random()); // ensure about 4 origin sends per sec
83         }
84 #endif
85
86         if(e.effects & EF_RESTARTANIM_BIT)
87         {
88                 e.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
89                 e.effects &= ~EF_RESTARTANIM_BIT;
90         }
91
92         if(e.effects & EF_TELEPORT_BIT)
93         {
94                 e.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
95                 e.effects &= ~EF_TELEPORT_BIT;
96         }
97
98 #define CSQCMODEL_IF(cond) if(cond) {
99 #define CSQCMODEL_ENDIF }
100 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
101         { \
102                 t tmp = e.f; \
103                 if(tmp != e.csqcmodel_##f) \
104                 { \
105                         e.csqcmodel_##f = tmp; \
106                         e.SendFlags |= flag; \
107                 } \
108         }
109 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
110         { \
111                 t tmp = rint(bound(mi, s * e.f, ma) - mi); \
112                 if(tmp != e.csqcmodel_##f) \
113                 { \
114                         e.csqcmodel_##f = tmp; \
115                         e.SendFlags |= flag; \
116                 } \
117         }
118         ALLPROPERTIES
119 #undef CSQCMODEL_PROPERTY_SCALED
120 #undef CSQCMODEL_PROPERTY
121 #undef CSQCMODEL_ENDIF
122 #undef CSQCMODEL_IF
123 }
124
125 void CSQCModel_LinkEntity(entity e)
126 {
127         e.SendEntity = CSQCModel_Send;
128         e.SendFlags = 0xFFFFFF;
129         CSQCModel_CheckUpdate(e);
130 }
131
132 void CSQCModel_UnlinkEntity(entity e)
133 {
134         e.SendEntity = func_null;
135 }