qcsrc/lib/net.qh

   1 #pragma once
   2
   3 #include "registry.qh"
   4 #include "sort.qh"
   5 #include "yenc.qh"
   6
   7 // netcode mismatch and not sure what caused it? developer_csqcentities 1
   8
   9 .string netname;
  10 .int m_id;
  11 .bool(entity this, entity sender, bool isNew) m_read;
  12 #define NET_HANDLE(id, param) bool Net_Handle_##id(entity this, entity sender, param)
  13
  14 #define NET_GUARD(id) \
  15     bool Net_Handle_##id##_guard(entity this, entity sender, bool isNew) { \
  16         bool valid = false; \
  17         serialize_marker(to, valid); \
  18         if (!valid) LOG_FATALF("Last message not fully parsed: %s", _net_prevmsgstr); \
  19         _net_prevmsgstr = #id; \
  20         return Net_Handle_##id(this, sender, isNew); \
  21     }
  22
  23 #ifdef CSQC
  24 string _net_prevmsgstr;
  25         #define REGISTER_NET_TEMP(id) \
  26                 NET_HANDLE(id, bool); \
  27         NET_GUARD(id); \
  28                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) { \
  29                         this.netname = #id; \
  30                         this.m_read = Net_Handle_##id##_guard; \
  31                 }
  32 #else
  33         #define REGISTER_NET_TEMP(id) \
  34                 const bool NET_##id##_istemp = true; \
  35                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  36                 { \
  37                         this.netname = #id; \
  38                 }
  39 #endif
  40 #define REGISTER_NET_S2C(id) REGISTER_NET_TEMP(id)
  41
  42 REGISTRY(TempEntities, BITS(8) - 80)
  43 #define TempEntities_from(i) _TempEntities_from(i, NULL)
  44 REGISTER_REGISTRY(TempEntities)
  45 REGISTRY_SORT(TempEntities)
  46 REGISTRY_CHECK(TempEntities)
  47 STATIC_INIT(TempEntities_renumber) { FOREACH(TempEntities, true, it.m_id = 80 + i); }
  48
  49
  50
  51 #ifdef CSQC
  52         #define REGISTER_NET_LINKED(id) \
  53                 ACCUMULATE NET_HANDLE(id, bool isnew) \
  54                 { \
  55                         this = __self; \
  56                         this.sourceLoc = __FILE__ ":" STR(__LINE__); \
  57                         if (!this) isnew = true; \
  58                 } \
  59                 NET_GUARD(id); \
  60                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  61                 { \
  62                         this.netname = #id; \
  63                         this.m_read = Net_Handle_##id##_guard; \
  64                 }
  65 #else
  66         #define REGISTER_NET_LINKED(id) \
  67                 const bool NET_##id##_istemp = false; \
  68                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  69                 { \
  70                         this.netname = #id; \
  71                 }
  72 #endif
  73
  74 REGISTRY(LinkedEntities, BITS(8) - 1)
  75 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
  76 REGISTER_REGISTRY(LinkedEntities)
  77 REGISTRY_SORT(LinkedEntities)
  78 REGISTRY_CHECK(LinkedEntities)
  79 STATIC_INIT(LinkedEntities_renumber) { FOREACH(LinkedEntities, true, it.m_id = 1 + i); }
  80
  81
  82
  83 #ifdef SVQC
  84         #define REGISTER_NET_C2S(id) \
  85                 NET_HANDLE(id, bool); \
  86                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  87                 { \
  88                         this.netname = #id; \
  89                         this.m_read = Net_Handle_##id; \
  90                 }
  91 #else
  92         #define REGISTER_NET_C2S(id) \
  93                 const bool NET_##id##_istemp = true; \
  94                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  95                 { \
  96                         this.netname = #id; \
  97                 }
  98 #endif
  99
 100 REGISTRY(C2S_Protocol, BITS(8) - 1)
 101 #define C2S_Protocol_from(i) _C2S_Protocol_from(i, NULL)
 102 REGISTER_REGISTRY(C2S_Protocol)
 103 REGISTRY_SORT(C2S_Protocol)
 104 REGISTRY_CHECK(C2S_Protocol)
 105 STATIC_INIT(C2S_Protocol_renumber) { FOREACH(C2S_Protocol, true, it.m_id = i); }
 106
 107 #ifdef SVQC
 108         const int MSG_ENTITY = 5;
 109
 110         .int SendFlags;
 111
 112         IntrusiveList g_uncustomizables;
 113         STATIC_INIT(g_uncustomizables) { g_uncustomizables = IL_NEW(); }
 114
 115         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
 116         {
 117                 if (e.classname == "") e.classname = "net_linked";
 118
 119                 if (e.model == "" || e.modelindex == 0)
 120                 {
 121                         vector mi = e.mins;
 122                         vector ma = e.maxs;
 123                         _setmodel(e, "null");
 124                         setsize(e, mi, ma);
 125                 }
 126
 127                 setSendEntity(e, sendfunc);
 128                 e.SendFlags = 0xFFFFFF;
 129
 130                 if (!docull) e.effects |= EF_NODEPTHTEST;
 131
 132                 if (dt)
 133                 {
 134                         e.nextthink = time + dt;
 135                         setthink(e, SUB_Remove);
 136                 }
 137         }
 138
 139         void Net_UnlinkEntity(entity e)
 140         {
 141                 setSendEntity(e, func_null);
 142         }
 143
 144         .void(entity this) uncustomizeentityforclient;
 145         .float uncustomizeentityforclient_set;
 146
 147         void SetCustomizer(entity e, bool(entity this, entity client) customizer, void(entity this) uncustomizer)
 148         {
 149                 setcefc(e, customizer);
 150                 e.uncustomizeentityforclient = uncustomizer;
 151                 e.uncustomizeentityforclient_set = !!uncustomizer;
 152                 if(uncustomizer)
 153                         IL_PUSH(g_uncustomizables, e);
 154         }
 155
 156         void UncustomizeEntitiesRun()
 157         {
 158                 IL_EACH(g_uncustomizables, it.uncustomizeentityforclient_set, it.uncustomizeentityforclient(it));
 159         }
 160
 161         STRING_ITERATOR(g_buf, string_null, 0);
 162
 163         int ReadByte();
 164
 165         void Net_ClientCommand(entity sender, string command)
 166         {
 167                 // command matches `c2s "(.+)"`
 168                 string buf = substring(command, argv_start_index(1) + 1, -2);
 169                 if (buf == "") return;
 170                 STRING_ITERATOR_SET(g_buf, buf, 0);
 171                 for (int C2S; (C2S = ReadByte()) >= 0; )
 172                 {
 173                         entity reader = C2S_Protocol_from(C2S);
 174                         if (reader && reader.m_read && reader.m_read(NULL, sender, true)) continue;
 175                         LOG_SEVEREF("Net_ClientCommand() with malformed C2S=%d", C2S);
 176                         return;
 177                 }
 178                 g_buf_i--;
 179                 int expected = strlen(buf);
 180                 if (g_buf_i > expected) LOG_WARNF("Underflow: %d", g_buf_i - expected);
 181                 if (g_buf_i < expected) LOG_WARNF("Overrflow: %d", expected - g_buf_i);
 182         }
 183
 184 #endif
 185
 186 #ifdef CSQC
 187         const int MSG_C2S = 0;
 188
 189         #define Net_Accept(classname) \
 190                 MACRO_BEGIN \
 191                         if (!this) this = new(classname); \
 192                 MACRO_END
 193         #define Net_Reject() \
 194                 MACRO_BEGIN \
 195                         if (this) delete(this); \
 196                 MACRO_END
 197
 198         string g_buf;
 199
 200         void Net_Flush()
 201         {
 202                 if (g_buf == "") return;
 203                 localcmd("\ncmd c2s \"", strreplace("$", "$$", g_buf), "\"\n");
 204                 strfree(g_buf);
 205         }
 206 #endif
 207
 208 #if defined(CSQC)
 209         #define WriteHeader(to, id) \
 210                 WriteByte(to, NET_##id.m_id)
 211 #elif defined(SVQC)
 212         #define WriteHeader(to, id) \
 213                 MACRO_BEGIN \
 214                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
 215                         WriteByte(to, NET_##id.m_id); \
 216                         bool _net_valid = false; serialize_marker(to, _net_valid); \
 217                 MACRO_END
 218 #endif
 219
 220 // serialization: new style
 221
 222 USING(Stream, int);
 223 #if defined(SVQC)
 224         #define stream_reading(stream) false
 225         #define stream_writing(stream) true
 226 #elif defined(CSQC)
 227         #define stream_reading(stream) true
 228         #define stream_writing(stream) false
 229 #endif
 230
 231 #define serialize(T, stream, ...) \
 232 MACRO_BEGIN \
 233     noref Stream _stream = stream; \
 234     serialize_##T(_stream, __VA_ARGS__); \
 235 MACRO_END
 236
 237 #if defined(SVQC)
 238         #define serialize_byte(stream, this) \
 239                 MACRO_BEGIN \
 240                 WriteByte(stream, this); \
 241                 MACRO_END
 242 #elif defined(CSQC)
 243         #define serialize_byte(stream, this) \
 244                 MACRO_BEGIN \
 245                 this = ReadByte(); \
 246                 MACRO_END
 247 #endif
 248
 249 #if defined(SVQC)
 250         #define serialize_float(stream, this) \
 251                 MACRO_BEGIN \
 252                 WriteCoord(stream, this); \
 253                 MACRO_END
 254 #elif defined(CSQC)
 255         #define serialize_float(stream, this) \
 256                 MACRO_BEGIN \
 257                 this = ReadCoord(); \
 258                 MACRO_END
 259 #endif
 260
 261 #define serialize_vector(stream, this) \
 262 MACRO_BEGIN \
 263     vector _v = this; \
 264     serialize_float(stream, _v.x); \
 265     serialize_float(stream, _v.y); \
 266     serialize_float(stream, _v.z); \
 267     this = _v; \
 268 MACRO_END
 269
 270 #define serialize_marker(stream, this) \
 271 MACRO_BEGIN \
 272     if (NDEBUG) { \
 273         this = true; \
 274     } else { \
 275         int _de = 0xDE, _ad = 0xAD, _be = 0xBE, _ef = 0xEF; \
 276         serialize_byte(stream, _de); \
 277         serialize_byte(stream, _ad); \
 278         serialize_byte(stream, _be); \
 279         serialize_byte(stream, _ef); \
 280         this = (_de == 0xDE && _ad == 0xAD && _be == 0xBE && _ef == 0xEF); \
 281     } \
 282 MACRO_END
 283
 284 // serialization: old
 285
 286 #define ReadRegistered(r) r##_from(Read_byte())
 287 #define WriteRegistered(r, to, it) Write_byte(to, it.m_id)
 288
 289 #define Read_byte() ReadByte()
 290 #define Write_byte(to, f) WriteByte(to, f)
 291
 292 #if defined(CSQC)
 293         int ReadByte();
 294         void WriteByte(int to, int b)
 295         {
 296                 assert(to == MSG_C2S);
 297                 string s = string_null;
 298                 yenc_single(b, s);
 299                 string tmp = strcat(g_buf, s);
 300                 strcpy(g_buf, tmp);
 301         }
 302         void WriteShort(int to, int b)
 303         {
 304                 WriteByte(to, (b >> 8) & 0xFF);
 305                 WriteByte(to, b & 0xFF);
 306         }
 307 #elif defined(SVQC)
 308         int ReadByte()
 309         {
 310                 int ret = -1;
 311                 ydec_single(g_buf, ret);
 312                 return ret;
 313         }
 314         int ReadShort()
 315         {
 316                 return (ReadByte() << 8) | (ReadByte());
 317         }
 318         void WriteByte(int to, int b);
 319 #endif
 320
 321 #define Read_int() ReadInt24_t()
 322 #define Write_int(to, f) WriteInt24_t(to, f)
 323
 324 #define Read_float() ReadFloat()
 325 #define Write_float(to, f) WriteFloat(to, f)
 326
 327 #define Read_string() ReadString()
 328 #define Write_string(to, f) WriteString(to, f)
 329
 330 #ifdef GAMEQC
 331         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 332         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 333         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 334
 335         #ifdef CSQC
 336                 float servertime;
 337                 entity ReadCSQCEntity()
 338                 {
 339                         int f = ReadShort();
 340                         if (f == 0) return NULL;
 341                         return findfloat(NULL, entnum, f);
 342                 }
 343                 int ReadInt24_t()
 344                 {
 345                         int v = ReadShort() << 8; // note: this is signed
 346                         v += ReadByte();          // note: this is unsigned
 347                         return v;
 348                 }
 349                 #define ReadInt48_t() vec2(ReadInt24_t(), ReadInt24_t())
 350                 #define ReadInt72_t() vec3(ReadInt24_t(), ReadInt24_t(), ReadInt24_t())
 351
 352                 noref int _ReadSByte;
 353                 #define ReadSByte() (_ReadSByte = ReadByte(), (_ReadSByte & BIT(7) ? -128 : 0) + (_ReadSByte & BITS(7)))
 354                 #define ReadFloat() ReadCoord()
 355                 #define ReadVector() vec3(ReadFloat(), ReadFloat(), ReadFloat())
 356                 #define ReadVector2D() vec2(ReadFloat(), ReadFloat())
 357
 358                 float ReadApproxPastTime()
 359                 {
 360                         float dt = ReadByte();
 361
 362                         // map from range...PPROXPASTTIME_MAX / 256
 363                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 364
 365                         return servertime - dt;
 366                 }
 367
 368         #else
 369                 void WriteInt24_t(float dst, float val)
 370                 {
 371                         float v;
 372                         WriteShort(dst, (v = floor(val >> 8)));
 373                         WriteByte(dst, val - (v << 8));  // 0..255
 374                 }
 375                 void WriteInt48_t(float dst, vector val)
 376                 {
 377                         WriteInt24_t(dst, val.x);
 378                         WriteInt24_t(dst, val.y);
 379                 }
 380                 void WriteInt72_t(float dst, vector val)
 381                 {
 382                         WriteInt24_t(dst, val.x);
 383                         WriteInt24_t(dst, val.y);
 384                         WriteInt24_t(dst, val.z);
 385                 }
 386
 387                 #define WriteFloat(to, f) WriteCoord(to, f)
 388                 #define WriteVector(to, v) MACRO_BEGIN WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); MACRO_END
 389                 #define WriteVector2D(to, v) MACRO_BEGIN WriteFloat(to, v.x); WriteFloat(to, v.y); MACRO_END
 390
 391                 // this will use the value:
 392                 //   128
 393                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 394                 // accuracy at x is 1/derivative, i.e.
 395                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 396                 void WriteApproxPastTime(float dst, float t)
 397                 {
 398                         float dt = time - t;
 399
 400                         // warning: this is approximate; do not resend when you don't have to!
 401                         // be careful with sendflags here!
 402                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 403
 404                         // map to range...
 405                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 406
 407                         // round...
 408                         dt = rint(bound(0, dt, 255));
 409
 410                         WriteByte(dst, dt);
 411                 }
 412
 413                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 414                 #define WRITESPECTATABLE_MSG_ONE(to, statement) MACRO_BEGIN \
 415                         entity prev = msg_entity; \
 416                         entity dst = to; \
 417                         FOREACH_CLIENT(IS_REAL_CLIENT(it), { \
 418                                 if (it == dst || (it.classname == STR_SPECTATOR && it.enemy == dst)) \
 419                                 { \
 420                                         msg_entity = it; \
 421                                         LAMBDA(statement); \
 422                                 } \
 423                         }); \
 424                         msg_entity = prev; \
 425                 MACRO_END
 426         #endif
 427 #endif