qcsrc/lib/net.qh

   1 #pragma once
   2
   3 #include "registry.qh"
   4 #include "sort.qh"
   5 #include "yenc.qh"
   6
   7 .string netname;
   8 .int m_id;
   9 .bool(entity this, entity sender, bool isNew) m_read;
  10 #define NET_HANDLE(id, param) bool Net_Handle_##id(entity this, entity sender, param)
  11
  12
  13 #ifdef CSQC
  14         #define REGISTER_NET_TEMP(id) \
  15                 NET_HANDLE(id, bool); \
  16                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  17                 { \
  18                         this.netname = #id; \
  19                         this.m_read = Net_Handle_##id; \
  20                 }
  21 #else
  22         #define REGISTER_NET_TEMP(id) \
  23                 const bool NET_##id##_istemp = true; \
  24                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  25                 { \
  26                         this.netname = #id; \
  27                 }
  28 #endif
  29 #define REGISTER_NET_S2C(id) REGISTER_NET_TEMP(id)
  30
  31 REGISTRY(TempEntities, BITS(8) - 80)
  32 #define TempEntities_from(i) _TempEntities_from(i, NULL)
  33 REGISTER_REGISTRY(TempEntities)
  34 REGISTRY_SORT(TempEntities)
  35 REGISTRY_CHECK(TempEntities)
  36 STATIC_INIT(RegisterTempEntities_renumber) { FOREACH(TempEntities, true, it.m_id = 80 + i); }
  37
  38
  39
  40 #ifdef CSQC
  41         #define REGISTER_NET_LINKED(id) \
  42                 [[accumulate]] NET_HANDLE(id, bool isnew) \
  43                 { \
  44                         this = self; \
  45                         this.sourceLoc = __FILE__ ":" STR(__LINE__); \
  46                         if (!this) isnew = true; \
  47                 } \
  48                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  49                 { \
  50                         this.netname = #id; \
  51                         this.m_read = Net_Handle_##id; \
  52                 }
  53 #else
  54         #define REGISTER_NET_LINKED(id) \
  55                 const bool NET_##id##_istemp = false; \
  56                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  57                 { \
  58                         this.netname = #id; \
  59                 }
  60 #endif
  61
  62 REGISTRY(LinkedEntities, BITS(8) - 1)
  63 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
  64 REGISTER_REGISTRY(LinkedEntities)
  65 REGISTRY_SORT(LinkedEntities)
  66 REGISTRY_CHECK(LinkedEntities)
  67 STATIC_INIT(RegisterLinkedEntities_renumber) { FOREACH(LinkedEntities, true, it.m_id = 1 + i); }
  68
  69
  70
  71 #ifdef SVQC
  72         #define REGISTER_NET_C2S(id) \
  73                 NET_HANDLE(id, bool); \
  74                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  75                 { \
  76                         this.netname = #id; \
  77                         this.m_read = Net_Handle_##id; \
  78                 }
  79 #else
  80         #define REGISTER_NET_C2S(id) \
  81                 const bool NET_##id##_istemp = true; \
  82                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  83                 { \
  84                         this.netname = #id; \
  85                 }
  86 #endif
  87
  88 REGISTRY(C2S_Protocol, BITS(8) - 1)
  89 #define C2S_Protocol_from(i) _C2S_Protocol_from(i, NULL)
  90 REGISTER_REGISTRY(C2S_Protocol)
  91 REGISTRY_SORT(C2S_Protocol)
  92 REGISTRY_CHECK(C2S_Protocol)
  93 STATIC_INIT(C2S_Protocol_renumber) { FOREACH(C2S_Protocol, true, it.m_id = i); }
  94
  95 #ifdef SVQC
  96         const int MSG_ENTITY = 5;
  97
  98         .int Version;  // deprecated, use SendFlags
  99         .int SendFlags;
 100         .bool(entity to, int sendflags) SendEntity;
 101         /** return false to remove from the client */
 102         .bool(entity this, entity to, int sendflags) SendEntity3;
 103
 104         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
 105
 106         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
 107         {
 108                 if (e.classname == "") e.classname = "net_linked";
 109
 110                 if (e.model == "" || e.modelindex == 0)
 111                 {
 112                         vector mi = e.mins;
 113                         vector ma = e.maxs;
 114                         _setmodel(e, "null");
 115                         setsize(e, mi, ma);
 116                 }
 117
 118                 e.SendEntity = SendEntity_self;
 119                 e.SendEntity3 = sendfunc;
 120                 e.SendFlags = 0xFFFFFF;
 121
 122                 if (!docull) e.effects |= EF_NODEPTHTEST;
 123
 124                 if (dt)
 125                 {
 126                         e.nextthink = time + dt;
 127                         e.think = SUB_Remove_self;
 128                 }
 129         }
 130
 131         void Net_UnlinkEntity(entity e)
 132         {
 133                 e.SendEntity = func_null;
 134         }
 135
 136         .void() uncustomizeentityforclient;
 137         .float uncustomizeentityforclient_set;
 138
 139         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
 140         {
 141                 e.customizeentityforclient = customizer;
 142                 e.uncustomizeentityforclient = uncustomizer;
 143                 e.uncustomizeentityforclient_set = !!uncustomizer;
 144         }
 145
 146         void UncustomizeEntitiesRun()
 147         {
 148                 FOREACH_ENTITY_FLOAT(uncustomizeentityforclient_set, true, WITH(entity, self, it, it.uncustomizeentityforclient()));
 149         }
 150
 151         STRING_ITERATOR(g_buf, string_null, 0);
 152
 153         int ReadByte();
 154
 155         void Net_ClientCommand(entity sender, string command)
 156         {
 157                 // command matches `c2s "(.+)"`
 158                 string buf = substring(command, argv_start_index(1) + 1, -2);
 159                 if (buf == "") return;
 160                 STRING_ITERATOR_SET(g_buf, buf, 0);
 161                 for (int C2S; (C2S = ReadByte()) >= 0; )
 162                 {
 163                         entity reader = C2S_Protocol_from(C2S);
 164                         if (reader && reader.m_read && reader.m_read(NULL, sender, true)) continue;
 165                         LOG_SEVEREF("Net_ClientCommand() with malformed C2S=%d\n", C2S);
 166                         return;
 167                 }
 168                 g_buf_i--;
 169                 int expected = strlen(buf);
 170                 if (g_buf_i > expected) LOG_WARNINGF("Underflow: %d", g_buf_i - expected);
 171                 if (g_buf_i < expected) LOG_WARNINGF("Overrflow: %d", expected - g_buf_i);
 172         }
 173
 174 #endif
 175
 176 #ifdef CSQC
 177         const int MSG_C2S = 0;
 178
 179         #define Net_Accept(classname) \
 180                 MACRO_BEGIN { \
 181                         if (!this)    this = new(classname); \
 182                 } MACRO_END
 183         #define Net_Reject() \
 184                 MACRO_BEGIN { \
 185                         if (this)     remove(this); \
 186                 } MACRO_END
 187
 188         string g_buf;
 189
 190         void Net_Flush()
 191         {
 192                 if (g_buf == "") return;
 193                 localcmd("\ncmd c2s \"", strreplace("$", "$$", g_buf), "\"\n");
 194                 strunzone(g_buf);
 195                 g_buf = string_null;
 196         }
 197 #endif
 198
 199 #if defined(CSQC)
 200         #define WriteHeader(to, id) \
 201                 MACRO_BEGIN { \
 202                         WriteByte(to, NET_##id.m_id); \
 203                 } MACRO_END
 204 #elif defined(SVQC)
 205         #define WriteHeader(to, id) \
 206                 MACRO_BEGIN { \
 207                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
 208                         WriteByte(to, NET_##id.m_id); \
 209                 } MACRO_END
 210 #endif
 211
 212 #define ReadRegistered(r) r##_from(Read_byte())
 213 #define WriteRegistered(r, to, it) Write_byte(to, it.m_id)
 214
 215 #define Read_byte() ReadByte()
 216 #define Write_byte(to, f) WriteByte(to, f)
 217
 218 #if defined(CSQC)
 219         int ReadByte();
 220         void WriteByte(int to, int b)
 221         {
 222                 assert(to == MSG_C2S);
 223                 string s = string_null;
 224                 yenc_single(b, s);
 225                 string tmp = strcat(g_buf, s);
 226                 if (g_buf) strunzone(g_buf);
 227                 g_buf = strzone(tmp);
 228         }
 229 #elif defined(SVQC)
 230         int ReadByte()
 231         {
 232                 int ret = -1;
 233                 ydec_single(g_buf, ret);
 234                 return ret;
 235         }
 236         void WriteByte(int to, int b);
 237 #endif
 238
 239 #define Read_int() ReadInt24_t()
 240 #define Write_int(to, f) WriteInt24_t(to, f)
 241
 242 #define Read_float() ReadFloat()
 243 #define Write_float(to, f) WriteFloat(to, f)
 244
 245 #define Read_string() ReadString()
 246 #define Write_string(to, f) WriteString(to, f)
 247
 248 #ifndef MENUQC
 249         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 250         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 251         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 252
 253         #ifdef CSQC
 254                 entity ReadCSQCEntity()
 255                 {
 256                         int f = ReadShort();
 257                         if (f == 0) return NULL;
 258                         return findfloat(NULL, entnum, f);
 259                 }
 260                 int ReadInt24_t()
 261                 {
 262                         int v = ReadShort() << 8; // note: this is signed
 263                         v += ReadByte();          // note: this is unsigned
 264                         return v;
 265                 }
 266                 #define ReadInt48_t() vec3(ReadInt24_t(), ReadInt24_t(), 0)
 267                 #define ReadInt72_t() vec3(ReadInt24_t(), ReadInt24_t(), ReadInt24_t())
 268
 269                 int _ReadSByte;
 270                 #define ReadSByte() (_ReadSByte = ReadByte(), (_ReadSByte & BIT(7) ? -128 : 0) + (_ReadSByte & BITS(7)))
 271                 #define ReadFloat() ReadCoord()
 272                 #define ReadVector() vec3(ReadFloat(), ReadFloat(), ReadFloat())
 273                 #define ReadVector2D() vec3(ReadFloat(), ReadFloat(), 0)
 274
 275                 float ReadApproxPastTime()
 276                 {
 277                         float dt = ReadByte();
 278
 279                         // map from range...PPROXPASTTIME_MAX / 256
 280                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 281
 282                         return servertime - dt;
 283                 }
 284
 285         #else
 286                 void WriteInt24_t(float dst, float val)
 287                 {
 288                         float v;
 289                         WriteShort(dst, (v = floor(val >> 8)));
 290                         WriteByte(dst, val - (v << 8));  // 0..255
 291                 }
 292                 void WriteInt48_t(float dst, vector val)
 293                 {
 294                         WriteInt24_t(dst, val.x);
 295                         WriteInt24_t(dst, val.y);
 296                 }
 297                 void WriteInt72_t(float dst, vector val)
 298                 {
 299                         WriteInt24_t(dst, val.x);
 300                         WriteInt24_t(dst, val.y);
 301                         WriteInt24_t(dst, val.z);
 302                 }
 303
 304         #define WriteFloat(to, f) WriteCoord(to, f)
 305                 #define WriteVector(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); } MACRO_END
 306         #define WriteVector2D(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); } MACRO_END
 307
 308                 // this will use the value:
 309                 //   128
 310                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 311                 // accuracy at x is 1/derivative, i.e.
 312                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 313                 void WriteApproxPastTime(float dst, float t)
 314                 {
 315                         float dt = time - t;
 316
 317                         // warning: this is approximate; do not resend when you don't have to!
 318                         // be careful with sendflags here!
 319                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 320
 321                         // map to range...
 322                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 323
 324                         // round...
 325                         dt = rint(bound(0, dt, 255));
 326
 327                         WriteByte(dst, dt);
 328                 }
 329
 330                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 331                 #define WRITESPECTATABLE_MSG_ONE(to, statement) MACRO_BEGIN { \
 332                         entity prev = msg_entity; \
 333                         entity dst = to; \
 334                         FOREACH_CLIENT(IS_REAL_CLIENT(it), { \
 335                                 if (it == dst || (it.classname == STR_SPECTATOR && it.enemy == dst)) \
 336                                 { \
 337                                         msg_entity = it; \
 338                                         LAMBDA(statement); \
 339                                 } \
 340                         }); \
 341                         msg_entity = prev; \
 342                 } MACRO_END
 343         #endif
 344 #endif