qcsrc/lib/vector.qh

   1 #ifndef VECTOR_H
   2 #define VECTOR_H
   3
   4 noref vector _vlen2;
   5 #define vlen2(v) \
   6         (_vlen2 = (v), \
   7           _vlen2.x * _vlen2.x \
   8         + _vlen2.y * _vlen2.y \
   9         + _vlen2.z * _vlen2.z)
  10
  11 noref float _vdist_f;
  12 /** Vector distance comparison, avoids sqrt() */
  13 #define vdist(v, cmp, f) (vlen2(v) cmp (_vdist_f = (f), _vdist_f * _vdist_f))
  14 /*
  15 #define vdist(v, cmp, f) (vlen(v) cmp (f))
  16 */
  17
  18 #define cross(a, b) ((a) >< (b))
  19 /*
  20 vector cross(vector a, vector b)
  21 {
  22         return
  23                 '1 0 0' * (a.y * b.z - a.z * b.y)
  24         +       '0 1 0' * (a.z * b.x - a.x * b.z)
  25         +       '0 0 1' * (a.x * b.y - a.y * b.x);
  26 }
  27 */
  28
  29 const vector eX = '1 0 0';
  30 const vector eY = '0 1 0';
  31 const vector eZ = '0 0 1';
  32
  33 vector randompos(vector m1, vector m2)
  34 {
  35         vector v;
  36         m2 = m2 - m1;
  37         v_x = m2_x * random() + m1_x;
  38         v_y = m2_y * random() + m1_y;
  39         v_z = m2_z * random() + m1_z;
  40         return v;
  41 }
  42
  43 float vlen_maxnorm2d(vector v)
  44 {
  45         return max(v.x, v.y, -v.x, -v.y);
  46 }
  47
  48 float vlen_minnorm2d(vector v)
  49 {
  50         return min(max(v.x, -v.x), max(v.y, -v.y));
  51 }
  52
  53 float dist_point_line(vector p, vector l0, vector ldir)
  54 {
  55         ldir = normalize(ldir);
  56
  57         // remove the component in line direction
  58         p = p - (p * ldir) * ldir;
  59
  60         // vlen of the remaining vector
  61         return vlen(p);
  62 }
  63
  64 /** requires that m2>m1 in all coordinates, and that m4>m3 */
  65 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) { return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z; }
  66
  67 /** requires the same as boxesoverlap, but is a stronger condition */
  68 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) { return smins.x >= bmins.x && smaxs.x <= bmaxs.x && smins.y >= bmins.y && smaxs.y <= bmaxs.y && smins.z >= bmins.z && smaxs.z <= bmaxs.z; }
  69
  70
  71 noref vector _vec2;
  72 #define vec2(v) (_vec2 = (v), _vec2.z = 0, _vec2)
  73
  74 noref vector _vec3;
  75 #define vec3(x, y, z) (_vec3_x = (x), _vec3_y = (y), _vec3_z = (z), _vec3)
  76
  77 vector rotate(vector v, float a)
  78 {
  79         float a_sin = sin(a), a_cos = cos(a);
  80         vector r = '0 0 0';
  81         r.x =      v.x * a_cos + v.y * a_sin;
  82         r.y = -1 * v.x * a_sin + v.y * a_cos;
  83         return r;
  84 }
  85
  86 noref vector _yinvert;
  87 #define yinvert(v) (_yinvert = (v), _yinvert.y = 1 - _yinvert.y, _yinvert)
  88
  89 #ifndef MENUQC
  90         vector get_corner_position(entity box, int corner)
  91         {
  92                 switch (corner)
  93                 {
  94                         case 1: return vec3(box.absmin.x, box.absmin.y, box.absmin.z);
  95                         case 2: return vec3(box.absmax.x, box.absmin.y, box.absmin.z);
  96                         case 3: return vec3(box.absmin.x, box.absmax.y, box.absmin.z);
  97                         case 4: return vec3(box.absmin.x, box.absmin.y, box.absmax.z);
  98                         case 5: return vec3(box.absmax.x, box.absmax.y, box.absmin.z);
  99                         case 6: return vec3(box.absmin.x, box.absmax.y, box.absmax.z);
 100                         case 7: return vec3(box.absmax.x, box.absmin.y, box.absmax.z);
 101                         case 8: return vec3(box.absmax.x, box.absmax.y, box.absmax.z);
 102                         default: return '0 0 0';
 103                 }
 104         }
 105
 106         vector NearestPointOnBox(entity box, vector org)
 107         {
 108                 vector m1 = box.mins + box.origin;
 109                 vector m2 = box.maxs + box.origin;
 110
 111                 vector ret;
 112                 ret.x = bound(m1.x, org.x, m2.x);
 113                 ret.y = bound(m1.y, org.y, m2.y);
 114                 ret.z = bound(m1.z, org.z, m2.z);
 115                 return ret;
 116         }
 117 #endif
 118
 119 #endif