qcsrc/lib/net.qh

   1 #ifndef NET_H
   2 #define NET_H
   3
   4 #ifdef SVQC
   5         .int Version;  // deprecated, use SendFlags
   6         .int SendFlags;
   7         .bool(entity to, int sendflags)SendEntity;
   8         .bool(entity this, entity to, int sendflags)SendEntity3;
   9
  10         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
  11
  12         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags)sendfunc)
  13         {
  14                 if (e.classname == "") e.classname = "net_linked";
  15
  16                 if (e.model == "" || self.modelindex == 0)
  17                 {
  18                         vector mi = e.mins;
  19                         vector ma = e.maxs;
  20                         _setmodel(e, "null");
  21                         setsize(e, mi, ma);
  22                 }
  23
  24                 e.SendEntity = SendEntity_self;
  25                 e.SendEntity3 = sendfunc;
  26                 e.SendFlags = 0xFFFFFF;
  27
  28                 if (!docull) e.effects |= EF_NODEPTHTEST;
  29
  30                 if (dt)
  31                 {
  32                         e.nextthink = time + dt;
  33                         e.think = SUB_Remove;
  34                 }
  35         }
  36
  37         .void() uncustomizeentityforclient;
  38         .float uncustomizeentityforclient_set;
  39
  40         void SetCustomizer(entity e, float()customizer, void()uncustomizer)
  41         {
  42                 e.customizeentityforclient = customizer;
  43                 e.uncustomizeentityforclient = uncustomizer;
  44                 e.uncustomizeentityforclient_set = !!uncustomizer;
  45         }
  46
  47         void UncustomizeEntitiesRun()
  48         {
  49                 for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
  50                         WITH(entity, self, e, e.uncustomizeentityforclient());
  51         }
  52
  53 #endif
  54
  55 #include "registry.qh"
  56 #include "sort.qh"
  57
  58 .string netname;
  59 .int m_id;
  60 .bool(entity this, bool isNew) m_read;
  61
  62 #ifdef CSQC
  63         #define Net_Accept(classname) \
  64                 do \
  65                 { \
  66                         if (!this)    this = new(classname); \
  67                 } \
  68                 while (0)
  69         #define Net_Reject() \
  70                 do \
  71                 { \
  72                         if (this)     remove(this); \
  73                 } \
  74                 while (0)
  75         #define NET_HANDLE(id, param) \
  76                 bool Net_Handle_##id(entity this, param)
  77 #else
  78         #define WriteHeader(to, id) \
  79                 do \
  80                 { \
  81                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
  82                         WriteByte(to, NET_##id.m_id); \
  83                 } \
  84                 while (0)
  85 #endif
  86
  87 #ifdef CSQC
  88         #define REGISTER_NET_LINKED(id) \
  89                 [[accumulate]] NET_HANDLE(id, bool) \
  90                 { \
  91                         this = self; \
  92                         this.sourceLocFile = __FILE__; \
  93                         this.sourceLocLine = __LINE__; \
  94                 } \
  95                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
  96                 { \
  97                         make_pure(this); \
  98                         this.netname = #id; \
  99                         this.m_read = Net_Handle_##id; \
 100                 }
 101 #else
 102         #define REGISTER_NET_LINKED(id) \
 103                 const bool NET_##id##_istemp = false; \
 104                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
 105                 { \
 106                         make_pure(this); \
 107                         this.netname = #id; \
 108                 }
 109 #endif
 110
 111 REGISTRY(LinkedEntities, BITS(8) - 1)
 112 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
 113 REGISTER_REGISTRY(RegisterLinkedEntities)
 114 REGISTRY_SORT(LinkedEntities, netname, 0)
 115 STATIC_INIT(RegisterLinkedEntities_renumber)
 116 {
 117         for (int i = 0; i < LinkedEntities_COUNT; ++i)
 118                 LinkedEntities_from(i).m_id = 1 + i;
 119 }
 120
 121 #ifdef CSQC
 122         #define REGISTER_NET_TEMP(id) \
 123                 NET_HANDLE(id, bool); \
 124                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 125                 { \
 126                         make_pure(this); \
 127                         this.netname = #id; \
 128                         this.m_read = Net_Handle_##id; \
 129                 }
 130 #else
 131         #define REGISTER_NET_TEMP(id) \
 132                 const bool NET_##id##_istemp = true; \
 133                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 134                 { \
 135                         make_pure(this); \
 136                         this.netname = #id; \
 137                 }
 138 #endif
 139
 140 REGISTRY(TempEntities, BITS(8) - 80)
 141 #define TempEntities_from(i) _TempEntities_from(i, NULL)
 142 REGISTER_REGISTRY(RegisterTempEntities)
 143 REGISTRY_SORT(TempEntities, netname, 0)
 144 STATIC_INIT(RegisterTempEntities_renumber)
 145 {
 146         for (int i = 0; i < TempEntities_COUNT; ++i)
 147                 TempEntities_from(i).m_id = 80 + i;
 148 }
 149
 150 #ifndef MENUQC
 151         #ifdef CSQC
 152                 int ReadInt24_t()
 153                 {
 154                         int v = ReadShort() << 8; // note: this is signed
 155                         v += ReadByte();          // note: this is unsigned
 156                         return v;
 157                 }
 158                 vector ReadInt48_t()
 159                 {
 160                         vector v;
 161                         v.x = ReadInt24_t();
 162                         v.y = ReadInt24_t();
 163                         v.z = 0;
 164                         return v;
 165                 }
 166                 vector ReadInt72_t()
 167                 {
 168                         vector v;
 169                         v.x = ReadInt24_t();
 170                         v.y = ReadInt24_t();
 171                         v.z = ReadInt24_t();
 172                         return v;
 173                 }
 174         #else
 175                 const int MSG_ENTITY = 5;
 176
 177                 void WriteInt24_t(float dst, float val)
 178                 {
 179                         float v;
 180                         WriteShort(dst, (v = floor(val >> 8)));
 181                         WriteByte(dst, val - (v << 8));  // 0..255
 182                 }
 183                 void WriteInt48_t(float dst, vector val)
 184                 {
 185                         WriteInt24_t(dst, val.x);
 186                         WriteInt24_t(dst, val.y);
 187                 }
 188                 void WriteInt72_t(float dst, vector val)
 189                 {
 190                         WriteInt24_t(dst, val.x);
 191                         WriteInt24_t(dst, val.y);
 192                         WriteInt24_t(dst, val.z);
 193                 }
 194
 195                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 196         #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
 197         #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
 198         #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
 199         #endif
 200 #endif
 201
 202 #endif