qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <common/t_items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         FIXED_MAKE_VECTORS_NEW(my_ang, forward, right, up);
  75         e.warpzone_forward = forward;
  76         FIXED_MAKE_VECTORS(other_ang, forward, right, up);
  77         e.warpzone_targetforward = forward;
  78         setcamera_transform(e, WarpZone_camera_transform);
  79 }
  80
  81 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  82 {
  83         // a fixed camera view
  84         if(this.warpzone_fadestart)
  85                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  86                         return org;
  87                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  88                         // unneeded on client, on server this helps a lot
  89         trace_endpos = this.warpzone_origin;
  90         makevectors(this.warpzone_angles);
  91         return this.warpzone_origin;
  92 }
  93
  94 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  95 {
  96         e.warpzone_origin = my_org;
  97         e.warpzone_angles = my_ang;
  98         setcamera_transform(e, WarpZone_Camera_camera_transform);
  99 }
 100
 101 .entity enemy;
 102
 103 vector WarpZoneLib_BoxTouchesBrush_mins;
 104 vector WarpZoneLib_BoxTouchesBrush_maxs;
 105 entity WarpZoneLib_BoxTouchesBrush_ent;
 106 entity WarpZoneLib_BoxTouchesBrush_ignore;
 107 float WarpZoneLib_BoxTouchesBrush_Recurse()
 108 {
 109         float s;
 110         entity se;
 111         float f;
 112
 113         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 114 #ifdef CSQC
 115         if (trace_networkentity)
 116         {
 117                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 118                 // we cannot continue, as a player blocks us...
 119                 // so, abort
 120                 return 0;
 121         }
 122 #endif
 123         if (!trace_ent)
 124                 return 0;
 125         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 126                 return 1;
 127
 128         se = trace_ent;
 129         s = se.solid;
 130         se.solid = SOLID_NOT;
 131         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 132         se.solid = s;
 133
 134         return f;
 135 }
 136
 137 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 138 {
 139     float f, s;
 140
 141     if(!e.modelindex || e.warpzone_isboxy)
 142         return 1;
 143
 144     s = e.solid;
 145     e.solid = SOLID_BSP;
 146     WarpZoneLib_BoxTouchesBrush_mins = mi;
 147     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 148     WarpZoneLib_BoxTouchesBrush_ent = e;
 149     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 150     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 151     e.solid = s;
 152
 153     return f;
 154 }
 155
 156 entity WarpZone_Find(vector mi, vector ma)
 157 {
 158         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 159         if(!warpzone_warpzones_exist)
 160                 return NULL;
 161         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 162         {
 163                 return it;
 164         });
 165         return NULL;
 166 }
 167
 168 void WarpZone_MakeAllSolid()
 169 {
 170         if(!warpzone_warpzones_exist)
 171                 return;
 172         IL_EACH(g_warpzones, true,
 173         {
 174                 it.solid = SOLID_BSP;
 175         });
 176 }
 177
 178 void WarpZone_MakeAllOther()
 179 {
 180         if(!warpzone_warpzones_exist)
 181                 return;
 182         IL_EACH(g_warpzones, true,
 183         {
 184                 it.solid = SOLID_TRIGGER;
 185         });
 186 }
 187
 188 void WarpZone_Trace_InitTransform()
 189 {
 190         if(!WarpZone_trace_transform)
 191         {
 192                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 193         }
 194         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 195 }
 196 void WarpZone_Trace_AddTransform(entity wz)
 197 {
 198         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 199 }
 200
 201 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 202 {
 203         float nomonsters_adjusted;
 204         float frac, sol, i;
 205         float contentshack;
 206         vector o0, e0;
 207         entity wz;
 208
 209         WarpZone_trace_forent = forent;
 210         WarpZone_trace_firstzone = NULL;
 211         WarpZone_trace_lastzone = NULL;
 212         WarpZone_Trace_InitTransform();
 213         if(!warpzone_warpzones_exist)
 214         {
 215                 if(nomonsters == MOVE_NOTHING)
 216                 {
 217                         trace_endpos = end;
 218                         trace_fraction = 1;
 219                         if(cb)
 220                                 cb(org, trace_endpos, end);
 221                         return;
 222                 }
 223                 else
 224                 {
 225                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 226                         if(cb)
 227                                 cb(org, trace_endpos, end);
 228                         return;
 229                 }
 230         }
 231
 232         o0 = org;
 233         e0 = end;
 234
 235         switch(nomonsters)
 236         {
 237                 case MOVE_WORLDONLY:
 238                 case MOVE_NOTHING:
 239                         nomonsters_adjusted = MOVE_NOMONSTERS;
 240                         break;
 241                 default:
 242                         nomonsters_adjusted = nomonsters;
 243                         break;
 244         }
 245         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 246                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 247
 248         // if starting in warpzone, first transform
 249         wz = WarpZone_Find(org + mi, org + ma);
 250         if(wz)
 251         {
 252                 WarpZone_trace_firstzone = wz;
 253                 WarpZone_trace_lastzone = wz;
 254                 if(zone && wz != zone)
 255                 {
 256                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 257                         sol = 1;
 258                         trace_fraction = 0;
 259                         trace_endpos = org;
 260                         goto fail;
 261                 }
 262                 WarpZone_Trace_AddTransform(wz);
 263                 org = WarpZone_TransformOrigin(wz, org);
 264                 end = WarpZone_TransformOrigin(wz, end);
 265         }
 266         WarpZone_MakeAllSolid();
 267         sol = -1;
 268         frac = 0;
 269         i = 16;
 270         for (;;)
 271         {
 272                 if(--i < 1)
 273                 {
 274                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 275                         trace_ent = NULL;
 276                         break;
 277                 }
 278                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 279                 if(cb)
 280                         cb(org, trace_endpos, end);
 281                 if(sol < 0)
 282                         sol = trace_startsolid;
 283
 284                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 285                 if(trace_fraction >= 1)
 286                         break;
 287                 if(trace_ent.classname != "trigger_warpzone")
 288                 {
 289                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 290                         {
 291                                 // continue the trace, ignoring this hit (we only care for warpzones)
 292                                 org = trace_endpos + normalize(end - org);
 293                                 continue;
 294                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 295                                 // otherwise, players could block entrances that way
 296                         }
 297                         break;
 298                 }
 299                 /*if(trace_ent == wz)
 300                 {
 301                         // FIXME can this check be removed? Do we really need it?
 302                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 303                         trace_ent = NULL;
 304                         break;
 305                 }*/
 306                 wz = trace_ent;
 307                 if(!WarpZone_trace_firstzone)
 308                         WarpZone_trace_firstzone = wz;
 309                 WarpZone_trace_lastzone = wz;
 310                 if(zone && wz != zone)
 311                         break;
 312                 WarpZone_Trace_AddTransform(wz);
 313                 // we hit a warpzone... so, let's perform the trace after the warp again
 314                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 315                 end = WarpZone_TransformOrigin(wz, end);
 316
 317                 // we got warped, so let's step back a bit
 318                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 319                 org = trace_endpos;
 320         }
 321         WarpZone_MakeAllOther();
 322 LABEL(fail)
 323         if(contentshack)
 324                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 325         trace_startsolid = sol;
 326 }
 327
 328 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 329 {
 330         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 331 }
 332
 333 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 334 {
 335         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 336 }
 337
 338 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 339 {
 340         float g, dt, i;
 341         vector vf, vr, vu, v0, o0;
 342         entity wz;
 343
 344         o0 = e.origin;
 345         v0 = e.velocity;
 346         g = cvar("sv_gravity") * e.gravity;
 347
 348         WarpZone_trace_forent = forent;
 349         WarpZone_trace_firstzone = NULL;
 350         WarpZone_trace_lastzone = NULL;
 351         WarpZone_Trace_InitTransform();
 352         WarpZone_tracetoss_time = 0;
 353         if(!warpzone_warpzones_exist)
 354         {
 355                 tracetoss(e, WarpZone_trace_forent);
 356                 if(cb)
 357                         cb(e.origin, trace_endpos, trace_endpos);
 358                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 359                 WarpZone_tracetoss_time += dt;
 360                 e.velocity_z -= dt * g;
 361                 WarpZone_tracetoss_velocity = e.velocity;
 362                 e.velocity = v0;
 363                 return;
 364         }
 365
 366         vf = v_forward;
 367         vr = v_right;
 368         vu = v_up;
 369
 370         // if starting in warpzone, first transform
 371         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 372         if(wz)
 373         {
 374                 WarpZone_trace_firstzone = wz;
 375                 WarpZone_trace_lastzone = wz;
 376                 if(zone && wz != zone)
 377                 {
 378                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 379
 380                         WarpZone_tracetoss_time = 0;
 381                         trace_endpos = o0;
 382                         goto fail;
 383                 }
 384                 WarpZone_Trace_AddTransform(wz);
 385                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 386                 setorigin(e, org);
 387                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 388         }
 389         WarpZone_MakeAllSolid();
 390         i = 16;
 391         for (;;)
 392         {
 393                 if(--i < 1)
 394                 {
 395                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 396                         trace_ent = NULL;
 397                         break;
 398                 }
 399                 tracetoss(e, WarpZone_trace_forent);
 400                 if(cb)
 401                         cb(e.origin, trace_endpos, trace_endpos);
 402                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 403                 WarpZone_tracetoss_time += dt;
 404                 e.origin = trace_endpos;
 405                 e.velocity_z -= dt * g;
 406                 if(trace_fraction >= 1)
 407                         break;
 408                 if(trace_ent.classname != "trigger_warpzone")
 409                         break;
 410                 if(trace_ent == wz)
 411                 {
 412                         // FIXME can this check be removed? Do we really need it?
 413                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 414                         trace_ent = NULL;
 415                         break;
 416                 }
 417                 wz = trace_ent;
 418                 if(!WarpZone_trace_firstzone)
 419                         WarpZone_trace_firstzone = wz;
 420                 WarpZone_trace_lastzone = wz;
 421                 if(zone && wz != zone)
 422                         break;
 423                 WarpZone_Trace_AddTransform(wz);
 424                 // we hit a warpzone... so, let's perform the trace after the warp again
 425                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 426                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 427
 428                 // we got warped, so let's step back a bit
 429                 e.velocity = -e.velocity;
 430                 tracetoss(e, WarpZone_trace_forent);
 431                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 432                 WarpZone_tracetoss_time -= dt;
 433                 e.origin = trace_endpos;
 434                 e.velocity = -e.velocity;
 435         }
 436         WarpZone_MakeAllOther();
 437 LABEL(fail)
 438         WarpZone_tracetoss_velocity = e.velocity;
 439         v_forward = vf;
 440         v_right = vr;
 441         v_up = vu;
 442         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 443         e.velocity = v0;
 444         e.origin = o0;
 445 }
 446
 447 void WarpZone_TraceToss(entity e, entity forent)
 448 {
 449         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 450 }
 451
 452 entity WarpZone_TrailParticles_trace_callback_own;
 453 float WarpZone_TrailParticles_trace_callback_eff;
 454 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 455 {
 456         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 457 }
 458
 459 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 460 {
 461         WarpZone_TrailParticles_trace_callback_own = own;
 462         WarpZone_TrailParticles_trace_callback_eff = eff;
 463         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 464 }
 465
 466 #ifdef CSQC
 467 float WarpZone_TrailParticles_trace_callback_f;
 468 float WarpZone_TrailParticles_trace_callback_flags;
 469 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 470 {
 471         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 472 }
 473
 474 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 475 {
 476         WarpZone_TrailParticles_trace_callback_own = own;
 477         WarpZone_TrailParticles_trace_callback_eff = eff;
 478         WarpZone_TrailParticles_trace_callback_f = f;
 479         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 480         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 481 }
 482 #endif
 483
 484 float WarpZone_PlaneDist(entity wz, vector v)
 485 {
 486         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 487 }
 488
 489 float WarpZone_TargetPlaneDist(entity wz, vector v)
 490 {
 491         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 492 }
 493
 494 vector WarpZone_TransformOrigin(entity wz, vector v)
 495 {
 496         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 497 }
 498
 499 vector WarpZone_TransformVelocity(entity wz, vector v)
 500 {
 501         return AnglesTransform_Apply(wz.warpzone_transform, v);
 502 }
 503
 504 vector WarpZone_TransformAngles(entity wz, vector v)
 505 {
 506         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 507 }
 508
 509 vector WarpZone_TransformVAngles(entity wz, vector ang)
 510 {
 511 #ifdef KEEP_ROLL
 512         float roll;
 513         roll = ang.z;
 514         ang.z = 0;
 515 #endif
 516
 517         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 518
 519 #ifdef KEEP_ROLL
 520         ang = AnglesTransform_Normalize(ang, true);
 521         ang = AnglesTransform_CancelRoll(ang);
 522         ang.z = roll;
 523 #else
 524         ang = AnglesTransform_Normalize(ang, false);
 525 #endif
 526
 527         return ang;
 528 }
 529
 530 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 531 {
 532         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 533 }
 534
 535 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 536 {
 537         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 538 }
 539
 540 vector WarpZone_UnTransformAngles(entity wz, vector v)
 541 {
 542         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 543 }
 544
 545 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 546 {
 547         float roll;
 548
 549         roll = ang.z;
 550         ang.z = 0;
 551
 552         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 553         ang = AnglesTransform_Normalize(ang, true);
 554         ang = AnglesTransform_CancelRoll(ang);
 555
 556         ang.z = roll;
 557         return ang;
 558 }
 559
 560 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 561 {
 562         vector nearest;
 563         nearest.x = bound(mi.x, org.x, ma.x);
 564         nearest.y = bound(mi.y, org.y, ma.y);
 565         nearest.z = bound(mi.z, org.z, ma.z);
 566         return nearest;
 567 }
 568
 569 bool WarpZoneLib_BadEntity(entity e)
 570 {
 571         if (is_pure(e)) return true;
 572         string s = e.classname;
 573
 574         //if (s == "net_linked") return true; // actually some real entities are linked without classname, fail
 575         if (s == "") return true;
 576
 577         if (startsWith(s, "target_")) return true;
 578
 579         if (startsWith(s, "info_")) return true;
 580
 581         return false;
 582 }
 583
 584 .float WarpZone_findradius_hit;
 585 .entity WarpZone_findradius_next;
 586 void WarpZone_FindRadius_Recurse(
 587     /** blast origin of current search */
 588     vector org,
 589     float rad,
 590     /** original blast origin */
 591     vector org0,
 592     /** how to untransform (victim to blast system) */
 593     vector transform,
 594     vector shift,
 595     bool needlineofsight)
 596 {
 597         if (rad <= 0) return;
 598         entity wz = NULL;
 599         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 600                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 601                 if (needlineofsight)
 602                 {
 603                         traceline(org, p, MOVE_NOMONSTERS, it);
 604                         if (trace_fraction < 1) continue;
 605                 }
 606                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 607                 {
 608                         it.WarpZone_findradius_nearest = p;
 609                         it.WarpZone_findradius_dist = org0 - p;
 610                         it.WarpZone_findradius_findorigin = org;
 611                         it.WarpZone_findradius_findradius = rad;
 612                         if (it.classname == "warpzone_refsys")
 613                         {
 614                                 // ignore, especially: do not overwrite the refsys parameters
 615                         }
 616                         else if (it.classname == "trigger_warpzone")
 617                         {
 618                                 it.WarpZone_findradius_next = wz;
 619                                 wz = it;
 620                                 it.WarpZone_findradius_hit = 1;
 621                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 622                                 it.enemy.WarpZone_findradius_hit = 1;
 623                         }
 624                         else
 625                         {
 626                                 it.warpzone_transform = transform;
 627                                 it.warpzone_shift = shift;
 628                                 it.WarpZone_findradius_hit = 1;
 629                         }
 630                 }
 631     });
 632         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 633         {
 634                 if (WarpZoneLib_BadEntity(e)) continue;
 635
 636                 vector org0_new = WarpZone_TransformOrigin(e, org);
 637                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 638                 vector org_new = trace_endpos;
 639
 640                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 641                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 642                 WarpZone_FindRadius_Recurse(
 643                         org_new,
 644                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 645                         org0_new,
 646                         transform_new, shift_new,
 647                         needlineofsight);
 648                 e.WarpZone_findradius_hit = 0;
 649                 e.enemy.WarpZone_findradius_hit = 0;
 650         }
 651 }
 652 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 653 {
 654     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 655     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 656         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 657         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 658         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 659         return list_first;
 660 }
 661
 662 .entity WarpZone_refsys;
 663 void WarpZone_RefSys_GC(entity this)
 664 {
 665         // garbage collect unused reference systems
 666         this.nextthink = time + 1;
 667         if(this.owner.WarpZone_refsys != this)
 668                 delete(this);
 669 }
 670 void WarpZone_RefSys_CheckCreate(entity me)
 671 {
 672         if(me.WarpZone_refsys.owner != me)
 673         {
 674                 me.WarpZone_refsys = new(warpzone_refsys);
 675                 me.WarpZone_refsys.owner = me;
 676                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 677                 me.WarpZone_refsys.nextthink = time + 1;
 678                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 679         }
 680 }
 681 void WarpZone_RefSys_Clear(entity me)
 682 {
 683         if(me.WarpZone_refsys)
 684         {
 685                 delete(me.WarpZone_refsys);
 686                 me.WarpZone_refsys = NULL;
 687         }
 688 }
 689 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 690 {
 691         if(t != '0 0 0' || s != '0 0 0')
 692         {
 693                 WarpZone_RefSys_CheckCreate(me);
 694                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 695         }
 696 }
 697 void WarpZone_RefSys_Add(entity me, entity wz)
 698 {
 699         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 700 }
 701 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 702 {
 703         if(t != '0 0 0' || s != '0 0 0')
 704         {
 705                 WarpZone_RefSys_CheckCreate(me);
 706                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 707         }
 708 }
 709 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 710 {
 711         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 712 }
 713 .vector WarpZone_refsys_incremental_shift;
 714 .vector WarpZone_refsys_incremental_transform;
 715 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 716 {
 717         //vector t, s;
 718         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 719         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 720                 return;
 721         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 722         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 723         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 724         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 725 }
 726 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 727 {
 728         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 729         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 730 }
 731 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 732 {
 733         if(from.WarpZone_refsys)
 734                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 735         if(to.WarpZone_refsys)
 736                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 737         return org;
 738 }
 739 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 740 {
 741         if(from.WarpZone_refsys)
 742                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 743         if(to.WarpZone_refsys)
 744                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 745         return vel;
 746 }
 747 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 748 {
 749         if(from.WarpZone_refsys)
 750                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 751         if(to.WarpZone_refsys)
 752                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 753         return ang;
 754 }
 755 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 756 {
 757         if(from.WarpZone_refsys)
 758                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 759         if(to.WarpZone_refsys)
 760                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 761         return ang;
 762 }
 763 void WarpZone_RefSys_Copy(entity me, entity from)
 764 {
 765         if(from.WarpZone_refsys)
 766         {
 767                 WarpZone_RefSys_CheckCreate(me);
 768                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 769                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 770         }
 771         else
 772                 WarpZone_RefSys_Clear(me);
 773 }
 774 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 775 {
 776         entity e;
 777         e = spawn();
 778         WarpZone_RefSys_Copy(e, me);
 779         return e;
 780 }
 781
 782 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
 783 {
 784         return !WarpZoneLib_BoxTouchesBrush(toucher.absmin, toucher.absmax, this, toucher);
 785 }
 786
 787
 788 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 789 {
 790         float eps = 0.0625;
 791         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 792         if (trace_startsolid)
 793                 return;
 794         if (trace_fraction < 1)
 795         {
 796                 // hit something
 797                 // adjust origin in the other direction...
 798                 setorigin(e, e.origin - by * (1 - trace_fraction));
 799         }
 800 }
 801
 802 bool WarpZoneLib_MoveOutOfSolid(entity e)
 803 {
 804         vector o = e.origin;
 805         traceline(o, o, MOVE_WORLDONLY, e);
 806         if (trace_startsolid)
 807                 return false;
 808
 809         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 810         if (!trace_startsolid)
 811                 return true;
 812
 813         vector m0 = e.mins;
 814         vector m1 = e.maxs;
 815         e.mins = '0 0 0';
 816         e.maxs = '0 0 0';
 817         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
 818         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
 819         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
 820         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
 821         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
 822         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
 823         setorigin(e, e.origin);
 824
 825         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 826         if (trace_startsolid)
 827         {
 828                 setorigin(e, o);
 829                 return false;
 830         }
 831
 832         return true;
 833 }