qcsrc/lib/net.qh

   1 #pragma once
   2
   3 #include "registry.qh"
   4 #include "sort.qh"
   5 #include "yenc.qh"
   6
   7 .string netname;
   8 .int m_id;
   9 .bool(entity this, entity sender, bool isNew) m_read;
  10 #define NET_HANDLE(id, param) bool Net_Handle_##id(entity this, entity sender, param)
  11
  12
  13 #ifdef CSQC
  14         #define REGISTER_NET_TEMP(id) \
  15                 NET_HANDLE(id, bool); \
  16                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  17                 { \
  18                         this.netname = #id; \
  19                         this.m_read = Net_Handle_##id; \
  20                 }
  21 #else
  22         #define REGISTER_NET_TEMP(id) \
  23                 const bool NET_##id##_istemp = true; \
  24                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  25                 { \
  26                         this.netname = #id; \
  27                 }
  28 #endif
  29 #define REGISTER_NET_S2C(id) REGISTER_NET_TEMP(id)
  30
  31 REGISTRY(TempEntities, BITS(8) - 80)
  32 #define TempEntities_from(i) _TempEntities_from(i, NULL)
  33 REGISTER_REGISTRY(TempEntities)
  34 REGISTRY_SORT(TempEntities)
  35 REGISTRY_CHECK(TempEntities)
  36 STATIC_INIT(RegisterTempEntities_renumber) { FOREACH(TempEntities, true, it.m_id = 80 + i); }
  37
  38
  39
  40 #ifdef CSQC
  41         #define REGISTER_NET_LINKED(id) \
  42                 [[accumulate]] NET_HANDLE(id, bool isnew) \
  43                 { \
  44                         this = self; \
  45                         this.sourceLoc = __FILE__ ":" STR(__LINE__); \
  46                         if (!this) isnew = true; \
  47                 } \
  48                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  49                 { \
  50                         this.netname = #id; \
  51                         this.m_read = Net_Handle_##id; \
  52                 }
  53 #else
  54         #define REGISTER_NET_LINKED(id) \
  55                 const bool NET_##id##_istemp = false; \
  56                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  57                 { \
  58                         this.netname = #id; \
  59                 }
  60 #endif
  61
  62 REGISTRY(LinkedEntities, BITS(8) - 1)
  63 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
  64 REGISTER_REGISTRY(LinkedEntities)
  65 REGISTRY_SORT(LinkedEntities)
  66 REGISTRY_CHECK(LinkedEntities)
  67 STATIC_INIT(RegisterLinkedEntities_renumber) { FOREACH(LinkedEntities, true, it.m_id = 1 + i); }
  68
  69
  70
  71 #ifdef SVQC
  72         #define REGISTER_NET_C2S(id) \
  73                 NET_HANDLE(id, bool); \
  74                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  75                 { \
  76                         this.netname = #id; \
  77                         this.m_read = Net_Handle_##id; \
  78                 }
  79 #else
  80         #define REGISTER_NET_C2S(id) \
  81                 const bool NET_##id##_istemp = true; \
  82                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  83                 { \
  84                         this.netname = #id; \
  85                 }
  86 #endif
  87
  88 REGISTRY(C2S_Protocol, BITS(8) - 1)
  89 #define C2S_Protocol_from(i) _C2S_Protocol_from(i, NULL)
  90 REGISTER_REGISTRY(C2S_Protocol)
  91 REGISTRY_SORT(C2S_Protocol)
  92 REGISTRY_CHECK(C2S_Protocol)
  93 STATIC_INIT(C2S_Protocol_renumber) { FOREACH(C2S_Protocol, true, it.m_id = i); }
  94
  95 #ifdef SVQC
  96         const int MSG_ENTITY = 5;
  97
  98         .int Version;  // deprecated, use SendFlags
  99         .int SendFlags;
 100         .bool(entity to, int sendflags) SendEntity;
 101         /** return false to remove from the client */
 102         .bool(entity this, entity to, int sendflags) SendEntity3;
 103
 104         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
 105
 106         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
 107         {
 108                 if (e.classname == "") e.classname = "net_linked";
 109
 110                 if (e.model == "" || e.modelindex == 0)
 111                 {
 112                         vector mi = e.mins;
 113                         vector ma = e.maxs;
 114                         _setmodel(e, "null");
 115                         setsize(e, mi, ma);
 116                 }
 117
 118                 e.SendEntity = SendEntity_self;
 119                 e.SendEntity3 = sendfunc;
 120                 e.SendFlags = 0xFFFFFF;
 121
 122                 if (!docull) e.effects |= EF_NODEPTHTEST;
 123
 124                 if (dt)
 125                 {
 126                         e.nextthink = time + dt;
 127                         e.think = SUB_Remove_self;
 128                 }
 129         }
 130
 131         void Net_UnlinkEntity(entity e)
 132         {
 133                 e.SendEntity = func_null;
 134         }
 135
 136         .void() uncustomizeentityforclient;
 137         .float uncustomizeentityforclient_set;
 138
 139         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
 140         {
 141                 e.customizeentityforclient = customizer;
 142                 e.uncustomizeentityforclient = uncustomizer;
 143                 e.uncustomizeentityforclient_set = !!uncustomizer;
 144         }
 145
 146         void UncustomizeEntitiesRun()
 147         {
 148                 FOREACH_ENTITY_FLOAT(uncustomizeentityforclient_set, true, LAMBDA(
 149                         WITH(entity, self, it, it.uncustomizeentityforclient());
 150                 ));
 151         }
 152
 153         STRING_ITERATOR(g_buf, string_null, 0);
 154
 155         int ReadByte();
 156
 157         void Net_ClientCommand(entity sender, string command)
 158         {
 159                 // command matches `c2s "(.+)"`
 160                 string buf = substring(command, argv_start_index(1) + 1, -2);
 161                 if (buf == "") return;
 162                 STRING_ITERATOR_SET(g_buf, buf, 0);
 163                 for (int C2S; (C2S = ReadByte()) >= 0; )
 164                 {
 165                         entity reader = C2S_Protocol_from(C2S);
 166                         if (reader && reader.m_read && reader.m_read(NULL, sender, true)) continue;
 167                         LOG_SEVEREF("Net_ClientCommand() with malformed C2S=%d\n", C2S);
 168                         return;
 169                 }
 170                 g_buf_i--;
 171                 int expected = strlen(buf);
 172                 if (g_buf_i > expected) LOG_WARNINGF("Underflow: %d", g_buf_i - expected);
 173                 if (g_buf_i < expected) LOG_WARNINGF("Overrflow: %d", expected - g_buf_i);
 174         }
 175
 176 #endif
 177
 178 #ifdef CSQC
 179         const int MSG_C2S = 0;
 180
 181         #define Net_Accept(classname) \
 182                 MACRO_BEGIN { \
 183                         if (!this)    this = new(classname); \
 184                 } MACRO_END
 185         #define Net_Reject() \
 186                 MACRO_BEGIN { \
 187                         if (this)     remove(this); \
 188                 } MACRO_END
 189
 190         string g_buf;
 191
 192         void Net_Flush()
 193         {
 194                 if (g_buf == "") return;
 195                 localcmd("\ncmd c2s \"", strreplace("$", "$$", g_buf), "\"\n");
 196                 strunzone(g_buf);
 197                 g_buf = string_null;
 198         }
 199 #endif
 200
 201 #if defined(CSQC)
 202         #define WriteHeader(to, id) \
 203                 MACRO_BEGIN { \
 204                         WriteByte(to, NET_##id.m_id); \
 205                 } MACRO_END
 206 #elif defined(SVQC)
 207         #define WriteHeader(to, id) \
 208                 MACRO_BEGIN { \
 209                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
 210                         WriteByte(to, NET_##id.m_id); \
 211                 } MACRO_END
 212 #endif
 213
 214 #define ReadRegistered(r) r##_from(Read_byte())
 215 #define WriteRegistered(r, to, it) Write_byte(to, it.m_id)
 216
 217 #define Read_byte() ReadByte()
 218 #define Write_byte(to, f) WriteByte(to, f)
 219
 220 #if defined(CSQC)
 221         int ReadByte();
 222         void WriteByte(int to, int b)
 223         {
 224                 assert(to == MSG_C2S);
 225                 string s = string_null;
 226                 yenc_single(b, s);
 227                 string tmp = strcat(g_buf, s);
 228                 if (g_buf) strunzone(g_buf);
 229                 g_buf = strzone(tmp);
 230         }
 231 #elif defined(SVQC)
 232         int ReadByte()
 233         {
 234                 int ret = -1;
 235                 ydec_single(g_buf, ret);
 236                 return ret;
 237         }
 238         void WriteByte(int to, int b);
 239 #endif
 240
 241 #define Read_int() ReadInt24_t()
 242 #define Write_int(to, f) WriteInt24_t(to, f)
 243
 244 #define Read_float() ReadFloat()
 245 #define Write_float(to, f) WriteFloat(to, f)
 246
 247 #define Read_string() ReadString()
 248 #define Write_string(to, f) WriteString(to, f)
 249
 250 #ifndef MENUQC
 251         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 252         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 253         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 254
 255         #ifdef CSQC
 256                 entity ReadCSQCEntity()
 257                 {
 258                         int f = ReadShort();
 259                         if (f == 0) return NULL;
 260                         return findfloat(NULL, entnum, f);
 261                 }
 262                 int ReadInt24_t()
 263                 {
 264                         int v = ReadShort() << 8; // note: this is signed
 265                         v += ReadByte();          // note: this is unsigned
 266                         return v;
 267                 }
 268                 vector ReadInt48_t()
 269                 {
 270                         vector v;
 271                         v.x = ReadInt24_t();
 272                         v.y = ReadInt24_t();
 273                         v.z = 0;
 274                         return v;
 275                 }
 276                 vector ReadInt72_t()
 277                 {
 278                         vector v;
 279                         v.x = ReadInt24_t();
 280                         v.y = ReadInt24_t();
 281                         v.z = ReadInt24_t();
 282                         return v;
 283                 }
 284
 285                 int _ReadSByte;
 286                 #define ReadSByte() (_ReadSByte = ReadByte(), (_ReadSByte & BIT(7) ? -128 : 0) + (_ReadSByte & BITS(7)))
 287                 #define ReadFloat() ReadCoord()
 288         vector ReadVector() { vector v; v.x = ReadFloat(); v.y = ReadFloat(); v.z = ReadFloat(); return v; }
 289                 vector ReadVector2D() { vector v; v.x = ReadFloat(); v.y = ReadFloat(); v.z = 0; return v; }
 290
 291                 float ReadApproxPastTime()
 292                 {
 293                         float dt = ReadByte();
 294
 295                         // map from range...PPROXPASTTIME_MAX / 256
 296                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 297
 298                         return servertime - dt;
 299                 }
 300
 301         #else
 302                 void WriteInt24_t(float dst, float val)
 303                 {
 304                         float v;
 305                         WriteShort(dst, (v = floor(val >> 8)));
 306                         WriteByte(dst, val - (v << 8));  // 0..255
 307                 }
 308                 void WriteInt48_t(float dst, vector val)
 309                 {
 310                         WriteInt24_t(dst, val.x);
 311                         WriteInt24_t(dst, val.y);
 312                 }
 313                 void WriteInt72_t(float dst, vector val)
 314                 {
 315                         WriteInt24_t(dst, val.x);
 316                         WriteInt24_t(dst, val.y);
 317                         WriteInt24_t(dst, val.z);
 318                 }
 319
 320         #define WriteFloat(to, f) WriteCoord(to, f)
 321                 #define WriteVector(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); } MACRO_END
 322         #define WriteVector2D(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); } MACRO_END
 323
 324                 // this will use the value:
 325                 //   128
 326                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 327                 // accuracy at x is 1/derivative, i.e.
 328                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 329                 void WriteApproxPastTime(float dst, float t)
 330                 {
 331                         float dt = time - t;
 332
 333                         // warning: this is approximate; do not resend when you don't have to!
 334                         // be careful with sendflags here!
 335                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 336
 337                         // map to range...
 338                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 339
 340                         // round...
 341                         dt = rint(bound(0, dt, 255));
 342
 343                         WriteByte(dst, dt);
 344                 }
 345
 346                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 347                 #define WRITESPECTATABLE_MSG_ONE(to, statement) MACRO_BEGIN { \
 348                         entity prev = msg_entity; \
 349                         entity dst = to; \
 350                         FOREACH_CLIENT(IS_REAL_CLIENT(it), { \
 351                                 if (it == dst || (it.classname == STR_SPECTATOR && it.enemy == dst)) \
 352                                 { \
 353                                         msg_entity = it; \
 354                                         LAMBDA(statement); \
 355                                 } \
 356                         }); \
 357                         msg_entity = prev; \
 358                 } MACRO_END
 359         #endif
 360 #endif