Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / lib / warpzone / common.qc
1 #include "common.qh"
2
3 #if defined(CSQC)
4     #include <common/t_items.qh>
5 #elif defined(MENUQC)
6 #elif defined(SVQC)
7     #include <common/weapons/_all.qh>
8 #endif
9
10 void WarpZone_Accumulator_Clear(entity acc)
11 {
12         acc.warpzone_transform = '0 0 0';
13         acc.warpzone_shift = '0 0 0';
14 }
15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
16 {
17         vector tr, st;
18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
20         acc.warpzone_transform = tr;
21         acc.warpzone_shift = st;
22 }
23 void WarpZone_Accumulator_Add(entity acc, entity wz)
24 {
25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
26 }
27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
28 {
29         vector tt, ss;
30         tt = AnglesTransform_Invert(t);
31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
33         // yes, this probably can be done simpler... but this way is "obvious" :)
34 }
35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
36 {
37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
38 }
39
40 float autocvar_cl_warpzone_usetrace = 1;
41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
42 {
43         vector vf, vr, vu;
44         if(this.warpzone_fadestart)
45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
46                         return org;
47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
48                         // unneeded on client, on server this helps a lot
49         vf = v_forward;
50         vr = v_right;
51         vu = v_up;
52         org = WarpZone_TransformOrigin(this, org);
53         vf = WarpZone_TransformVelocity(this, vf);
54         vr = WarpZone_TransformVelocity(this, vr);
55         vu = WarpZone_TransformVelocity(this, vu);
56         if(autocvar_cl_warpzone_usetrace)
57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
58         else
59                 trace_endpos = this.warpzone_targetorigin;
60         v_forward = vf;
61         v_right = vr;
62         v_up = vu;
63         return org;
64 }
65
66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
67 {
68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
70         e.warpzone_origin = my_org;
71         e.warpzone_targetorigin = other_org;
72         e.warpzone_angles = my_ang;
73         e.warpzone_targetangles = other_ang;
74         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
75         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
76         setcamera_transform(e, WarpZone_camera_transform);
77 }
78
79 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
80 {
81         // a fixed camera view
82         if(this.warpzone_fadestart)
83                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
84                         return org;
85                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
86                         // unneeded on client, on server this helps a lot
87         trace_endpos = this.warpzone_origin;
88         makevectors(this.warpzone_angles);
89         return this.warpzone_origin;
90 }
91
92 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
93 {
94         e.warpzone_origin = my_org;
95         e.warpzone_angles = my_ang;
96         setcamera_transform(e, WarpZone_Camera_camera_transform);
97 }
98
99 .entity enemy;
100
101 vector WarpZoneLib_BoxTouchesBrush_mins;
102 vector WarpZoneLib_BoxTouchesBrush_maxs;
103 entity WarpZoneLib_BoxTouchesBrush_ent;
104 entity WarpZoneLib_BoxTouchesBrush_ignore;
105 float WarpZoneLib_BoxTouchesBrush_Recurse()
106 {
107         float s;
108         entity se;
109         float f;
110
111         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
112 #ifdef CSQC
113         if (trace_networkentity)
114         {
115                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
116                 // we cannot continue, as a player blocks us...
117                 // so, abort
118                 return 0;
119         }
120 #endif
121         if (!trace_ent)
122                 return 0;
123         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
124                 return 1;
125
126         se = trace_ent;
127         s = se.solid;
128         se.solid = SOLID_NOT;
129         f = WarpZoneLib_BoxTouchesBrush_Recurse();
130         se.solid = s;
131
132         return f;
133 }
134
135 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
136 {
137     float f, s;
138
139     if(!e.modelindex || e.warpzone_isboxy)
140         return 1;
141
142     s = e.solid;
143     e.solid = SOLID_BSP;
144     WarpZoneLib_BoxTouchesBrush_mins = mi;
145     WarpZoneLib_BoxTouchesBrush_maxs = ma;
146     WarpZoneLib_BoxTouchesBrush_ent = e;
147     WarpZoneLib_BoxTouchesBrush_ignore = ig;
148     f = WarpZoneLib_BoxTouchesBrush_Recurse();
149     e.solid = s;
150
151     return f;
152 }
153
154 entity WarpZone_Find(vector mi, vector ma)
155 {
156         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
157         if(!warpzone_warpzones_exist)
158                 return NULL;
159         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
160         {
161                 return it;
162         });
163         return NULL;
164 }
165
166 void WarpZone_MakeAllSolid()
167 {
168         if(!warpzone_warpzones_exist)
169                 return;
170         IL_EACH(g_warpzones, true,
171         {
172                 it.solid = SOLID_BSP;
173         });
174 }
175
176 void WarpZone_MakeAllOther()
177 {
178         if(!warpzone_warpzones_exist)
179                 return;
180         IL_EACH(g_warpzones, true,
181         {
182                 it.solid = SOLID_TRIGGER;
183         });
184 }
185
186 void WarpZone_Trace_InitTransform()
187 {
188         if(!WarpZone_trace_transform)
189         {
190                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
191         }
192         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
193 }
194 void WarpZone_Trace_AddTransform(entity wz)
195 {
196         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
197 }
198
199 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
200 {
201         float nomonsters_adjusted;
202         float frac, sol, i;
203         float contentshack;
204         vector o0, e0;
205         entity wz;
206         vector vf, vr, vu;
207
208         WarpZone_trace_forent = forent;
209         WarpZone_trace_firstzone = NULL;
210         WarpZone_trace_lastzone = NULL;
211         WarpZone_Trace_InitTransform();
212         if(!warpzone_warpzones_exist)
213         {
214                 if(nomonsters == MOVE_NOTHING)
215                 {
216                         trace_endpos = end;
217                         trace_fraction = 1;
218                         if(cb)
219                                 cb(org, trace_endpos, end);
220                         return;
221                 }
222                 else
223                 {
224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
225                         if(cb)
226                                 cb(org, trace_endpos, end);
227                         return;
228                 }
229         }
230
231         vf = v_forward;
232         vr = v_right;
233         vu = v_up;
234         o0 = org;
235         e0 = end;
236
237         switch(nomonsters)
238         {
239                 case MOVE_WORLDONLY:
240                 case MOVE_NOTHING:
241                         nomonsters_adjusted = MOVE_NOMONSTERS;
242                         break;
243                 default:
244                         nomonsters_adjusted = nomonsters;
245                         break;
246         }
247         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
248                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
249
250         // if starting in warpzone, first transform
251         wz = WarpZone_Find(org + mi, org + ma);
252         if(wz)
253         {
254                 WarpZone_trace_firstzone = wz;
255                 WarpZone_trace_lastzone = wz;
256                 if(zone && wz != zone)
257                 {
258                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
259                         sol = 1;
260                         trace_fraction = 0;
261                         trace_endpos = org;
262                         goto fail;
263                 }
264                 WarpZone_Trace_AddTransform(wz);
265                 org = WarpZone_TransformOrigin(wz, org);
266                 end = WarpZone_TransformOrigin(wz, end);
267         }
268         WarpZone_MakeAllSolid();
269         sol = -1;
270         frac = 0;
271         i = 16;
272         for (;;)
273         {
274                 if(--i < 1)
275                 {
276                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
277                         trace_ent = NULL;
278                         break;
279                 }
280                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
281                 if(cb)
282                         cb(org, trace_endpos, end);
283                 if(sol < 0)
284                         sol = trace_startsolid;
285
286                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
287                 if(trace_fraction >= 1)
288                         break;
289                 if(trace_ent.classname != "trigger_warpzone")
290                 {
291                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
292                         {
293                                 // continue the trace, ignoring this hit (we only care for warpzones)
294                                 org = trace_endpos + normalize(end - org);
295                                 continue;
296                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
297                                 // otherwise, players could block entrances that way
298                         }
299                         break;
300                 }
301                 /*if(trace_ent == wz)
302                 {
303                         // FIXME can this check be removed? Do we really need it?
304                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
305                         trace_ent = NULL;
306                         break;
307                 }*/
308                 wz = trace_ent;
309                 if(!WarpZone_trace_firstzone)
310                         WarpZone_trace_firstzone = wz;
311                 WarpZone_trace_lastzone = wz;
312                 if(zone && wz != zone)
313                         break;
314                 WarpZone_Trace_AddTransform(wz);
315                 // we hit a warpzone... so, let's perform the trace after the warp again
316                 org = WarpZone_TransformOrigin(wz, trace_endpos);
317                 end = WarpZone_TransformOrigin(wz, end);
318
319                 // we got warped, so let's step back a bit
320                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
321                 org = trace_endpos;
322         }
323         WarpZone_MakeAllOther();
324 LABEL(fail)
325         if(contentshack)
326                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
327         trace_startsolid = sol;
328         v_forward = vf;
329         v_right = vr;
330         v_up = vu;
331 }
332
333 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
334 {
335         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
336 }
337
338 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
339 {
340         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
341 }
342
343 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
344 {
345         float g, dt, i;
346         vector vf, vr, vu, v0, o0;
347         entity wz;
348
349         o0 = e.origin;
350         v0 = e.velocity;
351         g = cvar("sv_gravity") * e.gravity;
352
353         WarpZone_trace_forent = forent;
354         WarpZone_trace_firstzone = NULL;
355         WarpZone_trace_lastzone = NULL;
356         WarpZone_Trace_InitTransform();
357         WarpZone_tracetoss_time = 0;
358         if(!warpzone_warpzones_exist)
359         {
360                 tracetoss(e, WarpZone_trace_forent);
361                 if(cb)
362                         cb(e.origin, trace_endpos, trace_endpos);
363                 dt = vlen(e.origin - o0) / vlen(e.velocity);
364                 WarpZone_tracetoss_time += dt;
365                 e.velocity_z -= dt * g;
366                 WarpZone_tracetoss_velocity = e.velocity;
367                 e.velocity = v0;
368                 return;
369         }
370
371         vf = v_forward;
372         vr = v_right;
373         vu = v_up;
374
375         // if starting in warpzone, first transform
376         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
377         if(wz)
378         {
379                 WarpZone_trace_firstzone = wz;
380                 WarpZone_trace_lastzone = wz;
381                 if(zone && wz != zone)
382                 {
383                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
384
385                         WarpZone_tracetoss_time = 0;
386                         trace_endpos = o0;
387                         goto fail;
388                 }
389                 WarpZone_Trace_AddTransform(wz);
390                 vector org = WarpZone_TransformOrigin(wz, e.origin);
391                 setorigin(e, org);
392                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
393         }
394         WarpZone_MakeAllSolid();
395         i = 16;
396         for (;;)
397         {
398                 if(--i < 1)
399                 {
400                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
401                         trace_ent = NULL;
402                         break;
403                 }
404                 tracetoss(e, WarpZone_trace_forent);
405                 if(cb)
406                         cb(e.origin, trace_endpos, trace_endpos);
407                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
408                 WarpZone_tracetoss_time += dt;
409                 e.origin = trace_endpos;
410                 e.velocity_z -= dt * g;
411                 if(trace_fraction >= 1)
412                         break;
413                 if(trace_ent.classname != "trigger_warpzone")
414                         break;
415                 if(trace_ent == wz)
416                 {
417                         // FIXME can this check be removed? Do we really need it?
418                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
419                         trace_ent = NULL;
420                         break;
421                 }
422                 wz = trace_ent;
423                 if(!WarpZone_trace_firstzone)
424                         WarpZone_trace_firstzone = wz;
425                 WarpZone_trace_lastzone = wz;
426                 if(zone && wz != zone)
427                         break;
428                 WarpZone_Trace_AddTransform(wz);
429                 // we hit a warpzone... so, let's perform the trace after the warp again
430                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
431                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
432
433                 // we got warped, so let's step back a bit
434                 e.velocity = -e.velocity;
435                 tracetoss(e, WarpZone_trace_forent);
436                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
437                 WarpZone_tracetoss_time -= dt;
438                 e.origin = trace_endpos;
439                 e.velocity = -e.velocity;
440         }
441         WarpZone_MakeAllOther();
442 LABEL(fail)
443         WarpZone_tracetoss_velocity = e.velocity;
444         v_forward = vf;
445         v_right = vr;
446         v_up = vu;
447         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
448         e.velocity = v0;
449         e.origin = o0;
450 }
451
452 void WarpZone_TraceToss(entity e, entity forent)
453 {
454         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
455 }
456
457 entity WarpZone_TrailParticles_trace_callback_own;
458 float WarpZone_TrailParticles_trace_callback_eff;
459 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
460 {
461         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
462 }
463
464 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
465 {
466         WarpZone_TrailParticles_trace_callback_own = own;
467         WarpZone_TrailParticles_trace_callback_eff = eff;
468         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
469 }
470
471 #ifdef CSQC
472 float WarpZone_TrailParticles_trace_callback_f;
473 float WarpZone_TrailParticles_trace_callback_flags;
474 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
475 {
476         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
477 }
478
479 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
480 {
481         WarpZone_TrailParticles_trace_callback_own = own;
482         WarpZone_TrailParticles_trace_callback_eff = eff;
483         WarpZone_TrailParticles_trace_callback_f = f;
484         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
485         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
486 }
487 #endif
488
489 float WarpZone_PlaneDist(entity wz, vector v)
490 {
491         return (v - wz.warpzone_origin) * wz.warpzone_forward;
492 }
493
494 float WarpZone_TargetPlaneDist(entity wz, vector v)
495 {
496         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
497 }
498
499 vector WarpZone_TransformOrigin(entity wz, vector v)
500 {
501         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
502 }
503
504 vector WarpZone_TransformVelocity(entity wz, vector v)
505 {
506         return AnglesTransform_Apply(wz.warpzone_transform, v);
507 }
508
509 vector WarpZone_TransformAngles(entity wz, vector v)
510 {
511         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
512 }
513
514 vector WarpZone_TransformVAngles(entity wz, vector ang)
515 {
516 #ifdef KEEP_ROLL
517         float roll;
518         roll = ang.z;
519         ang.z = 0;
520 #endif
521
522         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
523
524 #ifdef KEEP_ROLL
525         ang = AnglesTransform_Normalize(ang, true);
526         ang = AnglesTransform_CancelRoll(ang);
527         ang.z = roll;
528 #else
529         ang = AnglesTransform_Normalize(ang, false);
530 #endif
531
532         return ang;
533 }
534
535 vector WarpZone_UnTransformOrigin(entity wz, vector v)
536 {
537         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
538 }
539
540 vector WarpZone_UnTransformVelocity(entity wz, vector v)
541 {
542         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
543 }
544
545 vector WarpZone_UnTransformAngles(entity wz, vector v)
546 {
547         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
548 }
549
550 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
551 {
552         float roll;
553
554         roll = ang.z;
555         ang.z = 0;
556
557         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
558         ang = AnglesTransform_Normalize(ang, true);
559         ang = AnglesTransform_CancelRoll(ang);
560
561         ang.z = roll;
562         return ang;
563 }
564
565 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
566 {
567         vector nearest;
568         nearest.x = bound(mi.x, org.x, ma.x);
569         nearest.y = bound(mi.y, org.y, ma.y);
570         nearest.z = bound(mi.z, org.z, ma.z);
571         return nearest;
572 }
573
574 bool WarpZoneLib_BadEntity(entity e)
575 {
576         if (is_pure(e)) return true;
577         string s = e.classname;
578
579         //if (s == "net_linked") return true; // actually some real entities are linked without classname, fail
580         if (s == "") return true;
581
582         if (startsWith(s, "target_")) return true;
583
584         if (startsWith(s, "info_")) return true;
585
586         return false;
587 }
588
589 .float WarpZone_findradius_hit;
590 .entity WarpZone_findradius_next;
591 void WarpZone_FindRadius_Recurse(
592     /** blast origin of current search */
593     vector org,
594     float rad,
595     /** original blast origin */
596     vector org0,
597     /** how to untransform (victim to blast system) */
598     vector transform,
599     vector shift,
600     bool needlineofsight)
601 {
602         if (rad <= 0) return;
603         entity wz = NULL;
604         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
605                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
606                 if (needlineofsight)
607                 {
608                         traceline(org, p, MOVE_NOMONSTERS, it);
609                         if (trace_fraction < 1) continue;
610                 }
611                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
612                 {
613                         it.WarpZone_findradius_nearest = p;
614                         it.WarpZone_findradius_dist = org0 - p;
615                         it.WarpZone_findradius_findorigin = org;
616                         it.WarpZone_findradius_findradius = rad;
617                         if (it.classname == "warpzone_refsys")
618                         {
619                                 // ignore, especially: do not overwrite the refsys parameters
620                         }
621                         else if (it.classname == "trigger_warpzone")
622                         {
623                                 it.WarpZone_findradius_next = wz;
624                                 wz = it;
625                                 it.WarpZone_findradius_hit = 1;
626                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
627                                 it.enemy.WarpZone_findradius_hit = 1;
628                         }
629                         else
630                         {
631                                 it.warpzone_transform = transform;
632                                 it.warpzone_shift = shift;
633                                 it.WarpZone_findradius_hit = 1;
634                         }
635                 }
636     });
637         for(entity e = wz; e; e = e.WarpZone_findradius_next)
638         {
639                 if (WarpZoneLib_BadEntity(e)) continue;
640
641                 vector org0_new = WarpZone_TransformOrigin(e, org);
642                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
643                 vector org_new = trace_endpos;
644
645                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
646                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
647                 WarpZone_FindRadius_Recurse(
648                         org_new,
649                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
650                         org0_new,
651                         transform_new, shift_new,
652                         needlineofsight);
653                 e.WarpZone_findradius_hit = 0;
654                 e.enemy.WarpZone_findradius_hit = 0;
655         }
656 }
657 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
658 {
659     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
660     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
661         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
662         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
663         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
664         return list_first;
665 }
666
667 .entity WarpZone_refsys;
668 void WarpZone_RefSys_GC(entity this)
669 {
670         // garbage collect unused reference systems
671         this.nextthink = time + 1;
672         if(this.owner.WarpZone_refsys != this)
673                 delete(this);
674 }
675 void WarpZone_RefSys_CheckCreate(entity me)
676 {
677         if(me.WarpZone_refsys.owner != me)
678         {
679                 me.WarpZone_refsys = new(warpzone_refsys);
680                 me.WarpZone_refsys.owner = me;
681                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
682                 me.WarpZone_refsys.nextthink = time + 1;
683                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
684         }
685 }
686 void WarpZone_RefSys_Clear(entity me)
687 {
688         if(me.WarpZone_refsys)
689         {
690                 delete(me.WarpZone_refsys);
691                 me.WarpZone_refsys = NULL;
692         }
693 }
694 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
695 {
696         if(t != '0 0 0' || s != '0 0 0')
697         {
698                 WarpZone_RefSys_CheckCreate(me);
699                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
700         }
701 }
702 void WarpZone_RefSys_Add(entity me, entity wz)
703 {
704         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
705 }
706 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
707 {
708         if(t != '0 0 0' || s != '0 0 0')
709         {
710                 WarpZone_RefSys_CheckCreate(me);
711                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
712         }
713 }
714 void WarpZone_RefSys_AddInverse(entity me, entity wz)
715 {
716         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
717 }
718 .vector WarpZone_refsys_incremental_shift;
719 .vector WarpZone_refsys_incremental_transform;
720 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
721 {
722         //vector t, s;
723         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
724         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
725                 return;
726         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
727         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
728         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
729         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
730 }
731 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
732 {
733         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
734         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
735 }
736 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
737 {
738         if(from.WarpZone_refsys)
739                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
740         if(to.WarpZone_refsys)
741                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
742         return org;
743 }
744 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
745 {
746         if(from.WarpZone_refsys)
747                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
748         if(to.WarpZone_refsys)
749                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
750         return vel;
751 }
752 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
753 {
754         if(from.WarpZone_refsys)
755                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
756         if(to.WarpZone_refsys)
757                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
758         return ang;
759 }
760 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
761 {
762         if(from.WarpZone_refsys)
763                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
764         if(to.WarpZone_refsys)
765                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
766         return ang;
767 }
768 void WarpZone_RefSys_Copy(entity me, entity from)
769 {
770         if(from.WarpZone_refsys)
771         {
772                 WarpZone_RefSys_CheckCreate(me);
773                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
774                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
775         }
776         else
777                 WarpZone_RefSys_Clear(me);
778 }
779 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
780 {
781         entity e;
782         e = spawn();
783         WarpZone_RefSys_Copy(e, me);
784         return e;
785 }
786
787 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
788 {
789         return !WarpZoneLib_BoxTouchesBrush(toucher.absmin, toucher.absmax, this, toucher);
790 }
791
792
793 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
794 {
795         float eps = 0.0625;
796         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
797         if (trace_startsolid)
798                 return;
799         if (trace_fraction < 1)
800         {
801                 // hit something
802                 // adjust origin in the other direction...
803                 setorigin(e, e.origin - by * (1 - trace_fraction));
804         }
805 }
806
807 bool WarpZoneLib_MoveOutOfSolid(entity e)
808 {
809         vector o = e.origin;
810         traceline(o, o, MOVE_WORLDONLY, e);
811         if (trace_startsolid)
812                 return false;
813
814         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
815         if (!trace_startsolid)
816                 return true;
817
818         vector m0 = e.mins;
819         vector m1 = e.maxs;
820         e.mins = '0 0 0';
821         e.maxs = '0 0 0';
822         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
823         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
824         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
825         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
826         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
827         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
828         setorigin(e, e.origin);
829
830         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
831         if (trace_startsolid)
832         {
833                 setorigin(e, o);
834                 return false;
835         }
836
837         return true;
838 }