qcsrc/lib/stats.qh

   1 #pragma once
   2
   3 // TODO: rename to 'netvars'
   4
   5 #include "registry.qh"
   6 #include "sort.qh"
   7
   8 .int m_id;
   9 USING(vectori, vector);
  10
  11 const int STATS_ENGINE_RESERVE = 32;
  12 // must be listed in ascending order
  13 #define MAGIC_STATS(_, x) \
  14         _(x, MOVEVARS_TIMESCALE, 241) \
  15         /**/
  16
  17 int g_magic_stats_hole = 0;
  18
  19 #define MAGIC_STATS_FIX_MANUAL(it, var, id) \
  20         if (it.registered_id == "STAT_" #var) { --g_magic_stats_hole; it.m_id = id; } else
  21
  22 #define MAGIC_STATS_FIX_AUTO(it, var, id) \
  23         if (it.m_id == id) { ++g_magic_stats_hole; ++it.m_id; }
  24
  25 #define MAGIC_STATS_FIX(it) \
  26         it.m_id += g_magic_stats_hole; \
  27         MAGIC_STATS(MAGIC_STATS_FIX_MANUAL, it) { MAGIC_STATS(MAGIC_STATS_FIX_AUTO, it) }
  28
  29 #define REGISTER_STAT(...) EVAL_REGISTER_STAT(OVERLOAD(REGISTER_STAT, __VA_ARGS__))
  30 #define EVAL_REGISTER_STAT(...) __VA_ARGS__
  31 #if defined(CSQC)
  32         /** Get all stats and store them as globals, access with `STAT(ID)` */
  33         void stats_get() {}
  34         #define STAT(...) EVAL_STAT(OVERLOAD(STAT, __VA_ARGS__))
  35         #define EVAL_STAT(...) __VA_ARGS__
  36     #define STAT_1(id) STAT_2(id, NULL)
  37         #define STAT_2(id, cl) (0, _STAT(id))
  38
  39         #define getstat_int(id) getstati(id, 0, 24)
  40         #define getstat_bool(id) boolean(getstati(id))
  41         #define getstat_float(id) getstatf(id)
  42         #define getstat_vector(id) vec3(getstat_float(id + 0), getstat_float(id + 1), getstat_float(id + 2))
  43         #define getstat_vectori(id) vec3(getstat_int(id + 0), getstat_int(id + 1), getstat_int(id + 2))
  44
  45         #define _STAT(id) g_stat_##id
  46         #define REGISTER_STAT_2(id, T) \
  47                 T _STAT(id); \
  48                 /* T CAT(_STAT(id), _prev); */ \
  49                 REGISTER(Stats, STAT_##id, m_id, new_pure(stat)) \
  50                 { \
  51                         if (#T == "vector" || #T == "vectori") { \
  52                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, y); \
  53                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, z); \
  54                         } \
  55                 } \
  56                 [[accumulate]] void stats_get() \
  57                 { \
  58                         T it = getstat_##T(STAT_##id.m_id); \
  59                         /* if (it != CAT(_STAT(id), _prev)) \
  60                                 CAT(_STAT(id), _prev) = */ _STAT(id) = it; \
  61                 }
  62         #define REGISTER_STAT_3(x, T, expr) REGISTER_STAT_2(x, T)
  63 #elif defined(SVQC)
  64         /** Add all registered stats, access with `STAT(ID, player)` or `.type stat = _STAT(ID); player.stat` */
  65         void stats_add() {}
  66         #define STAT(id, cl) (cl)._STAT(id)
  67
  68         #define addstat_int(id, fld) addstat(id, AS_INT, fld)
  69         #define addstat_bool(id, fld) addstat(id, AS_INT, fld)
  70         #define addstat_float(id, fld) addstat(id, AS_FLOAT, fld)
  71         #define addstat_vector(id, fld) MACRO_BEGIN { \
  72                 addstat_float(id + 0, fld##_x); \
  73                 addstat_float(id + 1, fld##_y); \
  74                 addstat_float(id + 2, fld##_z); \
  75         } MACRO_END
  76         #define addstat_vectori(id, fld) MACRO_BEGIN { \
  77                 addstat_int(id + 0, fld##_x); \
  78                 addstat_int(id + 1, fld##_y); \
  79                 addstat_int(id + 2, fld##_z); \
  80         } MACRO_END
  81         const int AS_STRING = 1;
  82         const int AS_INT = 2;
  83         const int AS_FLOAT = 8;
  84
  85         .int __stat_null;
  86         /** Prevent engine stats being sent */
  87         STATIC_INIT(stats_clear)
  88         {
  89                 int r = STATS_ENGINE_RESERVE;
  90                 for (int i = 0, n = 256 - r; i < n; ++i) {
  91                         #define X(_, name, id) if (i == id) continue;
  92                         MAGIC_STATS(X, );
  93                         #undef X
  94                         addstat(r + i, AS_INT, __stat_null);
  95                 }
  96         }
  97
  98         #define _STAT(id) stat_##id
  99         #define REGISTER_STAT_2(id, T) \
 100                 .T _STAT(id); \
 101                 REGISTER(Stats, STAT_##id, m_id, new_pure(stat)) \
 102                 { \
 103                         if (#T == "vector" || #T == "vectori") { \
 104                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, y); \
 105                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, z); \
 106                         } \
 107                 } \
 108                 [[accumulate]] void stats_add() \
 109                 { \
 110                         .T fld = _STAT(id); \
 111                         addstat_##T(STAT_##id.m_id, fld); \
 112                 }
 113         void GlobalStats_update(entity this) {}
 114     #define REGISTER_STAT_3(id, T, expr) \
 115         REGISTER_STAT_2(id, T); \
 116         [[accumulate]] void GlobalStats_update(entity this) { STAT(id, this) = (expr); } \
 117         STATIC_INIT(worldstat_##id) { entity this = NULL; STAT(id, this) = (expr); }
 118 #else
 119         #define REGISTER_STAT_2(id, type)
 120     #define REGISTER_STAT_3(id, T, expr)
 121 #endif
 122
 123 REGISTRY(Stats, 256 - STATS_ENGINE_RESERVE)
 124 REGISTER_REGISTRY(Stats)
 125 REGISTRY_SORT(Stats)
 126 REGISTRY_CHECK(Stats)
 127 STATIC_INIT(RegisterStats_renumber)
 128 {
 129         FOREACH(Stats, true, {
 130                 it.m_id = STATS_ENGINE_RESERVE + i;
 131                 MAGIC_STATS_FIX(it);
 132         });
 133 }
 134 #ifdef SVQC
 135 STATIC_INIT(stats_add) { stats_add(); }
 136 #endif