qcsrc/lib/net.qh

   1 #ifndef NET_H
   2 #define NET_H
   3
   4 #ifdef SVQC
   5         .int Version;  // deprecated, use SendFlags
   6         .int SendFlags;
   7         .bool(entity to, int sendflags)SendEntity;
   8         .bool(entity this, entity to, int sendflags)SendEntity3;
   9
  10         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
  11
  12         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags)sendfunc)
  13         {
  14                 if (e.classname == "") e.classname = "net_linked";
  15
  16                 if (e.model == "" || self.modelindex == 0)
  17                 {
  18                         vector mi = e.mins;
  19                         vector ma = e.maxs;
  20                         _setmodel(e, "null");
  21                         setsize(e, mi, ma);
  22                 }
  23
  24                 e.SendEntity = SendEntity_self;
  25                 e.SendEntity3 = sendfunc;
  26                 e.SendFlags = 0xFFFFFF;
  27
  28                 if (!docull) e.effects |= EF_NODEPTHTEST;
  29
  30                 if (dt)
  31                 {
  32                         e.nextthink = time + dt;
  33                         e.think = SUB_Remove;
  34                 }
  35         }
  36
  37         .void() uncustomizeentityforclient;
  38         .float uncustomizeentityforclient_set;
  39
  40         void SetCustomizer(entity e, float(void)customizer, void(void)uncustomizer)
  41         {
  42                 e.customizeentityforclient = customizer;
  43                 e.uncustomizeentityforclient = uncustomizer;
  44                 e.uncustomizeentityforclient_set = !!uncustomizer;
  45         }
  46
  47         void UncustomizeEntitiesRun()
  48         {
  49                 for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
  50                         WITH(entity, self, e, e.uncustomizeentityforclient());
  51         }
  52
  53 #endif
  54
  55 #include "registry.qh"
  56 #include "sort.qh"
  57
  58 .string netname;
  59 .int m_id;
  60 .void(entity this, bool isNew)m_read;
  61
  62 #ifdef CSQC
  63         #define Net_Accept(classname) \
  64                 do \
  65                 { \
  66                         if (!this)    this = new(classname); \
  67                 } \
  68                 while (0)
  69         #define Net_Reject() \
  70                 do \
  71                 { \
  72                         if (this)     remove(this); \
  73                 } \
  74                 while (0)
  75 #else
  76         #define WriteHeader(to, id) \
  77                 do \
  78                 { \
  79                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
  80                         WriteByte(to, NET_##id.m_id); \
  81                 } \
  82                 while (0)
  83 #endif
  84
  85 #ifdef CSQC
  86         #define REGISTER_NET_LINKED(id, param) \
  87                 void Ent_Read##id(entity this, param) \
  88                 { \
  89                         this = self; \
  90                         this.sourceLocFile = __FILE__; \
  91                         this.sourceLocLine = __LINE__; \
  92                 } \
  93                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
  94                 { \
  95                         make_pure(this); \
  96                         this.netname = #id; \
  97                         this.m_read = Ent_Read##id; \
  98                 } \
  99                 [[accumulate]] void Ent_Read##id(entity this, param)
 100 #else
 101         #define REGISTER_NET_LINKED(id, param) \
 102                 const bool NET_##id##_istemp = false; \
 103                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
 104                 { \
 105                         make_pure(this); \
 106                         this.netname = #id; \
 107                 }
 108 #endif
 109
 110 REGISTRY(LinkedEntities, BITS(2))
 111 REGISTER_REGISTRY(RegisterLinkedEntities)
 112 REGISTRY_SORT(LinkedEntities, netname, 0)
 113 STATIC_INIT(RegisterLinkedEntities_renumber)
 114 {
 115         for (int i = 0; i < LinkedEntities_COUNT; ++i)
 116                 LinkedEntities[i].m_id = 100 + i;
 117 }
 118
 119 #ifdef CSQC
 120         #define REGISTER_NET_TEMP(id, param) \
 121                 void Net_Read##id(entity this, param); \
 122                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 123                 { \
 124                         make_pure(this); \
 125                         this.netname = #id; \
 126                         this.m_read = Net_Read##id; \
 127                 } \
 128                 void Net_Read##id(entity this, param)
 129 #else
 130         #define REGISTER_NET_TEMP(id, param) \
 131                 const bool NET_##id##_istemp = true; \
 132                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 133                 { \
 134                         make_pure(this); \
 135                         this.netname = #id; \
 136                 }
 137 #endif
 138
 139 REGISTRY(TempEntities, BITS(2))
 140 REGISTER_REGISTRY(RegisterTempEntities)
 141 REGISTRY_SORT(TempEntities, netname, 0)
 142 STATIC_INIT(RegisterTempEntities_renumber)
 143 {
 144         for (int i = 0; i < TempEntities_COUNT; ++i)
 145                 TempEntities[i].m_id = 115 + i;
 146 }
 147
 148 #ifndef MENUQC
 149         #ifdef CSQC
 150                 int ReadInt24_t()
 151                 {
 152                         int v = ReadShort() << 8; // note: this is signed
 153                         v += ReadByte();          // note: this is unsigned
 154                         return v;
 155                 }
 156                 vector ReadInt48_t()
 157                 {
 158                         vector v;
 159                         v.x = ReadInt24_t();
 160                         v.y = ReadInt24_t();
 161                         v.z = 0;
 162                         return v;
 163                 }
 164                 vector ReadInt72_t()
 165                 {
 166                         vector v;
 167                         v.x = ReadInt24_t();
 168                         v.y = ReadInt24_t();
 169                         v.z = ReadInt24_t();
 170                         return v;
 171                 }
 172         #else
 173                 const int MSG_ENTITY = 5;
 174
 175                 void WriteInt24_t(float dst, float val)
 176                 {
 177                         float v;
 178                         WriteShort(dst, (v = floor(val >> 8)));
 179                         WriteByte(dst, val - (v << 8));  // 0..255
 180                 }
 181                 void WriteInt48_t(float dst, vector val)
 182                 {
 183                         WriteInt24_t(dst, val.x);
 184                         WriteInt24_t(dst, val.y);
 185                 }
 186                 void WriteInt72_t(float dst, vector val)
 187                 {
 188                         WriteInt24_t(dst, val.x);
 189                         WriteInt24_t(dst, val.y);
 190                         WriteInt24_t(dst, val.z);
 191                 }
 192         #endif
 193 #endif
 194
 195 #endif