qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include "../../server/t_items.qh"
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include "../../common/weapons/all.qh"
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 .vector(vector, vector) camera_transform;
  41 float autocvar_cl_warpzone_usetrace = 1;
  42 vector WarpZone_camera_transform(vector org, vector ang)
  43 {SELFPARAM();
  44         vector vf, vr, vu;
  45         if(self.warpzone_fadestart)
  46                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  47                         return org;
  48                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  49                         // unneeded on client, on server this helps a lot
  50         vf = v_forward;
  51         vr = v_right;
  52         vu = v_up;
  53         org = WarpZone_TransformOrigin(self, org);
  54         vf = WarpZone_TransformVelocity(self, vf);
  55         vr = WarpZone_TransformVelocity(self, vr);
  56         vu = WarpZone_TransformVelocity(self, vu);
  57         if(autocvar_cl_warpzone_usetrace)
  58                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  59         else
  60                 trace_endpos = self.warpzone_targetorigin;
  61         v_forward = vf;
  62         v_right = vr;
  63         v_up = vu;
  64         return org;
  65 }
  66
  67 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  68 {
  69         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  70         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  71         e.warpzone_origin = my_org;
  72         e.warpzone_targetorigin = other_org;
  73         e.warpzone_angles = my_ang;
  74         e.warpzone_targetangles = other_ang;
  75         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  76         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  77         e.camera_transform = WarpZone_camera_transform;
  78 }
  79
  80 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  81 {SELFPARAM();
  82         // a fixed camera view
  83         if(self.warpzone_fadestart)
  84                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  85                         return org;
  86                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  87                         // unneeded on client, on server this helps a lot
  88         trace_endpos = self.warpzone_origin;
  89         makevectors(self.warpzone_angles);
  90         return self.warpzone_origin;
  91 }
  92
  93 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  94 {
  95         e.warpzone_origin = my_org;
  96         e.warpzone_angles = my_ang;
  97         e.camera_transform = WarpZone_Camera_camera_transform;
  98 }
  99
 100 .entity enemy;
 101
 102 vector WarpZoneLib_BoxTouchesBrush_mins;
 103 vector WarpZoneLib_BoxTouchesBrush_maxs;
 104 entity WarpZoneLib_BoxTouchesBrush_ent;
 105 entity WarpZoneLib_BoxTouchesBrush_ignore;
 106 float WarpZoneLib_BoxTouchesBrush_Recurse()
 107 {
 108         float s;
 109         entity se;
 110         float f;
 111
 112         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 113 #ifdef CSQC
 114         if (trace_networkentity)
 115         {
 116                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
 117                 // we cannot continue, as a player blocks us...
 118                 // so, abort
 119                 return 0;
 120         }
 121 #endif
 122         if (!trace_ent)
 123                 return 0;
 124         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 125                 return 1;
 126
 127         se = trace_ent;
 128         s = se.solid;
 129         se.solid = SOLID_NOT;
 130         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 131         se.solid = s;
 132
 133         return f;
 134 }
 135
 136 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 137 {
 138     float f, s;
 139
 140     if(!e.modelindex || e.warpzone_isboxy)
 141         return 1;
 142
 143     s = e.solid;
 144     e.solid = SOLID_BSP;
 145     WarpZoneLib_BoxTouchesBrush_mins = mi;
 146     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 147     WarpZoneLib_BoxTouchesBrush_ent = e;
 148     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 149     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 150     e.solid = s;
 151
 152     return f;
 153 }
 154
 155 entity WarpZone_Find(vector mi, vector ma)
 156 {
 157         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 158         entity e;
 159         if(!warpzone_warpzones_exist)
 160                 return world;
 161         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 162                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 163                         return e;
 164         return world;
 165 }
 166
 167 void WarpZone_MakeAllSolid()
 168 {
 169         entity e;
 170         if(!warpzone_warpzones_exist)
 171                 return;
 172         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 173                 e.solid = SOLID_BSP;
 174 }
 175
 176 void WarpZone_MakeAllOther()
 177 {
 178         entity e;
 179         if(!warpzone_warpzones_exist)
 180                 return;
 181         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 182                 e.solid = SOLID_TRIGGER;
 183 }
 184
 185 void WarpZone_Trace_InitTransform()
 186 {
 187         if(!WarpZone_trace_transform)
 188         {
 189                 WarpZone_trace_transform = new(warpzone_trace_transform);
 190                 make_pure(WarpZone_trace_transform);
 191         }
 192         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 193 }
 194 void WarpZone_Trace_AddTransform(entity wz)
 195 {
 196         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 197 }
 198
 199 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 200 {
 201         float nomonsters_adjusted;
 202         float frac, sol, i;
 203         float contentshack;
 204         vector o0, e0;
 205         entity wz;
 206         vector vf, vr, vu;
 207
 208         WarpZone_trace_forent = forent;
 209         WarpZone_trace_firstzone = world;
 210         WarpZone_trace_lastzone = world;
 211         WarpZone_Trace_InitTransform();
 212         if(!warpzone_warpzones_exist)
 213         {
 214                 if(nomonsters == MOVE_NOTHING)
 215                 {
 216                         trace_endpos = end;
 217                         trace_fraction = 1;
 218                         if(cb)
 219                                 cb(org, trace_endpos, end);
 220                         return;
 221                 }
 222                 else
 223                 {
 224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 225                         if(cb)
 226                                 cb(org, trace_endpos, end);
 227                         return;
 228                 }
 229         }
 230
 231         vf = v_forward;
 232         vr = v_right;
 233         vu = v_up;
 234         o0 = org;
 235         e0 = end;
 236
 237         switch(nomonsters)
 238         {
 239                 case MOVE_WORLDONLY:
 240                 case MOVE_NOTHING:
 241                         nomonsters_adjusted = MOVE_NOMONSTERS;
 242                         break;
 243                 default:
 244                         nomonsters_adjusted = nomonsters;
 245                         break;
 246         }
 247         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 248                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 249
 250         // if starting in warpzone, first transform
 251         wz = WarpZone_Find(org + mi, org + ma);
 252         if(wz)
 253         {
 254                 WarpZone_trace_firstzone = wz;
 255                 WarpZone_trace_lastzone = wz;
 256                 if(zone && wz != zone)
 257                 {
 258                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 259                         sol = 1;
 260                         trace_fraction = 0;
 261                         trace_endpos = org;
 262                         goto fail;
 263                 }
 264                 WarpZone_Trace_AddTransform(wz);
 265                 org = WarpZone_TransformOrigin(wz, org);
 266                 end = WarpZone_TransformOrigin(wz, end);
 267         }
 268         WarpZone_MakeAllSolid();
 269         sol = -1;
 270         frac = 0;
 271         i = 16;
 272         for (;;)
 273         {
 274                 if(--i < 1)
 275                 {
 276                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
 277                         trace_ent = world;
 278                         break;
 279                 }
 280                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 281                 if(cb)
 282                         cb(org, trace_endpos, end);
 283                 if(sol < 0)
 284                         sol = trace_startsolid;
 285
 286                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 287                 if(trace_fraction >= 1)
 288                         break;
 289                 if(trace_ent.classname != "trigger_warpzone")
 290                 {
 291                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 292                         {
 293                                 // continue the trace, ignoring this hit (we only care for warpzones)
 294                                 org = trace_endpos + normalize(end - org);
 295                                 continue;
 296                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 297                                 // otherwise, players could block entrances that way
 298                         }
 299                         break;
 300                 }
 301                 if(trace_ent == wz)
 302                 {
 303                         // FIXME can this check be removed? Do we really need it?
 304                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
 305                         trace_ent = world;
 306                         break;
 307                 }
 308                 wz = trace_ent;
 309                 if(!WarpZone_trace_firstzone)
 310                         WarpZone_trace_firstzone = wz;
 311                 WarpZone_trace_lastzone = wz;
 312                 if(zone && wz != zone)
 313                         break;
 314                 WarpZone_Trace_AddTransform(wz);
 315                 // we hit a warpzone... so, let's perform the trace after the warp again
 316                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 317                 end = WarpZone_TransformOrigin(wz, end);
 318
 319                 // we got warped, so let's step back a bit
 320                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 321                 org = trace_endpos;
 322         }
 323         WarpZone_MakeAllOther();
 324 :fail
 325         if(contentshack)
 326                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 327         trace_startsolid = sol;
 328         v_forward = vf;
 329         v_right = vr;
 330         v_up = vu;
 331 }
 332
 333 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 334 {
 335         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 336 }
 337
 338 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 339 {
 340         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 341 }
 342
 343 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 344 {
 345         float g, dt, i;
 346         vector vf, vr, vu, v0, o0;
 347         entity wz;
 348
 349         o0 = e.origin;
 350         v0 = e.velocity;
 351         g = cvar("sv_gravity") * e.gravity;
 352
 353         WarpZone_trace_forent = forent;
 354         WarpZone_trace_firstzone = world;
 355         WarpZone_trace_lastzone = world;
 356         WarpZone_Trace_InitTransform();
 357         WarpZone_tracetoss_time = 0;
 358         if(!warpzone_warpzones_exist)
 359         {
 360                 tracetoss(e, WarpZone_trace_forent);
 361                 if(cb)
 362                         cb(e.origin, trace_endpos, trace_endpos);
 363                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 364                 WarpZone_tracetoss_time += dt;
 365                 e.velocity_z -= dt * g;
 366                 WarpZone_tracetoss_velocity = e.velocity;
 367                 e.velocity = v0;
 368                 return;
 369         }
 370
 371         vf = v_forward;
 372         vr = v_right;
 373         vu = v_up;
 374
 375         // if starting in warpzone, first transform
 376         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 377         if(wz)
 378         {
 379                 WarpZone_trace_firstzone = wz;
 380                 WarpZone_trace_lastzone = wz;
 381                 if(zone && wz != zone)
 382                 {
 383                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 384
 385                         WarpZone_tracetoss_time = 0;
 386                         trace_endpos = o0;
 387                         goto fail;
 388                 }
 389                 WarpZone_Trace_AddTransform(wz);
 390                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 391                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 392         }
 393         WarpZone_MakeAllSolid();
 394         i = 16;
 395         for (;;)
 396         {
 397                 if(--i < 1)
 398                 {
 399                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
 400                         trace_ent = world;
 401                         break;
 402                 }
 403                 tracetoss(e, WarpZone_trace_forent);
 404                 if(cb)
 405                         cb(e.origin, trace_endpos, trace_endpos);
 406                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 407                 WarpZone_tracetoss_time += dt;
 408                 e.origin = trace_endpos;
 409                 e.velocity_z -= dt * g;
 410                 if(trace_fraction >= 1)
 411                         break;
 412                 if(trace_ent.classname != "trigger_warpzone")
 413                         break;
 414                 if(trace_ent == wz)
 415                 {
 416                         // FIXME can this check be removed? Do we really need it?
 417                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
 418                         trace_ent = world;
 419                         break;
 420                 }
 421                 wz = trace_ent;
 422                 if(!WarpZone_trace_firstzone)
 423                         WarpZone_trace_firstzone = wz;
 424                 WarpZone_trace_lastzone = wz;
 425                 if(zone && wz != zone)
 426                         break;
 427                 WarpZone_Trace_AddTransform(wz);
 428                 // we hit a warpzone... so, let's perform the trace after the warp again
 429                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 430                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 431
 432                 // we got warped, so let's step back a bit
 433                 e.velocity = -e.velocity;
 434                 tracetoss(e, WarpZone_trace_forent);
 435                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 436                 WarpZone_tracetoss_time -= dt;
 437                 e.origin = trace_endpos;
 438                 e.velocity = -e.velocity;
 439         }
 440         WarpZone_MakeAllOther();
 441 :fail
 442         WarpZone_tracetoss_velocity = e.velocity;
 443         v_forward = vf;
 444         v_right = vr;
 445         v_up = vu;
 446         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 447         e.velocity = v0;
 448         e.origin = o0;
 449 }
 450
 451 void WarpZone_TraceToss(entity e, entity forent)
 452 {
 453         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 454 }
 455
 456 entity WarpZone_TrailParticles_trace_callback_own;
 457 float WarpZone_TrailParticles_trace_callback_eff;
 458 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 459 {
 460         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 461 }
 462
 463 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 464 {
 465         WarpZone_TrailParticles_trace_callback_own = own;
 466         WarpZone_TrailParticles_trace_callback_eff = eff;
 467         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 468 }
 469
 470 #ifdef CSQC
 471 float WarpZone_TrailParticles_trace_callback_f;
 472 float WarpZone_TrailParticles_trace_callback_flags;
 473 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 474 {
 475         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 476 }
 477
 478 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 479 {
 480         WarpZone_TrailParticles_trace_callback_own = own;
 481         WarpZone_TrailParticles_trace_callback_eff = eff;
 482         WarpZone_TrailParticles_trace_callback_f = f;
 483         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 484         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 485 }
 486 #endif
 487
 488 float WarpZone_PlaneDist(entity wz, vector v)
 489 {
 490         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 491 }
 492
 493 float WarpZone_TargetPlaneDist(entity wz, vector v)
 494 {
 495         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 496 }
 497
 498 vector WarpZone_TransformOrigin(entity wz, vector v)
 499 {
 500         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 501 }
 502
 503 vector WarpZone_TransformVelocity(entity wz, vector v)
 504 {
 505         return AnglesTransform_Apply(wz.warpzone_transform, v);
 506 }
 507
 508 vector WarpZone_TransformAngles(entity wz, vector v)
 509 {
 510         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 511 }
 512
 513 vector WarpZone_TransformVAngles(entity wz, vector ang)
 514 {
 515 #ifdef KEEP_ROLL
 516         float roll;
 517         roll = ang.z;
 518         ang.z = 0;
 519 #endif
 520
 521         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 522
 523 #ifdef KEEP_ROLL
 524         ang = AnglesTransform_Normalize(ang, true);
 525         ang = AnglesTransform_CancelRoll(ang);
 526         ang.z = roll;
 527 #else
 528         ang = AnglesTransform_Normalize(ang, false);
 529 #endif
 530
 531         return ang;
 532 }
 533
 534 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 535 {
 536         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 537 }
 538
 539 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 540 {
 541         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 542 }
 543
 544 vector WarpZone_UnTransformAngles(entity wz, vector v)
 545 {
 546         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 547 }
 548
 549 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 550 {
 551         float roll;
 552
 553         roll = ang.z;
 554         ang.z = 0;
 555
 556         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 557         ang = AnglesTransform_Normalize(ang, true);
 558         ang = AnglesTransform_CancelRoll(ang);
 559
 560         ang.z = roll;
 561         return ang;
 562 }
 563
 564 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 565 {
 566         vector nearest;
 567         nearest.x = bound(mi.x, org.x, ma.x);
 568         nearest.y = bound(mi.y, org.y, ma.y);
 569         nearest.z = bound(mi.z, org.z, ma.z);
 570         return nearest;
 571 }
 572
 573 bool WarpZoneLib_BadEntity(entity e)
 574 {
 575         string s = e.classname;
 576         if (is_pure(e)) return true;
 577         switch (s)
 578         {
 579                 // case "net_linked": // actually some real entities are linked without classname, fail
 580                 case "":
 581                         return true;
 582         }
 583
 584         if (startsWith(s, "target_")) return true;
 585
 586         if (startsWith(s, "info_")) return true;
 587
 588         return false;
 589 }
 590
 591 .float WarpZone_findradius_hit;
 592 .entity WarpZone_findradius_next;
 593 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 594 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 595 {
 596         vector org_new;
 597         vector org0_new;
 598         vector shift_new, transform_new;
 599         vector p;
 600         entity e, e0;
 601         entity wz;
 602         if(rad <= 0)
 603                 return;
 604         e0 = findradius(org, rad);
 605         wz = world;
 606
 607         for(e = e0; e; e = e.chain)
 608         {
 609                 if(WarpZoneLib_BadEntity(e))
 610                         continue;
 611                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 612                 if(needlineofsight)
 613                 {
 614                         traceline(org, p, MOVE_NOMONSTERS, e);
 615                         if(trace_fraction < 1)
 616                                 continue;
 617                 }
 618                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 619                 {
 620                         e.WarpZone_findradius_nearest = p;
 621                         e.WarpZone_findradius_dist = org0 - p;
 622                         e.WarpZone_findradius_findorigin = org;
 623                         e.WarpZone_findradius_findradius = rad;
 624                         if(e.classname == "warpzone_refsys")
 625                         {
 626                                 // ignore, especially: do not overwrite the refsys parameters
 627                         }
 628                         else if(e.classname == "trigger_warpzone")
 629                         {
 630                                 e.WarpZone_findradius_next = wz;
 631                                 wz = e;
 632                                 e.WarpZone_findradius_hit = 1;
 633                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 634                                 e.enemy.WarpZone_findradius_hit = 1;
 635                         }
 636                         else
 637                         {
 638                                 e.warpzone_transform = transform;
 639                                 e.warpzone_shift = shift;
 640                                 e.WarpZone_findradius_hit = 1;
 641                         }
 642                 }
 643         }
 644         for(e = wz; e; e = e.WarpZone_findradius_next)
 645         {
 646                 if(WarpZoneLib_BadEntity(e))
 647                         continue;
 648
 649                 org0_new = WarpZone_TransformOrigin(e, org);
 650                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 651                 org_new = trace_endpos;
 652
 653                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 654                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 655                 WarpZone_FindRadius_Recurse(
 656                         org_new,
 657                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 658                         org0_new,
 659                         transform_new, shift_new,
 660                         needlineofsight);
 661                 e.WarpZone_findradius_hit = 0;
 662                 e.enemy.WarpZone_findradius_hit = 0;
 663         }
 664 }
 665 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 666 {
 667         entity e0, e;
 668         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 669         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 670         for(e = e0; e; e = e.chain)
 671                 e.WarpZone_findradius_hit = 0;
 672         return e0;
 673 }
 674
 675 .entity WarpZone_refsys;
 676 void WarpZone_RefSys_GC()
 677 {SELFPARAM();
 678         // garbage collect unused reference systems
 679         self.nextthink = time + 1;
 680         if(self.owner.WarpZone_refsys != self)
 681                 remove(self);
 682 }
 683 void WarpZone_RefSys_CheckCreate(entity me)
 684 {
 685         if(me.WarpZone_refsys.owner != me)
 686         {
 687                 me.WarpZone_refsys = new(warpzone_refsys);
 688                 me.WarpZone_refsys.owner = me;
 689                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 690                 me.WarpZone_refsys.nextthink = time + 1;
 691                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 692         }
 693 }
 694 void WarpZone_RefSys_Clear(entity me)
 695 {
 696         if(me.WarpZone_refsys)
 697         {
 698                 remove(me.WarpZone_refsys);
 699                 me.WarpZone_refsys = world;
 700         }
 701 }
 702 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 703 {
 704         if(t != '0 0 0' || s != '0 0 0')
 705         {
 706                 WarpZone_RefSys_CheckCreate(me);
 707                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 708         }
 709 }
 710 void WarpZone_RefSys_Add(entity me, entity wz)
 711 {
 712         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 713 }
 714 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 715 {
 716         if(t != '0 0 0' || s != '0 0 0')
 717         {
 718                 WarpZone_RefSys_CheckCreate(me);
 719                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 720         }
 721 }
 722 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 723 {
 724         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 725 }
 726 .vector WarpZone_refsys_incremental_shift;
 727 .vector WarpZone_refsys_incremental_transform;
 728 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 729 {
 730         //vector t, s;
 731         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 732         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 733                 return;
 734         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 735         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 736         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 737         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 738 }
 739 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 740 {
 741         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 742         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 743 }
 744 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 745 {
 746         if(from.WarpZone_refsys)
 747                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 748         if(to.WarpZone_refsys)
 749                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 750         return org;
 751 }
 752 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 753 {
 754         if(from.WarpZone_refsys)
 755                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 756         if(to.WarpZone_refsys)
 757                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 758         return vel;
 759 }
 760 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 761 {
 762         if(from.WarpZone_refsys)
 763                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 764         if(to.WarpZone_refsys)
 765                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 766         return ang;
 767 }
 768 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 769 {
 770         if(from.WarpZone_refsys)
 771                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 772         if(to.WarpZone_refsys)
 773                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 774         return ang;
 775 }
 776 void WarpZone_RefSys_Copy(entity me, entity from)
 777 {
 778         if(from.WarpZone_refsys)
 779         {
 780                 WarpZone_RefSys_CheckCreate(me);
 781                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 782                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 783         }
 784         else
 785                 WarpZone_RefSys_Clear(me);
 786 }
 787 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 788 {
 789         entity e;
 790         e = spawn();
 791         WarpZone_RefSys_Copy(e, me);
 792         return e;
 793 }
 794
 795 float WarpZoneLib_ExactTrigger_Touch()
 796 {SELFPARAM();
 797         return !WarpZoneLib_BoxTouchesBrush(other.absmin, other.absmax, self, other);
 798 }
 799
 800
 801 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 802 {
 803         float eps = 0.0625;
 804         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 805         if (trace_startsolid)
 806                 return;
 807         if (trace_fraction < 1)
 808         {
 809                 // hit something
 810                 // adjust origin in the other direction...
 811                 setorigin(e,e.origin - by * (1 - trace_fraction));
 812         }
 813 }
 814
 815 float WarpZoneLib_MoveOutOfSolid(entity e)
 816 {
 817         vector o, m0, m1;
 818
 819         o = e.origin;
 820         traceline(o, o, MOVE_WORLDONLY, e);
 821         if (trace_startsolid)
 822                 return false;
 823
 824         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 825         if (!trace_startsolid)
 826                 return true;
 827
 828         m0 = e.mins;
 829         m1 = e.maxs;
 830         e.mins = '0 0 0';
 831         e.maxs = '0 0 0';
 832         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m0_x);
 833         e.mins_x = m0_x;
 834         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m1_x);
 835         e.maxs_x = m1_x;
 836         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m0_y);
 837         e.mins_y = m0_y;
 838         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m1_y);
 839         e.maxs_y = m1_y;
 840         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m0_z);
 841         e.mins_z = m0_z;
 842         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m1_z);
 843         e.maxs_z = m1_z;
 844         setorigin(e, e.origin);
 845
 846         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 847         if (trace_startsolid)
 848         {
 849                 setorigin(e, o);
 850                 return false;
 851         }
 852
 853         return true;
 854 }