Rename a lib function (overlaps with an old map entity field)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / lib / vector.qh
1 #pragma once
2
3 noref vector _vlen2;
4 #define vlen2(v) (_vlen2 = (v), dotproduct(_vlen2, _vlen2))
5
6 #if 1
7 noref float _vdist_f;
8 /** Vector distance comparison, avoids sqrt() */
9 #define vdist(v, cmp, f) (vlen2(v) cmp (_vdist_f = (f), _vdist_f * _vdist_f))
10 #else
11 #define vdist(v, cmp, f) (vlen(v) cmp (f))
12 #endif
13
14 #if 1
15 #define dotproduct(a, b) ((a) * (b))
16 #else
17 noref vector _dotproduct_a, _dotproduct_b;
18 #define dotproduct(a, b) \
19         (_dotproduct_a = (a), _dotproduct_b = (b), \
20           _dotproduct_a.x * _dotproduct_b.x \
21         + _dotproduct_a.y * _dotproduct_b.y \
22         + _dotproduct_a.z * _dotproduct_b.z)
23 #endif
24
25 #if 1
26 #define cross(a, b) ((a) >< (b))
27 #else
28 vector cross(vector a, vector b)
29 {
30         return
31                 '1 0 0' * (a.y * b.z - a.z * b.y)
32         +       '0 1 0' * (a.z * b.x - a.x * b.z)
33         +       '0 0 1' * (a.x * b.y - a.y * b.x);
34 }
35 #endif
36
37 noref vector _vmul_a, _vmul_b;
38 #define vmul(a, b) \
39     (_vmul_a = (a), _vmul_b = (b), \
40           '1 0 0' * (_vmul_a.x * _vmul_b.x) \
41         + '0 1 0' * (_vmul_a.y * _vmul_b.y) \
42         + '0 0 1' * (_vmul_a.z * _vmul_b.z))
43
44 const vector eX = '1 0 0';
45 const vector eY = '0 1 0';
46 const vector eZ = '0 0 1';
47
48 vector randompos(vector m1, vector m2)
49 {
50         vector v;
51         m2 = m2 - m1;
52         v_x = m2_x * random() + m1_x;
53         v_y = m2_y * random() + m1_y;
54         v_z = m2_z * random() + m1_z;
55         return v;
56 }
57
58 float vlen_maxnorm2d(vector v)
59 {
60         return max(v.x, v.y, -v.x, -v.y);
61 }
62
63 float vlen_minnorm2d(vector v)
64 {
65         return min(max(v.x, -v.x), max(v.y, -v.y));
66 }
67
68 float dist_point_line(vector p, vector l0, vector ldir)
69 {
70         ldir = normalize(ldir);
71
72         // remove the component in line direction
73         p = p - (p * ldir) * ldir;
74
75         // vlen of the remaining vector
76         return vlen(p);
77 }
78
79 /** requires that m2>m1 in all coordinates, and that m4>m3 */
80 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) { return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z; }
81
82 /** requires the same as boxesoverlap, but is a stronger condition */
83 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) { return smins.x >= bmins.x && smaxs.x <= bmaxs.x && smins.y >= bmins.y && smaxs.y <= bmaxs.y && smins.z >= bmins.z && smaxs.z <= bmaxs.z; }
84
85 #define PITCH(v) ((v).x)
86 #define YAW(v) ((v).y)
87 #define ROLL(v) ((v).z)
88
89 #define MAKEVECTORS(f, angles, forward, right, up) MACRO_BEGIN { \
90         f(angles); \
91         forward = v_forward; \
92         right = v_right; \
93         up = v_up; \
94 } MACRO_END
95
96 noref vector _vec2;
97 #define vec2(...) EVAL(OVERLOAD(vec2, __VA_ARGS__))
98 #define vec2_1(v) (_vec2 = (v), _vec2.z = 0, _vec2)
99 #define vec2_2(x, y) (_vec2_x = (x), _vec2_y = (y), _vec2)
100
101 noref vector _vec3;
102 #define vec3(_x, _y, _z) (_vec3.x = (_x), _vec3.y = (_y), _vec3.z = (_z), _vec3)
103
104 vector Rotate(vector v, float a)
105 {
106         float a_sin = sin(a), a_cos = cos(a);
107         vector r = '0 0 0';
108         r.x =      v.x * a_cos + v.y * a_sin;
109         r.y = -1 * v.x * a_sin + v.y * a_cos;
110         return r;
111 }
112
113 noref vector _yinvert;
114 #define yinvert(v) (_yinvert = (v), _yinvert.y = 1 - _yinvert.y, _yinvert)
115
116 /**
117  * @param dir the directional vector
118  * @param norm the normalized normal
119  * @returns dir reflected by norm
120  */
121 vector reflect(vector dir, vector norm)
122 {
123         return dir - 2 * (dir * norm) * norm;
124 }
125
126 /**
127  * clip vel along the plane defined by norm (assuming 0 distance away), bounciness determined by bounce 0..1
128  */
129 vector vec_reflect(vector vel, vector norm, float bounce)
130 {
131         return vel - (1 + bounce) * (vel * norm) * norm;
132 }
133
134 vector vec_epsilon(vector this, float eps)
135 {
136         if (this.x > -eps && this.x < eps) this.x = 0;
137         if (this.y > -eps && this.y < eps) this.y = 0;
138         if (this.z > -eps && this.z < eps) this.z = 0;
139         return this;
140 }
141
142 #define ClipVelocity(in, normal, out, overbounce) \
143         (out = vec_epsilon(vec_reflect(in, normal, (overbounce) - 1), 0.1))
144
145 #ifdef GAMEQC
146         vector get_corner_position(entity box, int corner)
147         {
148                 switch (corner)
149                 {
150                         case 1: return vec3(box.absmin.x, box.absmin.y, box.absmin.z);
151                         case 2: return vec3(box.absmax.x, box.absmin.y, box.absmin.z);
152                         case 3: return vec3(box.absmin.x, box.absmax.y, box.absmin.z);
153                         case 4: return vec3(box.absmin.x, box.absmin.y, box.absmax.z);
154                         case 5: return vec3(box.absmax.x, box.absmax.y, box.absmin.z);
155                         case 6: return vec3(box.absmin.x, box.absmax.y, box.absmax.z);
156                         case 7: return vec3(box.absmax.x, box.absmin.y, box.absmax.z);
157                         case 8: return vec3(box.absmax.x, box.absmax.y, box.absmax.z);
158                         default: return '0 0 0';
159                 }
160         }
161
162         vector NearestPointOnBox(entity box, vector org)
163         {
164                 vector m1 = box.mins + box.origin;
165                 vector m2 = box.maxs + box.origin;
166
167                 vector ret;
168                 ret.x = bound(m1.x, org.x, m2.x);
169                 ret.y = bound(m1.y, org.y, m2.y);
170                 ret.z = bound(m1.z, org.z, m2.z);
171                 return ret;
172         }
173 #endif