qcsrc/lib/string.qh

   1 #pragma once
   2
   3 #include "nil.qh"
   4 #include "sort.qh"
   5 #include "oo.qh"
   6
   7 #ifdef CSQC
   8         float stringwidth_colors(string s, vector theSize)
   9         {
  10                 return stringwidth_builtin(s, true, theSize);
  11         }
  12
  13         float stringwidth_nocolors(string s, vector theSize)
  14         {
  15                 return stringwidth_builtin(s, false, theSize);
  16         }
  17 #endif
  18 #ifdef MENUQC
  19         float stringwidth_colors(string s, vector theSize)
  20         {
  21                 return stringwidth(s, true, theSize);
  22         }
  23
  24         float stringwidth_nocolors(string s, vector theSize)
  25         {
  26                 return stringwidth(s, false, theSize);
  27         }
  28 #endif
  29
  30 ERASEABLE
  31 string seconds_tostring(float sec)
  32 {
  33         float minutes = floor(sec / 60);
  34         sec -= minutes * 60;
  35         return sprintf("%d:%02d", minutes, sec);
  36 }
  37
  38 ERASEABLE
  39 string format_time(float seconds)
  40 {
  41         seconds = floor(seconds + 0.5);
  42         float days = floor(seconds / 864000);
  43         seconds -= days * 864000;
  44         float hours = floor(seconds / 36000);
  45         seconds -= hours * 36000;
  46         float minutes = floor(seconds / 600);
  47         seconds -= minutes * 600;
  48         if (days > 0) return sprintf(_("%d days, %02d:%02d:%02d"), days, hours, minutes, seconds);
  49         else return sprintf(_("%02d:%02d:%02d"), hours, minutes, seconds);
  50 }
  51
  52 ERASEABLE
  53 string mmsss(float tenths)
  54 {
  55         tenths = floor(tenths + 0.5);
  56         float minutes = floor(tenths / 600);
  57         tenths -= minutes * 600;
  58         string s = ftos(1000 + tenths);
  59         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
  60 }
  61
  62 ERASEABLE
  63 string mmssss(float hundredths)
  64 {
  65         hundredths = floor(hundredths + 0.5);
  66         float minutes = floor(hundredths / 6000);
  67         hundredths -= minutes * 6000;
  68         string s = ftos(10000 + hundredths);
  69         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
  70 }
  71
  72 int ColorTranslateMode;
  73
  74 ERASEABLE
  75 string ColorTranslateRGB(string s)
  76 {
  77         return (ColorTranslateMode & 1) ? strdecolorize(s) : s;
  78 }
  79
  80 #ifdef GAMEQC
  81 // color code replace, place inside of sprintf and parse the string... defaults described as constants
  82 // foreground/normal colors
  83 string autocvar_hud_colorset_foreground_1 = "2"; // F1 - Green  // primary priority (important names, etc)
  84 string autocvar_hud_colorset_foreground_2 = "3"; // F2 - Yellow // secondary priority (items, locations, numbers, etc)
  85 string autocvar_hud_colorset_foreground_3 = "4"; // F3 - Blue   // tertiary priority or relatively inconsequential text
  86 string autocvar_hud_colorset_foreground_4 = "1"; // F4 - Red    // notice/attention grabbing texting
  87 // "kill" colors
  88 string autocvar_hud_colorset_kill_1 = "1";       // K1 - Red    // "bad" or "dangerous" text (death messages against you, kill notifications, etc)
  89 string autocvar_hud_colorset_kill_2 = "3";       // K2 - Yellow // similar to above, but less important... OR, a highlight out of above message type
  90 string autocvar_hud_colorset_kill_3 = "4";       // K3 - Blue   // "good" or "beneficial" text (you fragging someone, etc)
  91 // background color
  92 string autocvar_hud_colorset_background = "7";   // BG - White // neutral/unimportant text
  93
  94 /** color code replace, place inside of sprintf and parse the string */
  95 string CCR(string input)
  96 {
  97         // See the autocvar declarations in util.qh for default values
  98
  99         // foreground/normal colors
 100         input = strreplace("^F1", strcat("^", autocvar_hud_colorset_foreground_1), input);
 101         input = strreplace("^F2", strcat("^", autocvar_hud_colorset_foreground_2), input);
 102         input = strreplace("^F3", strcat("^", autocvar_hud_colorset_foreground_3), input);
 103         input = strreplace("^F4", strcat("^", autocvar_hud_colorset_foreground_4), input);
 104
 105         // "kill" colors
 106         input = strreplace("^K1", strcat("^", autocvar_hud_colorset_kill_1), input);
 107         input = strreplace("^K2", strcat("^", autocvar_hud_colorset_kill_2), input);
 108         input = strreplace("^K3", strcat("^", autocvar_hud_colorset_kill_3), input);
 109
 110         // background colors
 111         input = strreplace("^BG", strcat("^", autocvar_hud_colorset_background), input);
 112         input = strreplace("^N", "^7", input);  // "none"-- reset to white...
 113         return input;
 114 }
 115 #endif
 116
 117 #define startsWith(haystack, needle) (strstrofs(haystack, needle, 0) == 0)
 118
 119 ERASEABLE
 120 bool startsWithNocase(string haystack, string needle)
 121 {
 122         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
 123 }
 124
 125 noref string _endsWith_suffix;
 126 #define endsWith(this, suffix) (_endsWith_suffix = suffix, substring(this, -strlen(_endsWith_suffix), -1) == _endsWith_suffix)
 127
 128 /** unzone the string, and return it as tempstring. Safe to be called on string_null */
 129 ERASEABLE
 130 string fstrunzone(string s)
 131 {
 132         if (!s) return s;
 133         string sc = strcat(s, "");
 134         strunzone(s);
 135         return sc;
 136 }
 137
 138 /** returns first word */
 139 ERASEABLE
 140 string car(string s)
 141 {
 142         int o = strstrofs(s, " ", 0);
 143         if (o < 0) return s;
 144         return substring(s, 0, o);
 145 }
 146
 147 /** returns all but first word */
 148 ERASEABLE
 149 string cdr(string s)
 150 {
 151         int o = strstrofs(s, " ", 0);
 152         if (o < 0) return string_null;
 153         return substring(s, o + 1, strlen(s) - (o + 1));
 154 }
 155
 156 ERASEABLE
 157 string cons(string a, string b)
 158 {
 159         if (a == "") return b;
 160         if (b == "") return a;
 161         return strcat(a, " ", b);
 162 }
 163
 164 ERASEABLE
 165 string substring_range(string s, float b, float e)
 166 {
 167         return substring(s, b, e - b);
 168 }
 169
 170 ERASEABLE
 171 string swapwords(string str, float i, float j)
 172 {
 173         float n;
 174         string s1, s2, s3, s4, s5;
 175         float si, ei, sj, ej, s0, en;
 176         n = tokenizebyseparator(str, " ");  // must match g_maplist processing in ShuffleMaplist and "shuffle"
 177         si = argv_start_index(i);
 178         sj = argv_start_index(j);
 179         ei = argv_end_index(i);
 180         ej = argv_end_index(j);
 181         s0 = argv_start_index(0);
 182         en = argv_end_index(n - 1);
 183         s1 = substring_range(str, s0, si);
 184         s2 = substring_range(str, si, ei);
 185         s3 = substring_range(str, ei, sj);
 186         s4 = substring_range(str, sj, ej);
 187         s5 = substring_range(str, ej, en);
 188         return strcat(s1, s4, s3, s2, s5);
 189 }
 190
 191 string _shufflewords_str;
 192 ERASEABLE
 193 void _shufflewords_swapfunc(float i, float j, entity pass)
 194 {
 195         _shufflewords_str = swapwords(_shufflewords_str, i, j);
 196 }
 197
 198 ERASEABLE
 199 string shufflewords(string str)
 200 {
 201         _shufflewords_str = str;
 202         int n = tokenizebyseparator(str, " ");
 203         shuffle(n, _shufflewords_swapfunc, NULL);
 204         str = _shufflewords_str;
 205         _shufflewords_str = string_null;
 206         return str;
 207 }
 208
 209 ERASEABLE
 210 string unescape(string in)
 211 {
 212         in = strzone(in);  // but it doesn't seem to be necessary in my tests at least
 213
 214         int len = strlen(in);
 215         string str = "";
 216         for (int i = 0; i < len; ++i)
 217         {
 218                 string s = substring(in, i, 1);
 219                 if (s == "\\")
 220                 {
 221                         s = substring(in, i + 1, 1);
 222                         if (s == "n") str = strcat(str, "\n");
 223                         else if (s == "\\") str = strcat(str, "\\");
 224                         else str = strcat(str, substring(in, i, 2));
 225                         ++i;
 226                         continue;
 227                 }
 228                 str = strcat(str, s);
 229         }
 230         strunzone(in);
 231         return str;
 232 }
 233
 234 ERASEABLE
 235 string strwords(string s, int w)
 236 {
 237         int endpos = 0;
 238         for ( ; w && endpos >= 0; --w)
 239                 endpos = strstrofs(s, " ", endpos + 1);
 240         if (endpos < 0) return s;
 241         return substring(s, 0, endpos);
 242 }
 243
 244 #define strhasword(s, w) (strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0)
 245
 246 ERASEABLE
 247 int u8_strsize(string s)
 248 {
 249         int l = 0;
 250         for (int i = 0, c; (c = str2chr(s, i)) > 0; ++i, ++l)
 251         {
 252                 l += (c >= 0x80);
 253                 l += (c >= 0x800);
 254                 l += (c >= 0x10000);
 255         }
 256         return l;
 257 }
 258
 259 //List of Unicode spaces: https://www.cs.tut.fi/~jkorpela/chars/spaces.html
 260 ERASEABLE
 261 bool isInvisibleString(string s)
 262 {
 263         s = strdecolorize(s);
 264         bool utf8 = cvar("utf8_enable");
 265         for (int i = 0, n = strlen(s); i < n; ++i)
 266         {
 267                 int c = str2chr(s, i);
 268                 switch (c)
 269                 {
 270                         case 0:
 271                         case 32:           // space
 272                                 break;
 273                         case 192:          // charmap space
 274                                 if (!utf8) break;
 275                                 return false;
 276                         case 0xE000 + 192: // utf8 charmap space
 277                         case 0x00A0: // NO-BREAK SPACE
 278                         //case 0x1680: // OGHAM SPACE MARK
 279                         case 0x180E: // MONGOLIAN VOWEL SEPARATOR
 280                         case 0x2000: // EN QUAD
 281                         case 0x2001: // EM QUAD
 282                         case 0x2002: // EN SPACE
 283                         case 0x2003: // EM SPACE
 284                         case 0x2004: // THREE-PER-EM SPACE
 285                         case 0x2005: // FOUR-PER-EM SPACE
 286                         case 0x2006: // SIX-PER-EM SPACE
 287                         case 0x2007: // FIGURE SPACE
 288                         case 0x2008: // PUNCTUATION SPACE
 289                         case 0x2009: // THIN SPACE
 290                         case 0x200A: // HAIR SPACE
 291                         case 0x200B: // ZERO WIDTH SPACE
 292                         case 0x202F: // NARROW NO-BREAK SPACE
 293                         case 0x205F: // MEDIUM MATHEMATICAL SPACE
 294                         case 0x3000: // IDEOGRAPHIC SPACE
 295                         case 0xFEFF: // ZERO WIDTH NO-BREAK SPACE
 296                                 if (utf8) break;
 297                         default:
 298                                 return false;
 299                 }
 300         }
 301         return true;
 302 }
 303
 304 // Multiline text file buffers
 305
 306 ERASEABLE
 307 int buf_load(string pFilename)
 308 {
 309         int buf = buf_create();
 310         if (buf < 0) return -1;
 311         int fh = fopen(pFilename, FILE_READ);
 312         if (fh < 0)
 313         {
 314                 buf_del(buf);
 315                 return -1;
 316         }
 317         string l;
 318         for (int i = 0; (l = fgets(fh)); ++i)
 319                 bufstr_set(buf, i, l);
 320         fclose(fh);
 321         return buf;
 322 }
 323
 324 ERASEABLE
 325 void buf_save(float buf, string pFilename)
 326 {
 327         int fh = fopen(pFilename, FILE_WRITE);
 328         if (fh < 0) error(strcat("Can't write buf to ", pFilename));
 329         int n = buf_getsize(buf);
 330         for (int i = 0; i < n; ++i)
 331                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 332         fclose(fh);
 333 }
 334
 335 /**
 336  * converts a number to a string with the indicated number of decimals
 337  */
 338 ERASEABLE
 339 string ftos_decimals(float number, int decimals)
 340 {
 341         // inhibit stupid negative zero
 342         if (number == 0) number = 0;
 343         return sprintf("%.*f", decimals, number);
 344 }
 345
 346 /**
 347  * converts a number to a string with the minimum number of decimals
 348  */
 349 ERASEABLE
 350 string ftos_mindecimals(float number)
 351 {
 352         // inhibit stupid negative zero
 353         if (number == 0) number = 0;
 354         return sprintf("%.7g", number);
 355 }
 356
 357 ERASEABLE
 358 int vercmp_recursive(string v1, string v2)
 359 {
 360         int dot1 = strstrofs(v1, ".", 0);
 361         int dot2 = strstrofs(v2, ".", 0);
 362         string s1 = (dot1 == -1) ? v1 : substring(v1, 0, dot1);
 363         string s2 = (dot2 == -1) ? v2 : substring(v2, 0, dot2);
 364
 365         float r;
 366         r = stof(s1) - stof(s2);
 367         if (r != 0) return r;
 368
 369         r = strcasecmp(s1, s2);
 370         if (r != 0) return r;
 371
 372         if (dot1 == -1) return (dot2 == -1) ? 0 : -1;
 373         else return (dot2 == -1) ? 1 : vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
 374 }
 375
 376 ERASEABLE
 377 int vercmp(string v1, string v2)
 378 {
 379         if (strcasecmp(v1, v2) == 0) return 0;  // early out check
 380
 381         // "git" beats all
 382         if (v1 == "git") return 1;
 383         if (v2 == "git") return -1;
 384
 385         return vercmp_recursive(v1, v2);
 386 }
 387
 388 const string HEXDIGITS_MINSET = "0123456789ABCDEFabcdef";
 389 const string HEXDIGITS = "0123456789ABCDEF0123456789abcdef";
 390 #define HEXDIGIT_TO_DEC_RAW(d) (strstrofs(HEXDIGITS, (d), 0))
 391 #define HEXDIGIT_TO_DEC(d) ((HEXDIGIT_TO_DEC_RAW(d) | 0x10) - 0x10)
 392 #define DEC_TO_HEXDIGIT(d) (substring(HEXDIGITS_MINSET, (d), 1))
 393 #define IS_HEXDIGIT(d) (strstrofs(HEXDIGITS_MINSET, (d), 0) >= 0)
 394
 395 const string DIGITS = "0123456789";
 396 #define IS_DIGIT(d) (strstrofs(DIGITS, (d), 0) >= 0)