qcsrc/lib/oo.qh

   1 #pragma once
   2
   3 #include "misc.qh"
   4 #include "nil.qh"
   5 #include "static.qh"
   6
   7 #ifdef MENUQC
   8         #define NULL (0, null_entity)
   9 #else
  10         #define NULL (0, world)
  11 #endif
  12
  13 .vector origin;
  14 .bool pure_data;
  15 /** @deprecated use new_pure or NEW(class) */
  16 #define make_pure(e) \
  17         MACRO_BEGIN \
  18         { \
  19                 (e).pure_data = true; \
  20         } MACRO_END
  21 #define make_impure(e) \
  22         MACRO_BEGIN \
  23         { \
  24                 (e).pure_data = false; \
  25         } MACRO_END
  26 #define is_pure(e) ((e).pure_data)
  27
  28 .string classname;
  29 /** Location entity was spawned from in source */
  30 .string sourceLoc;
  31 entity _spawn();
  32
  33 #ifndef SPAWN_PURE
  34 #define SPAWN_PURE 0
  35 #endif
  36
  37 // pure entities: need no .origin
  38 #if SPAWN_PURE
  39 entity spawn_pure() = #600;
  40 #else
  41 #define spawn_pure() _spawn()
  42 #endif
  43
  44 entity __spawn(string _classname, string _sourceLoc, bool pure)
  45 {
  46         entity this = pure ? spawn_pure() : _spawn();
  47         this.classname = _classname;
  48         this.sourceLoc = _sourceLoc;
  49         if (pure) {
  50                 make_pure(this);
  51                 #ifdef CSQC
  52                 setorigin(this, '0 0 10000');
  53                 #endif
  54                 #ifdef SVQC
  55         setorigin(this, '0 0 -10000');
  56         #endif
  57         }
  58         return this;
  59 }
  60
  61
  62 #define entityclass(...) EVAL_entityclass(OVERLOAD_(entityclass, __VA_ARGS__))
  63 #define EVAL_entityclass(...) __VA_ARGS__
  64 #define entityclass_1(name) entityclass_2(name, Object)
  65 #ifndef QCC_SUPPORT_ENTITYCLASS
  66         #define entityclass_2(name, base) USING(name, entity)
  67         #define class(name)
  68         #define _new(class, pure) __spawn( #class, __FILE__ ":" STR(__LINE__), pure)
  69 #else
  70         #define entityclass_2(name, base) entityclass name : base {}
  71         #define class(name) [[class(name)]]
  72         #define _new(class, pure) ((class) __spawn( #class, __FILE__ ":" STR(__LINE__), pure))
  73 #endif
  74 /** entities you care about seeing (.origin works) */
  75 #define new(class) _new(class, false)
  76 /** purely logical entities (.origin doesn't work) */
  77 #define new_pure(class) _new(class, true)
  78 #define spawn() __spawn("entity", __FILE__ ":" STR(__LINE__), false)
  79
  80 #define delete(this) MACRO_BEGIN { \
  81     entity _this = (this); \
  82     void(entity) _dtor = _this.dtor; \
  83     if (_dtor) _dtor(_this); else remove(_this); \
  84     /* this = NULL; */  \
  85 } MACRO_END
  86
  87 entity _clearentity_ent;
  88 STATIC_INIT(clearentity)
  89 {
  90         _clearentity_ent = new_pure(clearentity);
  91 }
  92 void clearentity(entity e)
  93 {
  94 #ifdef CSQC
  95                 int n = e.entnum;
  96 #endif
  97         bool was_pure = is_pure(e);
  98         copyentity(_clearentity_ent, e);
  99         if (!was_pure) make_impure(e);
 100 #ifdef CSQC
 101                 e.entnum = n;
 102 #endif
 103 }
 104
 105 // Classes have a `spawn##cname(entity)` constructor
 106 // The parameter is used across [[accumulate]] functions
 107
 108 .bool transmute;
 109
 110 // Macros to hide this implementation detail:
 111 #ifdef __STDC__
 112         #define NEW(cname, ...) \
 113                 OVERLOAD_(spawn##cname, new_pure(cname) P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 114
 115     #define TRANSMUTE(cname, this, ...) \
 116         OVERLOAD_(spawn##cname, (this.transmute = true, this.classname = #cname, this) P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 117
 118         #define CONSTRUCT(cname, ...) \
 119                 OVERLOAD_(spawn##cname, this P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 120 #else
 121         #define NEW(cname, ...) \
 122                 OVERLOAD(spawn##cname, new_pure(cname),##__VA_ARGS__)
 123
 124     #define TRANSMUTE(cname, this, ...) \
 125         OVERLOAD(spawn##cname, (this.transmute = true, this.classname = #cname, this),##__VA_ARGS__)
 126
 127         #define CONSTRUCT(cname, ...) \
 128                 OVERLOAD(spawn##cname, this,##__VA_ARGS__)
 129 #endif
 130
 131 #define CONSTRUCTOR(cname, ...) \
 132         cname OVERLOAD(spawn##cname, cname this, __VA_ARGS__) \
 133         { \
 134                 return = this; \
 135         } \
 136         [[accumulate]] cname OVERLOAD(spawn##cname, cname this, __VA_ARGS__)
 137
 138 .string vtblname;
 139 .entity vtblbase;
 140
 141 void RegisterClasses() {}
 142 STATIC_INIT(RegisterClasses)
 143 {
 144         RegisterClasses();
 145 }
 146
 147 #define VTBL(cname, base) \
 148         _INIT_STATIC(cname); \
 149         entity cname##_vtbl; \
 150         void cname##_vtbl_init() \
 151         { \
 152                 cname e = new_pure(vtbl); \
 153                 spawn##cname##_static(e); \
 154                 e.vtblname = #cname; \
 155                 /* Top level objects refer to themselves */ \
 156                 e.vtblbase = base##_vtbl ? base##_vtbl : e; \
 157                 cname##_vtbl = e; \
 158         } \
 159         ACCUMULATE_FUNCTION(RegisterClasses, cname##_vtbl_init)
 160
 161 #define _INIT_STATIC(cname) [[accumulate]] void spawn##cname##_static(cname this)
 162 #define INIT(cname) [[accumulate]] cname spawn##cname##_1(cname this)
 163
 164 #define CLASS(cname, base)                  \
 165         entityclass(cname, base);               \
 166         class(cname).bool instanceOf##cname;    \
 167     bool is_##cname(entity e) { return e.instanceOf##cname; } \
 168         VTBL(cname, base)                       \
 169         _INIT_STATIC(cname)                     \
 170         {                                       \
 171                 if (cname##_vtbl && !this.transmute)\
 172                 {                                   \
 173                         copyentity(cname##_vtbl, this); \
 174                         return;                         \
 175                 }                                   \
 176                 spawn##base##_static(this);         \
 177                 this.instanceOf##cname = true;      \
 178         }                                       \
 179         INIT(cname)                             \
 180         {                                       \
 181                 /* Only statically initialize the current class, it contains everything it inherits */ \
 182                 if (cname##_vtbl.vtblname == this.classname) \
 183                 {                                   \
 184                         spawn##cname##_static(this);    \
 185                         this.transmute = false;         \
 186                         this.classname = #cname;        \
 187                         this.vtblname = string_null;    \
 188                         this.vtblbase = cname##_vtbl;   \
 189                 }                                   \
 190                 spawn##base##_1(this);              \
 191         }
 192
 193 #define METHOD_REFERENCE(cname, name) \
 194         cname##_##name
 195
 196 #define STATIC_METHOD(cname, name, prototype) \
 197         prototype METHOD_REFERENCE(cname, name)
 198
 199 #define METHOD(cname, name, prototype) \
 200         STATIC_METHOD(cname, name, prototype); \
 201         class(cname) .prototype name; \
 202         _INIT_STATIC(cname) \
 203         { \
 204                 this.name = METHOD_REFERENCE(cname, name); \
 205         } \
 206         STATIC_METHOD(cname, name, prototype)
 207
 208 #define DESTRUCTOR(cname) \
 209         STATIC_METHOD(cname, dtorimpl, void(cname this)); \
 210     METHOD(cname, dtor, void(cname this)) \
 211     { \
 212         METHOD_REFERENCE(cname, dtorimpl)(this); \
 213         entity super = SUPER(cname); \
 214         if (super != cname##_vtbl) super.dtor(this); \
 215     } \
 216         STATIC_METHOD(cname, dtorimpl, void(cname this))
 217
 218 #define ATTRIB(cname, name, type, val)      \
 219         class(cname).type name;                \
 220         INIT(cname) \
 221         { \
 222                 noref bool strzone; /* Error on strzone() calls. */ \
 223                 this.name = val; \
 224         }
 225
 226 #define STATIC_ATTRIB(cname, name, type, val) \
 227         type cname##_##name; \
 228         _INIT_STATIC(cname) \
 229         { \
 230                 noref bool strzone; /* Error on strzone() calls. */ \
 231                 cname##_##name = val; \
 232         }
 233
 234 // cleanup potentially zoned strings from base classes
 235
 236 #define ATTRIB_STRZONE(cname, name, type, val)      \
 237         class(cname).type name;                \
 238         INIT(cname) \
 239         { \
 240                 if (this.name) \
 241                         strunzone(this.name); \
 242                 this.name = strzone(val); \
 243         }
 244
 245 #define STATIC_ATTRIB_STRZONE(cname, name, type, val) \
 246         type cname##_##name; \
 247         _INIT_STATIC(cname) \
 248         { \
 249         if (cname##_##name) \
 250             strunzone(cname##_##name); \
 251                 cname##_##name = val; \
 252         }
 253
 254 #define ATTRIBARRAY(cname, name, type, cnt) \
 255         class(cname).type name[cnt];
 256
 257 #define ENDCLASS(cname) \
 258         INIT(cname) \
 259         { \
 260                 return this; \
 261         }
 262
 263 #define SUPER(cname) (cname##_vtbl.vtblbase)
 264
 265 #define spawn_static(this)
 266 #define spawn_1(this)
 267 #define _vtbl NULL
 268 CLASS(Object, );
 269     DESTRUCTOR(Object) { remove(this); }
 270     #define remove(this) delete(this)
 271         METHOD(Object, describe, string(Object this))
 272         {
 273             TC(Object, this);
 274                 string s = _("No description");
 275                 if (cvar("developer"))
 276                 {
 277                         for (int i = 0, n = numentityfields(); i < n; ++i)
 278                         {
 279                                 string value = getentityfieldstring(i, this);
 280                                 if (value != "") s = sprintf("%s\n%s = %s", s, entityfieldname(i), value);
 281                         }
 282                 }
 283                 return s;
 284         }
 285         METHOD(Object, display, void(Object this, void(string name, string icon) returns))
 286         {
 287             TC(Object, this);
 288                 returns(sprintf("entity %i", this), "nopreview_map");
 289         }
 290 ENDCLASS(Object)
 291 #undef spawn_static
 292 #undef spawn_1
 293 #undef _vtbl