qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <common/t_items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  75         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  76         setcamera_transform(e, WarpZone_camera_transform);
  77 }
  78
  79 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  80 {
  81         // a fixed camera view
  82         if(this.warpzone_fadestart)
  83                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  84                         return org;
  85                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  86                         // unneeded on client, on server this helps a lot
  87         trace_endpos = this.warpzone_origin;
  88         makevectors(this.warpzone_angles);
  89         return this.warpzone_origin;
  90 }
  91
  92 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  93 {
  94         e.warpzone_origin = my_org;
  95         e.warpzone_angles = my_ang;
  96         setcamera_transform(e, WarpZone_Camera_camera_transform);
  97 }
  98
  99 .entity enemy;
 100
 101 vector WarpZoneLib_BoxTouchesBrush_mins;
 102 vector WarpZoneLib_BoxTouchesBrush_maxs;
 103 entity WarpZoneLib_BoxTouchesBrush_ent;
 104 entity WarpZoneLib_BoxTouchesBrush_ignore;
 105 float WarpZoneLib_BoxTouchesBrush_Recurse()
 106 {
 107         float s;
 108         entity se;
 109         float f;
 110
 111         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 112 #ifdef CSQC
 113         if (trace_networkentity)
 114         {
 115                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 116                 // we cannot continue, as a player blocks us...
 117                 // so, abort
 118                 return 0;
 119         }
 120 #endif
 121         if (!trace_ent)
 122                 return 0;
 123         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 124                 return 1;
 125
 126         se = trace_ent;
 127         s = se.solid;
 128         se.solid = SOLID_NOT;
 129         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 130         se.solid = s;
 131
 132         return f;
 133 }
 134
 135 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 136 {
 137     float f, s;
 138
 139     if(!e.modelindex || e.warpzone_isboxy)
 140         return 1;
 141
 142     s = e.solid;
 143     e.solid = SOLID_BSP;
 144     WarpZoneLib_BoxTouchesBrush_mins = mi;
 145     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 146     WarpZoneLib_BoxTouchesBrush_ent = e;
 147     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 148     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 149     e.solid = s;
 150
 151     return f;
 152 }
 153
 154 entity WarpZone_Find(vector mi, vector ma)
 155 {
 156         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 157         if(!warpzone_warpzones_exist)
 158                 return NULL;
 159         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 160         {
 161                 return it;
 162         });
 163         return NULL;
 164 }
 165
 166 void WarpZone_MakeAllSolid()
 167 {
 168         if(!warpzone_warpzones_exist)
 169                 return;
 170         IL_EACH(g_warpzones, true,
 171         {
 172                 it.solid = SOLID_BSP;
 173         });
 174 }
 175
 176 void WarpZone_MakeAllOther()
 177 {
 178         if(!warpzone_warpzones_exist)
 179                 return;
 180         IL_EACH(g_warpzones, true,
 181         {
 182                 it.solid = SOLID_TRIGGER;
 183         });
 184 }
 185
 186 void WarpZone_Trace_InitTransform()
 187 {
 188         if(!WarpZone_trace_transform)
 189         {
 190                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 191         }
 192         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 193 }
 194 void WarpZone_Trace_AddTransform(entity wz)
 195 {
 196         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 197 }
 198
 199 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 200 {
 201         float nomonsters_adjusted;
 202         float frac, sol, i;
 203         float contentshack;
 204         vector o0, e0;
 205         entity wz;
 206         vector vf, vr, vu;
 207
 208         WarpZone_trace_forent = forent;
 209         WarpZone_trace_firstzone = NULL;
 210         WarpZone_trace_lastzone = NULL;
 211         WarpZone_Trace_InitTransform();
 212         if(!warpzone_warpzones_exist)
 213         {
 214                 if(nomonsters == MOVE_NOTHING)
 215                 {
 216                         trace_endpos = end;
 217                         trace_fraction = 1;
 218                         if(cb)
 219                                 cb(org, trace_endpos, end);
 220                         return;
 221                 }
 222                 else
 223                 {
 224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 225                         if(cb)
 226                                 cb(org, trace_endpos, end);
 227                         return;
 228                 }
 229         }
 230
 231         vf = v_forward;
 232         vr = v_right;
 233         vu = v_up;
 234         o0 = org;
 235         e0 = end;
 236
 237         switch(nomonsters)
 238         {
 239                 case MOVE_WORLDONLY:
 240                 case MOVE_NOTHING:
 241                         nomonsters_adjusted = MOVE_NOMONSTERS;
 242                         break;
 243                 default:
 244                         nomonsters_adjusted = nomonsters;
 245                         break;
 246         }
 247         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 248                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 249
 250         // if starting in warpzone, first transform
 251         wz = WarpZone_Find(org + mi, org + ma);
 252         if(wz)
 253         {
 254                 WarpZone_trace_firstzone = wz;
 255                 WarpZone_trace_lastzone = wz;
 256                 if(zone && wz != zone)
 257                 {
 258                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 259                         sol = 1;
 260                         trace_fraction = 0;
 261                         trace_endpos = org;
 262                         goto fail;
 263                 }
 264                 WarpZone_Trace_AddTransform(wz);
 265                 org = WarpZone_TransformOrigin(wz, org);
 266                 end = WarpZone_TransformOrigin(wz, end);
 267         }
 268         WarpZone_MakeAllSolid();
 269         sol = -1;
 270         frac = 0;
 271         i = 16;
 272         for (;;)
 273         {
 274                 if(--i < 1)
 275                 {
 276                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 277                         trace_ent = NULL;
 278                         break;
 279                 }
 280                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 281                 if(cb)
 282                         cb(org, trace_endpos, end);
 283                 if(sol < 0)
 284                         sol = trace_startsolid;
 285
 286                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 287                 if(trace_fraction >= 1)
 288                         break;
 289                 if(trace_ent.classname != "trigger_warpzone")
 290                 {
 291                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 292                         {
 293                                 // continue the trace, ignoring this hit (we only care for warpzones)
 294                                 org = trace_endpos + normalize(end - org);
 295                                 continue;
 296                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 297                                 // otherwise, players could block entrances that way
 298                         }
 299                         break;
 300                 }
 301                 if(trace_ent == wz)
 302                 {
 303                         // FIXME can this check be removed? Do we really need it?
 304                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 305                         trace_ent = NULL;
 306                         break;
 307                 }
 308                 wz = trace_ent;
 309                 if(!WarpZone_trace_firstzone)
 310                         WarpZone_trace_firstzone = wz;
 311                 WarpZone_trace_lastzone = wz;
 312                 if(zone && wz != zone)
 313                         break;
 314                 WarpZone_Trace_AddTransform(wz);
 315                 // we hit a warpzone... so, let's perform the trace after the warp again
 316                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 317                 end = WarpZone_TransformOrigin(wz, end);
 318
 319                 // we got warped, so let's step back a bit
 320                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 321                 org = trace_endpos;
 322         }
 323         WarpZone_MakeAllOther();
 324 LABEL(fail)
 325         if(contentshack)
 326                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 327         trace_startsolid = sol;
 328         v_forward = vf;
 329         v_right = vr;
 330         v_up = vu;
 331 }
 332
 333 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 334 {
 335         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 336 }
 337
 338 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 339 {
 340         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 341 }
 342
 343 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 344 {
 345         float g, dt, i;
 346         vector vf, vr, vu, v0, o0;
 347         entity wz;
 348
 349         o0 = e.origin;
 350         v0 = e.velocity;
 351         g = cvar("sv_gravity") * e.gravity;
 352
 353         WarpZone_trace_forent = forent;
 354         WarpZone_trace_firstzone = NULL;
 355         WarpZone_trace_lastzone = NULL;
 356         WarpZone_Trace_InitTransform();
 357         WarpZone_tracetoss_time = 0;
 358         if(!warpzone_warpzones_exist)
 359         {
 360                 tracetoss(e, WarpZone_trace_forent);
 361                 if(cb)
 362                         cb(e.origin, trace_endpos, trace_endpos);
 363                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 364                 WarpZone_tracetoss_time += dt;
 365                 e.velocity_z -= dt * g;
 366                 WarpZone_tracetoss_velocity = e.velocity;
 367                 e.velocity = v0;
 368                 return;
 369         }
 370
 371         vf = v_forward;
 372         vr = v_right;
 373         vu = v_up;
 374
 375         // if starting in warpzone, first transform
 376         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 377         if(wz)
 378         {
 379                 WarpZone_trace_firstzone = wz;
 380                 WarpZone_trace_lastzone = wz;
 381                 if(zone && wz != zone)
 382                 {
 383                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 384
 385                         WarpZone_tracetoss_time = 0;
 386                         trace_endpos = o0;
 387                         goto fail;
 388                 }
 389                 WarpZone_Trace_AddTransform(wz);
 390                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 391                 setorigin(e, org);
 392                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 393         }
 394         WarpZone_MakeAllSolid();
 395         i = 16;
 396         for (;;)
 397         {
 398                 if(--i < 1)
 399                 {
 400                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 401                         trace_ent = NULL;
 402                         break;
 403                 }
 404                 tracetoss(e, WarpZone_trace_forent);
 405                 if(cb)
 406                         cb(e.origin, trace_endpos, trace_endpos);
 407                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 408                 WarpZone_tracetoss_time += dt;
 409                 e.origin = trace_endpos;
 410                 e.velocity_z -= dt * g;
 411                 if(trace_fraction >= 1)
 412                         break;
 413                 if(trace_ent.classname != "trigger_warpzone")
 414                         break;
 415                 if(trace_ent == wz)
 416                 {
 417                         // FIXME can this check be removed? Do we really need it?
 418                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 419                         trace_ent = NULL;
 420                         break;
 421                 }
 422                 wz = trace_ent;
 423                 if(!WarpZone_trace_firstzone)
 424                         WarpZone_trace_firstzone = wz;
 425                 WarpZone_trace_lastzone = wz;
 426                 if(zone && wz != zone)
 427                         break;
 428                 WarpZone_Trace_AddTransform(wz);
 429                 // we hit a warpzone... so, let's perform the trace after the warp again
 430                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 431                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 432
 433                 // we got warped, so let's step back a bit
 434                 e.velocity = -e.velocity;
 435                 tracetoss(e, WarpZone_trace_forent);
 436                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 437                 WarpZone_tracetoss_time -= dt;
 438                 e.origin = trace_endpos;
 439                 e.velocity = -e.velocity;
 440         }
 441         WarpZone_MakeAllOther();
 442 LABEL(fail)
 443         WarpZone_tracetoss_velocity = e.velocity;
 444         v_forward = vf;
 445         v_right = vr;
 446         v_up = vu;
 447         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 448         e.velocity = v0;
 449         e.origin = o0;
 450 }
 451
 452 void WarpZone_TraceToss(entity e, entity forent)
 453 {
 454         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 455 }
 456
 457 entity WarpZone_TrailParticles_trace_callback_own;
 458 float WarpZone_TrailParticles_trace_callback_eff;
 459 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 460 {
 461         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 462 }
 463
 464 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 465 {
 466         WarpZone_TrailParticles_trace_callback_own = own;
 467         WarpZone_TrailParticles_trace_callback_eff = eff;
 468         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 469 }
 470
 471 #ifdef CSQC
 472 float WarpZone_TrailParticles_trace_callback_f;
 473 float WarpZone_TrailParticles_trace_callback_flags;
 474 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 475 {
 476         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 477 }
 478
 479 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 480 {
 481         WarpZone_TrailParticles_trace_callback_own = own;
 482         WarpZone_TrailParticles_trace_callback_eff = eff;
 483         WarpZone_TrailParticles_trace_callback_f = f;
 484         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 485         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 486 }
 487 #endif
 488
 489 float WarpZone_PlaneDist(entity wz, vector v)
 490 {
 491         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 492 }
 493
 494 float WarpZone_TargetPlaneDist(entity wz, vector v)
 495 {
 496         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 497 }
 498
 499 vector WarpZone_TransformOrigin(entity wz, vector v)
 500 {
 501         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 502 }
 503
 504 vector WarpZone_TransformVelocity(entity wz, vector v)
 505 {
 506         return AnglesTransform_Apply(wz.warpzone_transform, v);
 507 }
 508
 509 vector WarpZone_TransformAngles(entity wz, vector v)
 510 {
 511         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 512 }
 513
 514 vector WarpZone_TransformVAngles(entity wz, vector ang)
 515 {
 516 #ifdef KEEP_ROLL
 517         float roll;
 518         roll = ang.z;
 519         ang.z = 0;
 520 #endif
 521
 522         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 523
 524 #ifdef KEEP_ROLL
 525         ang = AnglesTransform_Normalize(ang, true);
 526         ang = AnglesTransform_CancelRoll(ang);
 527         ang.z = roll;
 528 #else
 529         ang = AnglesTransform_Normalize(ang, false);
 530 #endif
 531
 532         return ang;
 533 }
 534
 535 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 536 {
 537         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 538 }
 539
 540 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 541 {
 542         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 543 }
 544
 545 vector WarpZone_UnTransformAngles(entity wz, vector v)
 546 {
 547         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 548 }
 549
 550 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 551 {
 552         float roll;
 553
 554         roll = ang.z;
 555         ang.z = 0;
 556
 557         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 558         ang = AnglesTransform_Normalize(ang, true);
 559         ang = AnglesTransform_CancelRoll(ang);
 560
 561         ang.z = roll;
 562         return ang;
 563 }
 564
 565 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 566 {
 567         vector nearest;
 568         nearest.x = bound(mi.x, org.x, ma.x);
 569         nearest.y = bound(mi.y, org.y, ma.y);
 570         nearest.z = bound(mi.z, org.z, ma.z);
 571         return nearest;
 572 }
 573
 574 bool WarpZoneLib_BadEntity(entity e)
 575 {
 576         if (is_pure(e)) return true;
 577         string s = e.classname;
 578         switch (s)
 579         {
 580                 // case "net_linked": // actually some real entities are linked without classname, fail
 581                 case "":
 582                         return true;
 583         }
 584
 585         if (startsWith(s, "target_")) return true;
 586
 587         if (startsWith(s, "info_")) return true;
 588
 589         return false;
 590 }
 591
 592 .float WarpZone_findradius_hit;
 593 .entity WarpZone_findradius_next;
 594 void WarpZone_FindRadius_Recurse(
 595     /** blast origin of current search */
 596     vector org,
 597     float rad,
 598     /** original blast origin */
 599     vector org0,
 600     /** how to untransform (victim to blast system) */
 601     vector transform,
 602     vector shift,
 603     bool needlineofsight)
 604 {
 605         if (rad <= 0) return;
 606         entity wz = NULL;
 607         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 608                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 609                 if (needlineofsight)
 610                 {
 611                         traceline(org, p, MOVE_NOMONSTERS, it);
 612                         if (trace_fraction < 1) continue;
 613                 }
 614                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 615                 {
 616                         it.WarpZone_findradius_nearest = p;
 617                         it.WarpZone_findradius_dist = org0 - p;
 618                         it.WarpZone_findradius_findorigin = org;
 619                         it.WarpZone_findradius_findradius = rad;
 620                         if (it.classname == "warpzone_refsys")
 621                         {
 622                                 // ignore, especially: do not overwrite the refsys parameters
 623                         }
 624                         else if (it.classname == "trigger_warpzone")
 625                         {
 626                                 it.WarpZone_findradius_next = wz;
 627                                 wz = it;
 628                                 it.WarpZone_findradius_hit = 1;
 629                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 630                                 it.enemy.WarpZone_findradius_hit = 1;
 631                         }
 632                         else
 633                         {
 634                                 it.warpzone_transform = transform;
 635                                 it.warpzone_shift = shift;
 636                                 it.WarpZone_findradius_hit = 1;
 637                         }
 638                 }
 639     });
 640         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 641         {
 642                 if (WarpZoneLib_BadEntity(e)) continue;
 643
 644                 vector org0_new = WarpZone_TransformOrigin(e, org);
 645                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 646                 vector org_new = trace_endpos;
 647
 648                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 649                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 650                 WarpZone_FindRadius_Recurse(
 651                         org_new,
 652                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 653                         org0_new,
 654                         transform_new, shift_new,
 655                         needlineofsight);
 656                 e.WarpZone_findradius_hit = 0;
 657                 e.enemy.WarpZone_findradius_hit = 0;
 658         }
 659 }
 660 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 661 {
 662     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 663     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 664         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 665         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 666         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 667         return list_first;
 668 }
 669
 670 .entity WarpZone_refsys;
 671 void WarpZone_RefSys_GC(entity this)
 672 {
 673         // garbage collect unused reference systems
 674         this.nextthink = time + 1;
 675         if(this.owner.WarpZone_refsys != this)
 676                 delete(this);
 677 }
 678 void WarpZone_RefSys_CheckCreate(entity me)
 679 {
 680         if(me.WarpZone_refsys.owner != me)
 681         {
 682                 me.WarpZone_refsys = new(warpzone_refsys);
 683                 me.WarpZone_refsys.owner = me;
 684                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 685                 me.WarpZone_refsys.nextthink = time + 1;
 686                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 687         }
 688 }
 689 void WarpZone_RefSys_Clear(entity me)
 690 {
 691         if(me.WarpZone_refsys)
 692         {
 693                 delete(me.WarpZone_refsys);
 694                 me.WarpZone_refsys = NULL;
 695         }
 696 }
 697 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 698 {
 699         if(t != '0 0 0' || s != '0 0 0')
 700         {
 701                 WarpZone_RefSys_CheckCreate(me);
 702                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 703         }
 704 }
 705 void WarpZone_RefSys_Add(entity me, entity wz)
 706 {
 707         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 708 }
 709 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 710 {
 711         if(t != '0 0 0' || s != '0 0 0')
 712         {
 713                 WarpZone_RefSys_CheckCreate(me);
 714                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 715         }
 716 }
 717 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 718 {
 719         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 720 }
 721 .vector WarpZone_refsys_incremental_shift;
 722 .vector WarpZone_refsys_incremental_transform;
 723 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 724 {
 725         //vector t, s;
 726         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 727         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 728                 return;
 729         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 730         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 731         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 732         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 733 }
 734 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 735 {
 736         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 737         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 738 }
 739 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 740 {
 741         if(from.WarpZone_refsys)
 742                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 743         if(to.WarpZone_refsys)
 744                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 745         return org;
 746 }
 747 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 748 {
 749         if(from.WarpZone_refsys)
 750                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 751         if(to.WarpZone_refsys)
 752                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 753         return vel;
 754 }
 755 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 756 {
 757         if(from.WarpZone_refsys)
 758                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 759         if(to.WarpZone_refsys)
 760                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 761         return ang;
 762 }
 763 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 764 {
 765         if(from.WarpZone_refsys)
 766                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 767         if(to.WarpZone_refsys)
 768                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 769         return ang;
 770 }
 771 void WarpZone_RefSys_Copy(entity me, entity from)
 772 {
 773         if(from.WarpZone_refsys)
 774         {
 775                 WarpZone_RefSys_CheckCreate(me);
 776                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 777                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 778         }
 779         else
 780                 WarpZone_RefSys_Clear(me);
 781 }
 782 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 783 {
 784         entity e;
 785         e = spawn();
 786         WarpZone_RefSys_Copy(e, me);
 787         return e;
 788 }
 789
 790 float WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
 791 {
 792         return !WarpZoneLib_BoxTouchesBrush(toucher.absmin, toucher.absmax, this, toucher);
 793 }
 794
 795
 796 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 797 {
 798         float eps = 0.0625;
 799         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 800         if (trace_startsolid)
 801                 return;
 802         if (trace_fraction < 1)
 803         {
 804                 // hit something
 805                 // adjust origin in the other direction...
 806                 setorigin(e, e.origin - by * (1 - trace_fraction));
 807         }
 808 }
 809
 810 float WarpZoneLib_MoveOutOfSolid(entity e)
 811 {
 812         vector o, m0, m1;
 813
 814         o = e.origin;
 815         traceline(o, o, MOVE_WORLDONLY, e);
 816         if (trace_startsolid)
 817                 return false;
 818
 819         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 820         if (!trace_startsolid)
 821                 return true;
 822
 823         m0 = e.mins;
 824         m1 = e.maxs;
 825         e.mins = '0 0 0';
 826         e.maxs = '0 0 0';
 827         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m0_x);
 828         e.mins_x = m0_x;
 829         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m1_x);
 830         e.maxs_x = m1_x;
 831         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m0_y);
 832         e.mins_y = m0_y;
 833         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m1_y);
 834         e.maxs_y = m1_y;
 835         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m0_z);
 836         e.mins_z = m0_z;
 837         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m1_z);
 838         e.maxs_z = m1_z;
 839         setorigin(e, e.origin);
 840
 841         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 842         if (trace_startsolid)
 843         {
 844                 setorigin(e, o);
 845                 return false;
 846         }
 847
 848         return true;
 849 }