qcsrc/lib/sort.qh

   1 #pragma once
   2
   3 /** is only ever called for i1 < i2 */
   4 USING(swapfunc_t, void (int i1, int i2, entity pass));
   5 /** <0 for <, ==0 for ==, >0 for > (like strcmp) */
   6 USING(comparefunc_t, int (int i1, int i2, entity pass));
   7
   8 ERASEABLE
   9 void heapsort(int n, swapfunc_t swap, comparefunc_t cmp, entity pass)
  10 {
  11         #define heapify(_count) \
  12                 MACRO_BEGIN \
  13                 { \
  14                         for (int start = floor(((_count) - 2) / 2); start >= 0; --start) \
  15                         { \
  16                                 siftdown(start, (_count) - 1); \
  17                         } \
  18                 } MACRO_END
  19
  20         #define siftdown(_start, _end) \
  21                 MACRO_BEGIN \
  22                 { \
  23                         for (int root = (_start); root * 2 + 1 <= (_end); ) \
  24                         { \
  25                                 int child = root * 2 + 1; \
  26                                 if (child < (_end) && cmp(child, child + 1, pass) < 0) child += 1; \
  27                                 if (cmp(root, child, pass) >= 0) break; \
  28                                 swap(root, child, pass); \
  29                                 root = child; \
  30                         } \
  31                 } MACRO_END
  32
  33         heapify(n);
  34         int end = n - 1;
  35         while (end > 0)
  36         {
  37                 swap(0, end, pass);
  38                 end -= 1;
  39                 siftdown(0, end);
  40         }
  41 }
  42
  43 ERASEABLE
  44 void shuffle(float n, swapfunc_t swap, entity pass)
  45 {
  46         for (int i = 1; i < n; ++i)
  47         {
  48                 // swap i-th item at a random position from 0 to i
  49                 // proof for even distribution:
  50                 //   n = 1: obvious
  51                 //   n -> n+1:
  52                 //     item n+1 gets at any position with chance 1/(n+1)
  53                 //     all others will get their 1/n chance reduced by factor n/(n+1)
  54                 //     to be on place n+1, their chance will be 1/(n+1)
  55                 //     1/n * n/(n+1) = 1/(n+1)
  56                 //     q.e.d.
  57                 int j = floor(random() * (i + 1));
  58                 if (j != i) swap(j, i, pass);
  59         }
  60 }