Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / lib / warpzone / common.qc
1 #include "common.qh"
2
3 #if defined(CSQC)
4     #include <common/t_items.qh>
5 #elif defined(MENUQC)
6 #elif defined(SVQC)
7     #include <common/weapons/all.qh>
8 #endif
9
10 void WarpZone_Accumulator_Clear(entity acc)
11 {
12         acc.warpzone_transform = '0 0 0';
13         acc.warpzone_shift = '0 0 0';
14 }
15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
16 {
17         vector tr, st;
18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
20         acc.warpzone_transform = tr;
21         acc.warpzone_shift = st;
22 }
23 void WarpZone_Accumulator_Add(entity acc, entity wz)
24 {
25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
26 }
27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
28 {
29         vector tt, ss;
30         tt = AnglesTransform_Invert(t);
31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
33         // yes, this probably can be done simpler... but this way is "obvious" :)
34 }
35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
36 {
37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
38 }
39
40 .vector(vector, vector) camera_transform;
41 float autocvar_cl_warpzone_usetrace = 1;
42 vector WarpZone_camera_transform(vector org, vector ang)
43 {SELFPARAM();
44         vector vf, vr, vu;
45         if(self.warpzone_fadestart)
46                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
47                         return org;
48                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
49                         // unneeded on client, on server this helps a lot
50         vf = v_forward;
51         vr = v_right;
52         vu = v_up;
53         org = WarpZone_TransformOrigin(self, org);
54         vf = WarpZone_TransformVelocity(self, vf);
55         vr = WarpZone_TransformVelocity(self, vr);
56         vu = WarpZone_TransformVelocity(self, vu);
57         if(autocvar_cl_warpzone_usetrace)
58                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
59         else
60                 trace_endpos = self.warpzone_targetorigin;
61         v_forward = vf;
62         v_right = vr;
63         v_up = vu;
64         return org;
65 }
66
67 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
68 {
69         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
70         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
71         e.warpzone_origin = my_org;
72         e.warpzone_targetorigin = other_org;
73         e.warpzone_angles = my_ang;
74         e.warpzone_targetangles = other_ang;
75         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
76         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
77         e.camera_transform = WarpZone_camera_transform;
78 }
79
80 vector WarpZone_Camera_camera_transform(vector org, vector ang)
81 {SELFPARAM();
82         // a fixed camera view
83         if(self.warpzone_fadestart)
84                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
85                         return org;
86                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
87                         // unneeded on client, on server this helps a lot
88         trace_endpos = self.warpzone_origin;
89         makevectors(self.warpzone_angles);
90         return self.warpzone_origin;
91 }
92
93 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
94 {
95         e.warpzone_origin = my_org;
96         e.warpzone_angles = my_ang;
97         e.camera_transform = WarpZone_Camera_camera_transform;
98 }
99
100 .entity enemy;
101
102 vector WarpZoneLib_BoxTouchesBrush_mins;
103 vector WarpZoneLib_BoxTouchesBrush_maxs;
104 entity WarpZoneLib_BoxTouchesBrush_ent;
105 entity WarpZoneLib_BoxTouchesBrush_ignore;
106 float WarpZoneLib_BoxTouchesBrush_Recurse()
107 {
108         float s;
109         entity se;
110         float f;
111
112         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
113 #ifdef CSQC
114         if (trace_networkentity)
115         {
116                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
117                 // we cannot continue, as a player blocks us...
118                 // so, abort
119                 return 0;
120         }
121 #endif
122         if (!trace_ent)
123                 return 0;
124         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
125                 return 1;
126
127         se = trace_ent;
128         s = se.solid;
129         se.solid = SOLID_NOT;
130         f = WarpZoneLib_BoxTouchesBrush_Recurse();
131         se.solid = s;
132
133         return f;
134 }
135
136 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
137 {
138     float f, s;
139
140     if(!e.modelindex || e.warpzone_isboxy)
141         return 1;
142
143     s = e.solid;
144     e.solid = SOLID_BSP;
145     WarpZoneLib_BoxTouchesBrush_mins = mi;
146     WarpZoneLib_BoxTouchesBrush_maxs = ma;
147     WarpZoneLib_BoxTouchesBrush_ent = e;
148     WarpZoneLib_BoxTouchesBrush_ignore = ig;
149     f = WarpZoneLib_BoxTouchesBrush_Recurse();
150     e.solid = s;
151
152     return f;
153 }
154
155 entity WarpZone_Find(vector mi, vector ma)
156 {
157         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
158         entity e;
159         if(!warpzone_warpzones_exist)
160                 return world;
161         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
162                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
163                         return e;
164         return world;
165 }
166
167 void WarpZone_MakeAllSolid()
168 {
169         entity e;
170         if(!warpzone_warpzones_exist)
171                 return;
172         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
173                 e.solid = SOLID_BSP;
174 }
175
176 void WarpZone_MakeAllOther()
177 {
178         entity e;
179         if(!warpzone_warpzones_exist)
180                 return;
181         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
182                 e.solid = SOLID_TRIGGER;
183 }
184
185 void WarpZone_Trace_InitTransform()
186 {
187         if(!WarpZone_trace_transform)
188         {
189                 WarpZone_trace_transform = new(warpzone_trace_transform);
190                 make_pure(WarpZone_trace_transform);
191         }
192         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
193 }
194 void WarpZone_Trace_AddTransform(entity wz)
195 {
196         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
197 }
198
199 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
200 {
201         float nomonsters_adjusted;
202         float frac, sol, i;
203         float contentshack;
204         vector o0, e0;
205         entity wz;
206         vector vf, vr, vu;
207
208         WarpZone_trace_forent = forent;
209         WarpZone_trace_firstzone = world;
210         WarpZone_trace_lastzone = world;
211         WarpZone_Trace_InitTransform();
212         if(!warpzone_warpzones_exist)
213         {
214                 if(nomonsters == MOVE_NOTHING)
215                 {
216                         trace_endpos = end;
217                         trace_fraction = 1;
218                         if(cb)
219                                 cb(org, trace_endpos, end);
220                         return;
221                 }
222                 else
223                 {
224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
225                         if(cb)
226                                 cb(org, trace_endpos, end);
227                         return;
228                 }
229         }
230
231         vf = v_forward;
232         vr = v_right;
233         vu = v_up;
234         o0 = org;
235         e0 = end;
236
237         switch(nomonsters)
238         {
239                 case MOVE_WORLDONLY:
240                 case MOVE_NOTHING:
241                         nomonsters_adjusted = MOVE_NOMONSTERS;
242                         break;
243                 default:
244                         nomonsters_adjusted = nomonsters;
245                         break;
246         }
247         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
248                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
249
250         // if starting in warpzone, first transform
251         wz = WarpZone_Find(org + mi, org + ma);
252         if(wz)
253         {
254                 WarpZone_trace_firstzone = wz;
255                 WarpZone_trace_lastzone = wz;
256                 if(zone && wz != zone)
257                 {
258                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
259                         sol = 1;
260                         trace_fraction = 0;
261                         trace_endpos = org;
262                         goto fail;
263                 }
264                 WarpZone_Trace_AddTransform(wz);
265                 org = WarpZone_TransformOrigin(wz, org);
266                 end = WarpZone_TransformOrigin(wz, end);
267         }
268         WarpZone_MakeAllSolid();
269         sol = -1;
270         frac = 0;
271         i = 16;
272         for (;;)
273         {
274                 if(--i < 1)
275                 {
276                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
277                         trace_ent = world;
278                         break;
279                 }
280                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
281                 if(cb)
282                         cb(org, trace_endpos, end);
283                 if(sol < 0)
284                         sol = trace_startsolid;
285
286                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
287                 if(trace_fraction >= 1)
288                         break;
289                 if(trace_ent.classname != "trigger_warpzone")
290                 {
291                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
292                         {
293                                 // continue the trace, ignoring this hit (we only care for warpzones)
294                                 org = trace_endpos + normalize(end - org);
295                                 continue;
296                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
297                                 // otherwise, players could block entrances that way
298                         }
299                         break;
300                 }
301                 if(trace_ent == wz)
302                 {
303                         // FIXME can this check be removed? Do we really need it?
304                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
305                         trace_ent = world;
306                         break;
307                 }
308                 wz = trace_ent;
309                 if(!WarpZone_trace_firstzone)
310                         WarpZone_trace_firstzone = wz;
311                 WarpZone_trace_lastzone = wz;
312                 if(zone && wz != zone)
313                         break;
314                 WarpZone_Trace_AddTransform(wz);
315                 // we hit a warpzone... so, let's perform the trace after the warp again
316                 org = WarpZone_TransformOrigin(wz, trace_endpos);
317                 end = WarpZone_TransformOrigin(wz, end);
318
319                 // we got warped, so let's step back a bit
320                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
321                 org = trace_endpos;
322         }
323         WarpZone_MakeAllOther();
324 :fail
325         if(contentshack)
326                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
327         trace_startsolid = sol;
328         v_forward = vf;
329         v_right = vr;
330         v_up = vu;
331 }
332
333 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
334 {
335         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
336 }
337
338 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
339 {
340         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
341 }
342
343 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
344 {
345         float g, dt, i;
346         vector vf, vr, vu, v0, o0;
347         entity wz;
348
349         o0 = e.origin;
350         v0 = e.velocity;
351         g = cvar("sv_gravity") * e.gravity;
352
353         WarpZone_trace_forent = forent;
354         WarpZone_trace_firstzone = world;
355         WarpZone_trace_lastzone = world;
356         WarpZone_Trace_InitTransform();
357         WarpZone_tracetoss_time = 0;
358         if(!warpzone_warpzones_exist)
359         {
360                 tracetoss(e, WarpZone_trace_forent);
361                 if(cb)
362                         cb(e.origin, trace_endpos, trace_endpos);
363                 dt = vlen(e.origin - o0) / vlen(e.velocity);
364                 WarpZone_tracetoss_time += dt;
365                 e.velocity_z -= dt * g;
366                 WarpZone_tracetoss_velocity = e.velocity;
367                 e.velocity = v0;
368                 return;
369         }
370
371         vf = v_forward;
372         vr = v_right;
373         vu = v_up;
374
375         // if starting in warpzone, first transform
376         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
377         if(wz)
378         {
379                 WarpZone_trace_firstzone = wz;
380                 WarpZone_trace_lastzone = wz;
381                 if(zone && wz != zone)
382                 {
383                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
384
385                         WarpZone_tracetoss_time = 0;
386                         trace_endpos = o0;
387                         goto fail;
388                 }
389                 WarpZone_Trace_AddTransform(wz);
390                 vector org = WarpZone_TransformOrigin(wz, e.origin);
391                 setorigin(e, org);
392                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
393         }
394         WarpZone_MakeAllSolid();
395         i = 16;
396         for (;;)
397         {
398                 if(--i < 1)
399                 {
400                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
401                         trace_ent = world;
402                         break;
403                 }
404                 tracetoss(e, WarpZone_trace_forent);
405                 if(cb)
406                         cb(e.origin, trace_endpos, trace_endpos);
407                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
408                 WarpZone_tracetoss_time += dt;
409                 e.origin = trace_endpos;
410                 e.velocity_z -= dt * g;
411                 if(trace_fraction >= 1)
412                         break;
413                 if(trace_ent.classname != "trigger_warpzone")
414                         break;
415                 if(trace_ent == wz)
416                 {
417                         // FIXME can this check be removed? Do we really need it?
418                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
419                         trace_ent = world;
420                         break;
421                 }
422                 wz = trace_ent;
423                 if(!WarpZone_trace_firstzone)
424                         WarpZone_trace_firstzone = wz;
425                 WarpZone_trace_lastzone = wz;
426                 if(zone && wz != zone)
427                         break;
428                 WarpZone_Trace_AddTransform(wz);
429                 // we hit a warpzone... so, let's perform the trace after the warp again
430                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
431                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
432
433                 // we got warped, so let's step back a bit
434                 e.velocity = -e.velocity;
435                 tracetoss(e, WarpZone_trace_forent);
436                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
437                 WarpZone_tracetoss_time -= dt;
438                 e.origin = trace_endpos;
439                 e.velocity = -e.velocity;
440         }
441         WarpZone_MakeAllOther();
442 :fail
443         WarpZone_tracetoss_velocity = e.velocity;
444         v_forward = vf;
445         v_right = vr;
446         v_up = vu;
447         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
448         e.velocity = v0;
449         e.origin = o0;
450 }
451
452 void WarpZone_TraceToss(entity e, entity forent)
453 {
454         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
455 }
456
457 entity WarpZone_TrailParticles_trace_callback_own;
458 float WarpZone_TrailParticles_trace_callback_eff;
459 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
460 {
461         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
462 }
463
464 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
465 {
466         WarpZone_TrailParticles_trace_callback_own = own;
467         WarpZone_TrailParticles_trace_callback_eff = eff;
468         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
469 }
470
471 #ifdef CSQC
472 float WarpZone_TrailParticles_trace_callback_f;
473 float WarpZone_TrailParticles_trace_callback_flags;
474 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
475 {
476         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
477 }
478
479 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
480 {
481         WarpZone_TrailParticles_trace_callback_own = own;
482         WarpZone_TrailParticles_trace_callback_eff = eff;
483         WarpZone_TrailParticles_trace_callback_f = f;
484         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
485         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
486 }
487 #endif
488
489 float WarpZone_PlaneDist(entity wz, vector v)
490 {
491         return (v - wz.warpzone_origin) * wz.warpzone_forward;
492 }
493
494 float WarpZone_TargetPlaneDist(entity wz, vector v)
495 {
496         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
497 }
498
499 vector WarpZone_TransformOrigin(entity wz, vector v)
500 {
501         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
502 }
503
504 vector WarpZone_TransformVelocity(entity wz, vector v)
505 {
506         return AnglesTransform_Apply(wz.warpzone_transform, v);
507 }
508
509 vector WarpZone_TransformAngles(entity wz, vector v)
510 {
511         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
512 }
513
514 vector WarpZone_TransformVAngles(entity wz, vector ang)
515 {
516 #ifdef KEEP_ROLL
517         float roll;
518         roll = ang.z;
519         ang.z = 0;
520 #endif
521
522         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
523
524 #ifdef KEEP_ROLL
525         ang = AnglesTransform_Normalize(ang, true);
526         ang = AnglesTransform_CancelRoll(ang);
527         ang.z = roll;
528 #else
529         ang = AnglesTransform_Normalize(ang, false);
530 #endif
531
532         return ang;
533 }
534
535 vector WarpZone_UnTransformOrigin(entity wz, vector v)
536 {
537         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
538 }
539
540 vector WarpZone_UnTransformVelocity(entity wz, vector v)
541 {
542         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
543 }
544
545 vector WarpZone_UnTransformAngles(entity wz, vector v)
546 {
547         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
548 }
549
550 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
551 {
552         float roll;
553
554         roll = ang.z;
555         ang.z = 0;
556
557         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
558         ang = AnglesTransform_Normalize(ang, true);
559         ang = AnglesTransform_CancelRoll(ang);
560
561         ang.z = roll;
562         return ang;
563 }
564
565 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
566 {
567         vector nearest;
568         nearest.x = bound(mi.x, org.x, ma.x);
569         nearest.y = bound(mi.y, org.y, ma.y);
570         nearest.z = bound(mi.z, org.z, ma.z);
571         return nearest;
572 }
573
574 bool WarpZoneLib_BadEntity(entity e)
575 {
576         string s = e.classname;
577         if (is_pure(e)) return true;
578         switch (s)
579         {
580                 // case "net_linked": // actually some real entities are linked without classname, fail
581                 case "":
582                         return true;
583         }
584
585         if (startsWith(s, "target_")) return true;
586
587         if (startsWith(s, "info_")) return true;
588
589         return false;
590 }
591
592 .float WarpZone_findradius_hit;
593 .entity WarpZone_findradius_next;
594 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
595 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
596 {
597         vector org_new;
598         vector org0_new;
599         vector shift_new, transform_new;
600         vector p;
601         entity e, e0;
602         entity wz;
603         if(rad <= 0)
604                 return;
605         e0 = findradius(org, rad);
606         wz = world;
607
608         for(e = e0; e; e = e.chain)
609         {
610                 if(WarpZoneLib_BadEntity(e))
611                         continue;
612                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
613                 if(needlineofsight)
614                 {
615                         traceline(org, p, MOVE_NOMONSTERS, e);
616                         if(trace_fraction < 1)
617                                 continue;
618                 }
619                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
620                 {
621                         e.WarpZone_findradius_nearest = p;
622                         e.WarpZone_findradius_dist = org0 - p;
623                         e.WarpZone_findradius_findorigin = org;
624                         e.WarpZone_findradius_findradius = rad;
625                         if(e.classname == "warpzone_refsys")
626                         {
627                                 // ignore, especially: do not overwrite the refsys parameters
628                         }
629                         else if(e.classname == "trigger_warpzone")
630                         {
631                                 e.WarpZone_findradius_next = wz;
632                                 wz = e;
633                                 e.WarpZone_findradius_hit = 1;
634                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
635                                 e.enemy.WarpZone_findradius_hit = 1;
636                         }
637                         else
638                         {
639                                 e.warpzone_transform = transform;
640                                 e.warpzone_shift = shift;
641                                 e.WarpZone_findradius_hit = 1;
642                         }
643                 }
644         }
645         for(e = wz; e; e = e.WarpZone_findradius_next)
646         {
647                 if(WarpZoneLib_BadEntity(e))
648                         continue;
649
650                 org0_new = WarpZone_TransformOrigin(e, org);
651                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
652                 org_new = trace_endpos;
653
654                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
655                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
656                 WarpZone_FindRadius_Recurse(
657                         org_new,
658                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
659                         org0_new,
660                         transform_new, shift_new,
661                         needlineofsight);
662                 e.WarpZone_findradius_hit = 0;
663                 e.enemy.WarpZone_findradius_hit = 0;
664         }
665 }
666 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
667 {
668         entity e0, e;
669         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
670         e0 = findchainfloat(WarpZone_findradius_hit, 1);
671         for(e = e0; e; e = e.chain)
672                 e.WarpZone_findradius_hit = 0;
673         return e0;
674 }
675
676 .entity WarpZone_refsys;
677 void WarpZone_RefSys_GC()
678 {SELFPARAM();
679         // garbage collect unused reference systems
680         self.nextthink = time + 1;
681         if(self.owner.WarpZone_refsys != self)
682                 remove(self);
683 }
684 void WarpZone_RefSys_CheckCreate(entity me)
685 {
686         if(me.WarpZone_refsys.owner != me)
687         {
688                 me.WarpZone_refsys = new(warpzone_refsys);
689                 me.WarpZone_refsys.owner = me;
690                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
691                 me.WarpZone_refsys.nextthink = time + 1;
692                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
693         }
694 }
695 void WarpZone_RefSys_Clear(entity me)
696 {
697         if(me.WarpZone_refsys)
698         {
699                 remove(me.WarpZone_refsys);
700                 me.WarpZone_refsys = world;
701         }
702 }
703 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
704 {
705         if(t != '0 0 0' || s != '0 0 0')
706         {
707                 WarpZone_RefSys_CheckCreate(me);
708                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
709         }
710 }
711 void WarpZone_RefSys_Add(entity me, entity wz)
712 {
713         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
714 }
715 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
716 {
717         if(t != '0 0 0' || s != '0 0 0')
718         {
719                 WarpZone_RefSys_CheckCreate(me);
720                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
721         }
722 }
723 void WarpZone_RefSys_AddInverse(entity me, entity wz)
724 {
725         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
726 }
727 .vector WarpZone_refsys_incremental_shift;
728 .vector WarpZone_refsys_incremental_transform;
729 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
730 {
731         //vector t, s;
732         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
733         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
734                 return;
735         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
736         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
737         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
738         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
739 }
740 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
741 {
742         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
743         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
744 }
745 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
746 {
747         if(from.WarpZone_refsys)
748                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
749         if(to.WarpZone_refsys)
750                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
751         return org;
752 }
753 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
754 {
755         if(from.WarpZone_refsys)
756                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
757         if(to.WarpZone_refsys)
758                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
759         return vel;
760 }
761 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
762 {
763         if(from.WarpZone_refsys)
764                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
765         if(to.WarpZone_refsys)
766                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
767         return ang;
768 }
769 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
770 {
771         if(from.WarpZone_refsys)
772                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
773         if(to.WarpZone_refsys)
774                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
775         return ang;
776 }
777 void WarpZone_RefSys_Copy(entity me, entity from)
778 {
779         if(from.WarpZone_refsys)
780         {
781                 WarpZone_RefSys_CheckCreate(me);
782                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
783                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
784         }
785         else
786                 WarpZone_RefSys_Clear(me);
787 }
788 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
789 {
790         entity e;
791         e = spawn();
792         WarpZone_RefSys_Copy(e, me);
793         return e;
794 }
795
796 float WarpZoneLib_ExactTrigger_Touch()
797 {SELFPARAM();
798         return !WarpZoneLib_BoxTouchesBrush(other.absmin, other.absmax, self, other);
799 }
800
801
802 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
803 {
804         float eps = 0.0625;
805         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
806         if (trace_startsolid)
807                 return;
808         if (trace_fraction < 1)
809         {
810                 // hit something
811                 // adjust origin in the other direction...
812                 setorigin(e,e.origin - by * (1 - trace_fraction));
813         }
814 }
815
816 float WarpZoneLib_MoveOutOfSolid(entity e)
817 {
818         vector o, m0, m1;
819
820         o = e.origin;
821         traceline(o, o, MOVE_WORLDONLY, e);
822         if (trace_startsolid)
823                 return false;
824
825         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
826         if (!trace_startsolid)
827                 return true;
828
829         m0 = e.mins;
830         m1 = e.maxs;
831         e.mins = '0 0 0';
832         e.maxs = '0 0 0';
833         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m0_x);
834         e.mins_x = m0_x;
835         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m1_x);
836         e.maxs_x = m1_x;
837         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m0_y);
838         e.mins_y = m0_y;
839         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m1_y);
840         e.maxs_y = m1_y;
841         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m0_z);
842         e.mins_z = m0_z;
843         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m1_z);
844         e.maxs_z = m1_z;
845         setorigin(e, e.origin);
846
847         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
848         if (trace_startsolid)
849         {
850                 setorigin(e, o);
851                 return false;
852         }
853
854         return true;
855 }