qcsrc/lib/vector.qh

   1 #pragma once
   2
   3 noref vector _vlen2;
   4 #define vlen2(v) (_vlen2 = (v), dotproduct(_vlen2, _vlen2))
   5
   6 #if 1
   7 noref float _vdist_f;
   8 /** Vector distance comparison, avoids sqrt() */
   9 #define vdist(v, cmp, f) (vlen2(v) cmp (_vdist_f = (f), _vdist_f * _vdist_f))
  10 #else
  11 #define vdist(v, cmp, f) (vlen(v) cmp (f))
  12 #endif
  13
  14 #if 1
  15 #define dotproduct(a, b) ((a) * (b))
  16 #else
  17 noref vector _dotproduct_a, _dotproduct_b;
  18 #define dotproduct(a, b) \
  19         (_dotproduct_a = (a), _dotproduct_b = (b), \
  20           _dotproduct_a.x * _dotproduct_b.x \
  21         + _dotproduct_a.y * _dotproduct_b.y \
  22         + _dotproduct_a.z * _dotproduct_b.z)
  23 #endif
  24
  25 #if 1
  26 #define cross(a, b) ((a) >< (b))
  27 #else
  28 vector cross(vector a, vector b)
  29 {
  30         return
  31                 '1 0 0' * (a.y * b.z - a.z * b.y)
  32         +       '0 1 0' * (a.z * b.x - a.x * b.z)
  33         +       '0 0 1' * (a.x * b.y - a.y * b.x);
  34 }
  35 #endif
  36
  37 const vector eX = '1 0 0';
  38 const vector eY = '0 1 0';
  39 const vector eZ = '0 0 1';
  40
  41 vector randompos(vector m1, vector m2)
  42 {
  43         vector v;
  44         m2 = m2 - m1;
  45         v_x = m2_x * random() + m1_x;
  46         v_y = m2_y * random() + m1_y;
  47         v_z = m2_z * random() + m1_z;
  48         return v;
  49 }
  50
  51 float vlen_maxnorm2d(vector v)
  52 {
  53         return max(v.x, v.y, -v.x, -v.y);
  54 }
  55
  56 float vlen_minnorm2d(vector v)
  57 {
  58         return min(max(v.x, -v.x), max(v.y, -v.y));
  59 }
  60
  61 float dist_point_line(vector p, vector l0, vector ldir)
  62 {
  63         ldir = normalize(ldir);
  64
  65         // remove the component in line direction
  66         p = p - (p * ldir) * ldir;
  67
  68         // vlen of the remaining vector
  69         return vlen(p);
  70 }
  71
  72 /** requires that m2>m1 in all coordinates, and that m4>m3 */
  73 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) { return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z; }
  74
  75 /** requires the same as boxesoverlap, but is a stronger condition */
  76 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) { return smins.x >= bmins.x && smaxs.x <= bmaxs.x && smins.y >= bmins.y && smaxs.y <= bmaxs.y && smins.z >= bmins.z && smaxs.z <= bmaxs.z; }
  77
  78 #define PITCH(v) ((v).x)
  79 #define YAW(v) ((v).y)
  80 #define ROLL(v) ((v).z)
  81
  82 #define MAKEVECTORS(f, angles, forward, right, up) MACRO_BEGIN { \
  83         f(angles); \
  84         forward = v_forward; \
  85         right = v_right; \
  86         up = v_up; \
  87 } MACRO_END
  88
  89 noref vector _vec2;
  90 #define vec2(v) (_vec2 = (v), _vec2.z = 0, _vec2)
  91
  92 noref vector _vec3;
  93 #define vec3(_x, _y, _z) (_vec3.x = (_x), _vec3.y = (_y), _vec3.z = (_z), _vec3)
  94
  95 vector rotate(vector v, float a)
  96 {
  97         float a_sin = sin(a), a_cos = cos(a);
  98         vector r = '0 0 0';
  99         r.x =      v.x * a_cos + v.y * a_sin;
 100         r.y = -1 * v.x * a_sin + v.y * a_cos;
 101         return r;
 102 }
 103
 104 noref vector _yinvert;
 105 #define yinvert(v) (_yinvert = (v), _yinvert.y = 1 - _yinvert.y, _yinvert)
 106
 107 #ifndef MENUQC
 108         vector get_corner_position(entity box, int corner)
 109         {
 110                 switch (corner)
 111                 {
 112                         case 1: return vec3(box.absmin.x, box.absmin.y, box.absmin.z);
 113                         case 2: return vec3(box.absmax.x, box.absmin.y, box.absmin.z);
 114                         case 3: return vec3(box.absmin.x, box.absmax.y, box.absmin.z);
 115                         case 4: return vec3(box.absmin.x, box.absmin.y, box.absmax.z);
 116                         case 5: return vec3(box.absmax.x, box.absmax.y, box.absmin.z);
 117                         case 6: return vec3(box.absmin.x, box.absmax.y, box.absmax.z);
 118                         case 7: return vec3(box.absmax.x, box.absmin.y, box.absmax.z);
 119                         case 8: return vec3(box.absmax.x, box.absmax.y, box.absmax.z);
 120                         default: return '0 0 0';
 121                 }
 122         }
 123
 124         vector NearestPointOnBox(entity box, vector org)
 125         {
 126                 vector m1 = box.mins + box.origin;
 127                 vector m2 = box.maxs + box.origin;
 128
 129                 vector ret;
 130                 ret.x = bound(m1.x, org.x, m2.x);
 131                 ret.y = bound(m1.y, org.y, m2.y);
 132                 ret.z = bound(m1.z, org.z, m2.z);
 133                 return ret;
 134         }
 135 #endif