qcsrc/lib/net.qh

   1 #pragma once
   2
   3 #include "registry.qh"
   4 #include "sort.qh"
   5 #include "yenc.qh"
   6
   7 .string netname;
   8 .int m_id;
   9 .bool(entity this, entity sender, bool isNew) m_read;
  10 #define NET_HANDLE(id, param) bool Net_Handle_##id(entity this, entity sender, param)
  11
  12
  13 #ifdef CSQC
  14         #define REGISTER_NET_TEMP(id) \
  15                 NET_HANDLE(id, bool); \
  16                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  17                 { \
  18                         this.netname = #id; \
  19                         this.m_read = Net_Handle_##id; \
  20                 }
  21 #else
  22         #define REGISTER_NET_TEMP(id) \
  23                 const bool NET_##id##_istemp = true; \
  24                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  25                 { \
  26                         this.netname = #id; \
  27                 }
  28 #endif
  29 #define REGISTER_NET_S2C(id) REGISTER_NET_TEMP(id)
  30
  31 REGISTRY(TempEntities, BITS(8) - 80)
  32 #define TempEntities_from(i) _TempEntities_from(i, NULL)
  33 REGISTER_REGISTRY(TempEntities)
  34 REGISTRY_SORT(TempEntities)
  35 REGISTRY_CHECK(TempEntities)
  36 STATIC_INIT(RegisterTempEntities_renumber) { FOREACH(TempEntities, true, it.m_id = 80 + i); }
  37
  38
  39
  40 #ifdef CSQC
  41         #define REGISTER_NET_LINKED(id) \
  42                 [[accumulate]] NET_HANDLE(id, bool isnew) \
  43                 { \
  44                         this = self; \
  45                         this.sourceLocFile = __FILE__; \
  46                         this.sourceLocLine = __LINE__; \
  47                         if (!this) isnew = true; \
  48                 } \
  49                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  50                 { \
  51                         this.netname = #id; \
  52                         this.m_read = Net_Handle_##id; \
  53                 }
  54 #else
  55         #define REGISTER_NET_LINKED(id) \
  56                 const bool NET_##id##_istemp = false; \
  57                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  58                 { \
  59                         this.netname = #id; \
  60                 }
  61 #endif
  62
  63 REGISTRY(LinkedEntities, BITS(8) - 1)
  64 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
  65 REGISTER_REGISTRY(LinkedEntities)
  66 REGISTRY_SORT(LinkedEntities)
  67 REGISTRY_CHECK(LinkedEntities)
  68 STATIC_INIT(RegisterLinkedEntities_renumber) { FOREACH(LinkedEntities, true, it.m_id = 1 + i); }
  69
  70
  71
  72 #ifdef SVQC
  73         #define REGISTER_NET_C2S(id) \
  74                 NET_HANDLE(id, bool); \
  75                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  76                 { \
  77                         this.netname = #id; \
  78                         this.m_read = Net_Handle_##id; \
  79                 }
  80 #else
  81         #define REGISTER_NET_C2S(id) \
  82                 const bool NET_##id##_istemp = true; \
  83                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  84                 { \
  85                         this.netname = #id; \
  86                 }
  87 #endif
  88
  89 REGISTRY(C2S_Protocol, BITS(8) - 1)
  90 #define C2S_Protocol_from(i) _C2S_Protocol_from(i, NULL)
  91 REGISTER_REGISTRY(C2S_Protocol)
  92 REGISTRY_SORT(C2S_Protocol)
  93 REGISTRY_CHECK(C2S_Protocol)
  94 STATIC_INIT(C2S_Protocol_renumber) { FOREACH(C2S_Protocol, true, it.m_id = i); }
  95
  96 #ifdef SVQC
  97         const int MSG_ENTITY = 5;
  98
  99         .int Version;  // deprecated, use SendFlags
 100         .int SendFlags;
 101         .bool(entity to, int sendflags) SendEntity;
 102         /** return false to remove from the client */
 103         .bool(entity this, entity to, int sendflags) SendEntity3;
 104
 105         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
 106
 107         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
 108         {
 109                 if (e.classname == "") e.classname = "net_linked";
 110
 111                 if (e.model == "" || self.modelindex == 0)
 112                 {
 113                         vector mi = e.mins;
 114                         vector ma = e.maxs;
 115                         _setmodel(e, "null");
 116                         setsize(e, mi, ma);
 117                 }
 118
 119                 e.SendEntity = SendEntity_self;
 120                 e.SendEntity3 = sendfunc;
 121                 e.SendFlags = 0xFFFFFF;
 122
 123                 if (!docull) e.effects |= EF_NODEPTHTEST;
 124
 125                 if (dt)
 126                 {
 127                         e.nextthink = time + dt;
 128                         e.think = SUB_Remove_self;
 129                 }
 130         }
 131
 132         void Net_UnlinkEntity(entity e)
 133         {
 134                 e.SendEntity = func_null;
 135         }
 136
 137         .void() uncustomizeentityforclient;
 138         .float uncustomizeentityforclient_set;
 139
 140         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
 141         {
 142                 e.customizeentityforclient = customizer;
 143                 e.uncustomizeentityforclient = uncustomizer;
 144                 e.uncustomizeentityforclient_set = !!uncustomizer;
 145         }
 146
 147         void UncustomizeEntitiesRun()
 148         {
 149                 FOREACH_ENTITY_FLOAT(uncustomizeentityforclient_set, true, LAMBDA(
 150                         WITH(entity, self, it, it.uncustomizeentityforclient());
 151                 ));
 152         }
 153
 154         STRING_ITERATOR(g_buf, string_null, 0);
 155
 156         int ReadByte();
 157
 158         void Net_ClientCommand(entity sender, string command)
 159         {
 160                 // command matches `c2s "(.+)"`
 161                 string buf = substring(command, argv_start_index(1) + 1, -2);
 162                 if (buf == "") return;
 163                 STRING_ITERATOR_SET(g_buf, buf, 0);
 164                 for (int C2S; (C2S = ReadByte()) >= 0; )
 165                 {
 166                         entity reader = C2S_Protocol_from(C2S);
 167                         if (reader && reader.m_read && reader.m_read(NULL, sender, true)) continue;
 168                         LOG_SEVEREF("Net_ClientCommand() with malformed C2S=%d\n", C2S);
 169                         return;
 170                 }
 171                 g_buf_i--;
 172                 int expected = strlen(buf);
 173                 if (g_buf_i > expected) LOG_WARNINGF("Underflow: %d", g_buf_i - expected);
 174                 if (g_buf_i < expected) LOG_WARNINGF("Overrflow: %d", expected - g_buf_i);
 175         }
 176
 177 #endif
 178
 179 #ifdef CSQC
 180         const int MSG_C2S = 0;
 181
 182         #define Net_Accept(classname) \
 183                 MACRO_BEGIN { \
 184                         if (!this)    this = new(classname); \
 185                 } MACRO_END
 186         #define Net_Reject() \
 187                 MACRO_BEGIN { \
 188                         if (this)     remove(this); \
 189                 } MACRO_END
 190
 191         string g_buf;
 192
 193         void Net_Flush()
 194         {
 195                 if (g_buf == "") return;
 196                 localcmd("\ncmd c2s \"", strreplace("$", "$$", g_buf), "\"\n");
 197                 strunzone(g_buf);
 198                 g_buf = string_null;
 199         }
 200 #endif
 201
 202 #if defined(CSQC)
 203         #define WriteHeader(to, id) \
 204                 MACRO_BEGIN { \
 205                         WriteByte(to, NET_##id.m_id); \
 206                 } MACRO_END
 207 #elif defined(SVQC)
 208         #define WriteHeader(to, id) \
 209                 MACRO_BEGIN { \
 210                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
 211                         WriteByte(to, NET_##id.m_id); \
 212                 } MACRO_END
 213 #endif
 214
 215 #define ReadRegistered(r) r##_from(Read_byte())
 216 #define WriteRegistered(r, to, it) Write_byte(to, it.m_id)
 217
 218 #define Read_byte() ReadByte()
 219 #define Write_byte(to, f) WriteByte(to, f)
 220
 221 #if defined(CSQC)
 222         int ReadByte();
 223         void WriteByte(int to, int b)
 224         {
 225                 assert(to == MSG_C2S);
 226                 string s = string_null;
 227                 yenc_single(b, s);
 228                 string tmp = strcat(g_buf, s);
 229                 if (g_buf) strunzone(g_buf);
 230                 g_buf = strzone(tmp);
 231         }
 232 #elif defined(SVQC)
 233         int ReadByte()
 234         {
 235                 int ret = -1;
 236                 ydec_single(g_buf, ret);
 237                 return ret;
 238         }
 239         void WriteByte(int to, int b);
 240 #endif
 241
 242 #define Read_int() ReadInt24_t()
 243 #define Write_int(to, f) WriteInt24_t(to, f)
 244
 245 #define Read_float() ReadFloat()
 246 #define Write_float(to, f) WriteFloat(to, f)
 247
 248 #define Read_string() ReadString()
 249 #define Write_string(to, f) WriteString(to, f)
 250
 251 #ifndef MENUQC
 252         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 253         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 254         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 255
 256         #ifdef CSQC
 257                 entity ReadCSQCEntity()
 258                 {
 259                         int f = ReadShort();
 260                         if (f == 0) return NULL;
 261                         return findfloat(NULL, entnum, f);
 262                 }
 263                 int ReadInt24_t()
 264                 {
 265                         int v = ReadShort() << 8; // note: this is signed
 266                         v += ReadByte();          // note: this is unsigned
 267                         return v;
 268                 }
 269                 vector ReadInt48_t()
 270                 {
 271                         vector v;
 272                         v.x = ReadInt24_t();
 273                         v.y = ReadInt24_t();
 274                         v.z = 0;
 275                         return v;
 276                 }
 277                 vector ReadInt72_t()
 278                 {
 279                         vector v;
 280                         v.x = ReadInt24_t();
 281                         v.y = ReadInt24_t();
 282                         v.z = ReadInt24_t();
 283                         return v;
 284                 }
 285
 286                 int _ReadSByte;
 287                 #define ReadSByte() (_ReadSByte = ReadByte(), (_ReadSByte & BIT(7) ? -128 : 0) + (_ReadSByte & BITS(7)))
 288                 #define ReadFloat() ReadCoord()
 289         vector ReadVector() { vector v; v.x = ReadFloat(); v.y = ReadFloat(); v.z = ReadFloat(); return v; }
 290                 vector ReadVector2D() { vector v; v.x = ReadFloat(); v.y = ReadFloat(); v.z = 0; return v; }
 291
 292                 float ReadApproxPastTime()
 293                 {
 294                         float dt = ReadByte();
 295
 296                         // map from range...PPROXPASTTIME_MAX / 256
 297                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 298
 299                         return servertime - dt;
 300                 }
 301
 302         #else
 303                 void WriteInt24_t(float dst, float val)
 304                 {
 305                         float v;
 306                         WriteShort(dst, (v = floor(val >> 8)));
 307                         WriteByte(dst, val - (v << 8));  // 0..255
 308                 }
 309                 void WriteInt48_t(float dst, vector val)
 310                 {
 311                         WriteInt24_t(dst, val.x);
 312                         WriteInt24_t(dst, val.y);
 313                 }
 314                 void WriteInt72_t(float dst, vector val)
 315                 {
 316                         WriteInt24_t(dst, val.x);
 317                         WriteInt24_t(dst, val.y);
 318                         WriteInt24_t(dst, val.z);
 319                 }
 320
 321         #define WriteFloat(to, f) WriteCoord(to, f)
 322                 #define WriteVector(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); } MACRO_END
 323         #define WriteVector2D(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); } MACRO_END
 324
 325                 // this will use the value:
 326                 //   128
 327                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 328                 // accuracy at x is 1/derivative, i.e.
 329                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 330                 void WriteApproxPastTime(float dst, float t)
 331                 {
 332                         float dt = time - t;
 333
 334                         // warning: this is approximate; do not resend when you don't have to!
 335                         // be careful with sendflags here!
 336                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 337
 338                         // map to range...
 339                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 340
 341                         // round...
 342                         dt = rint(bound(0, dt, 255));
 343
 344                         WriteByte(dst, dt);
 345                 }
 346
 347                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 348                 #define WRITESPECTATABLE_MSG_ONE(to, statement) MACRO_BEGIN { \
 349                         entity prev = msg_entity; \
 350                         entity dst = to; \
 351                         FOREACH_CLIENT(IS_REAL_CLIENT(it), { \
 352                                 if (it == dst || (it.classname == STR_SPECTATOR && it.enemy == dst)) \
 353                                 { \
 354                                         msg_entity = it; \
 355                                         LAMBDA(statement); \
 356                                 } \
 357                         }); \
 358                         msg_entity = prev; \
 359                 } MACRO_END
 360         #endif
 361 #endif