qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <common/t_items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         FIXED_MAKE_VECTORS_NEW(my_ang, forward, right, up);
  75         e.warpzone_forward = forward;
  76         FIXED_MAKE_VECTORS(other_ang, forward, right, up);
  77         e.warpzone_targetforward = forward;
  78         setcamera_transform(e, WarpZone_camera_transform);
  79 }
  80
  81 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  82 {
  83         // a fixed camera view
  84         if(this.warpzone_fadestart)
  85                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  86                         return org;
  87                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  88                         // unneeded on client, on server this helps a lot
  89         trace_endpos = this.warpzone_origin;
  90         makevectors(this.warpzone_angles);
  91         return this.warpzone_origin;
  92 }
  93
  94 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  95 {
  96         e.warpzone_origin = my_org;
  97         e.warpzone_angles = my_ang;
  98         setcamera_transform(e, WarpZone_Camera_camera_transform);
  99 }
 100
 101 .entity enemy;
 102
 103 vector WarpZoneLib_BoxTouchesBrush_mins;
 104 vector WarpZoneLib_BoxTouchesBrush_maxs;
 105 entity WarpZoneLib_BoxTouchesBrush_ent;
 106 entity WarpZoneLib_BoxTouchesBrush_ignore;
 107 float WarpZoneLib_BoxTouchesBrush_Recurse()
 108 {
 109         float s;
 110         entity se;
 111         float f;
 112
 113         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 114 #ifdef CSQC
 115         if (trace_networkentity)
 116         {
 117                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 118                 // we cannot continue, as a player blocks us...
 119                 // so, abort
 120                 return 0;
 121         }
 122 #endif
 123         if (!trace_ent)
 124                 return 0;
 125         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 126                 return 1;
 127
 128         se = trace_ent;
 129         s = se.solid;
 130         se.solid = SOLID_NOT;
 131         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 132         se.solid = s;
 133
 134         return f;
 135 }
 136
 137 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 138 {
 139     float f, s;
 140
 141     if(!e.modelindex || e.warpzone_isboxy)
 142         return 1;
 143
 144     s = e.solid;
 145     e.solid = SOLID_BSP;
 146     WarpZoneLib_BoxTouchesBrush_mins = mi;
 147     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 148     WarpZoneLib_BoxTouchesBrush_ent = e;
 149     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 150     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 151     e.solid = s;
 152
 153     return f;
 154 }
 155
 156 entity WarpZone_Find(vector mi, vector ma)
 157 {
 158         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 159         if(!warpzone_warpzones_exist)
 160                 return NULL;
 161         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 162         {
 163                 return it;
 164         });
 165         return NULL;
 166 }
 167
 168 void WarpZone_MakeAllSolid()
 169 {
 170         if(!warpzone_warpzones_exist)
 171                 return;
 172         IL_EACH(g_warpzones, true,
 173         {
 174                 it.solid = SOLID_BSP;
 175         });
 176 }
 177
 178 void WarpZone_MakeAllOther()
 179 {
 180         if(!warpzone_warpzones_exist)
 181                 return;
 182         IL_EACH(g_warpzones, true,
 183         {
 184                 it.solid = SOLID_TRIGGER;
 185         });
 186 }
 187
 188 void WarpZone_Trace_InitTransform()
 189 {
 190         if(!WarpZone_trace_transform)
 191         {
 192                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 193         }
 194         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 195 }
 196 void WarpZone_Trace_AddTransform(entity wz)
 197 {
 198         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 199 }
 200
 201 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 202 {
 203         float nomonsters_adjusted;
 204         float frac, sol, i;
 205         float contentshack;
 206         entity wz;
 207
 208         WarpZone_trace_forent = forent;
 209         WarpZone_trace_firstzone = NULL;
 210         WarpZone_trace_lastzone = NULL;
 211         WarpZone_Trace_InitTransform();
 212         if(!warpzone_warpzones_exist)
 213         {
 214                 if(nomonsters == MOVE_NOTHING)
 215                 {
 216                         trace_endpos = end;
 217                         trace_fraction = 1;
 218                         if(cb)
 219                                 cb(org, trace_endpos, end);
 220                         return;
 221                 }
 222                 else
 223                 {
 224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 225                         if(cb)
 226                                 cb(org, trace_endpos, end);
 227                         return;
 228                 }
 229         }
 230
 231         switch(nomonsters)
 232         {
 233                 case MOVE_WORLDONLY:
 234                 case MOVE_NOTHING:
 235                         nomonsters_adjusted = MOVE_NOMONSTERS;
 236                         break;
 237                 default:
 238                         nomonsters_adjusted = nomonsters;
 239                         break;
 240         }
 241         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 242                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 243
 244         // if starting in warpzone, first transform
 245         wz = WarpZone_Find(org + mi, org + ma);
 246         if(wz)
 247         {
 248                 WarpZone_trace_firstzone = wz;
 249                 WarpZone_trace_lastzone = wz;
 250                 if(zone && wz != zone)
 251                 {
 252                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 253                         sol = 1;
 254                         trace_fraction = 0;
 255                         trace_endpos = org;
 256                         goto fail;
 257                 }
 258                 WarpZone_Trace_AddTransform(wz);
 259                 org = WarpZone_TransformOrigin(wz, org);
 260                 end = WarpZone_TransformOrigin(wz, end);
 261         }
 262         WarpZone_MakeAllSolid();
 263         sol = -1;
 264         frac = 0;
 265         i = 16;
 266         for (;;)
 267         {
 268                 if(--i < 1)
 269                 {
 270                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 271                         trace_ent = NULL;
 272                         break;
 273                 }
 274                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 275                 if(cb)
 276                         cb(org, trace_endpos, end);
 277                 if(sol < 0)
 278                         sol = trace_startsolid;
 279
 280                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 281                 if(trace_fraction >= 1)
 282                         break;
 283                 if(trace_ent.classname != "trigger_warpzone")
 284                 {
 285                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 286                         {
 287                                 // continue the trace, ignoring this hit (we only care for warpzones)
 288                                 org = trace_endpos + normalize(end - org);
 289                                 continue;
 290                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 291                                 // otherwise, players could block entrances that way
 292                         }
 293                         break;
 294                 }
 295                 /*if(trace_ent == wz)
 296                 {
 297                         // FIXME can this check be removed? Do we really need it?
 298                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 299                         trace_ent = NULL;
 300                         break;
 301                 }*/
 302                 wz = trace_ent;
 303                 if(!WarpZone_trace_firstzone)
 304                         WarpZone_trace_firstzone = wz;
 305                 WarpZone_trace_lastzone = wz;
 306                 if(zone && wz != zone)
 307                         break;
 308                 WarpZone_Trace_AddTransform(wz);
 309                 // we hit a warpzone... so, let's perform the trace after the warp again
 310                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 311                 end = WarpZone_TransformOrigin(wz, end);
 312
 313                 // we got warped, so let's step back a bit
 314                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 315                 org = trace_endpos;
 316         }
 317         WarpZone_MakeAllOther();
 318 LABEL(fail)
 319         if(contentshack)
 320                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 321         trace_startsolid = sol;
 322 }
 323
 324 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 325 {
 326         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 327 }
 328
 329 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 330 {
 331         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 332 }
 333
 334 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 335 {
 336         float g, dt, i;
 337         vector vf, vr, vu, v0, o0;
 338         entity wz;
 339
 340         o0 = e.origin;
 341         v0 = e.velocity;
 342         g = cvar("sv_gravity") * e.gravity;
 343
 344         WarpZone_trace_forent = forent;
 345         WarpZone_trace_firstzone = NULL;
 346         WarpZone_trace_lastzone = NULL;
 347         WarpZone_Trace_InitTransform();
 348         WarpZone_tracetoss_time = 0;
 349         if(!warpzone_warpzones_exist)
 350         {
 351                 tracetoss(e, WarpZone_trace_forent);
 352                 if(cb)
 353                         cb(e.origin, trace_endpos, trace_endpos);
 354                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 355                 WarpZone_tracetoss_time += dt;
 356                 e.velocity_z -= dt * g;
 357                 WarpZone_tracetoss_velocity = e.velocity;
 358                 e.velocity = v0;
 359                 return;
 360         }
 361
 362         vf = v_forward;
 363         vr = v_right;
 364         vu = v_up;
 365
 366         // if starting in warpzone, first transform
 367         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 368         if(wz)
 369         {
 370                 WarpZone_trace_firstzone = wz;
 371                 WarpZone_trace_lastzone = wz;
 372                 if(zone && wz != zone)
 373                 {
 374                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 375
 376                         WarpZone_tracetoss_time = 0;
 377                         trace_endpos = o0;
 378                         goto fail;
 379                 }
 380                 WarpZone_Trace_AddTransform(wz);
 381                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 382                 setorigin(e, org);
 383                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 384         }
 385         WarpZone_MakeAllSolid();
 386         i = 16;
 387         for (;;)
 388         {
 389                 if(--i < 1)
 390                 {
 391                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 392                         trace_ent = NULL;
 393                         break;
 394                 }
 395                 tracetoss(e, WarpZone_trace_forent);
 396                 if(cb)
 397                         cb(e.origin, trace_endpos, trace_endpos);
 398                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 399                 WarpZone_tracetoss_time += dt;
 400                 e.origin = trace_endpos;
 401                 e.velocity_z -= dt * g;
 402                 if(trace_fraction >= 1)
 403                         break;
 404                 if(trace_ent.classname != "trigger_warpzone")
 405                         break;
 406                 if(trace_ent == wz)
 407                 {
 408                         // FIXME can this check be removed? Do we really need it?
 409                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 410                         trace_ent = NULL;
 411                         break;
 412                 }
 413                 wz = trace_ent;
 414                 if(!WarpZone_trace_firstzone)
 415                         WarpZone_trace_firstzone = wz;
 416                 WarpZone_trace_lastzone = wz;
 417                 if(zone && wz != zone)
 418                         break;
 419                 WarpZone_Trace_AddTransform(wz);
 420                 // we hit a warpzone... so, let's perform the trace after the warp again
 421                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 422                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 423
 424                 // we got warped, so let's step back a bit
 425                 e.velocity = -e.velocity;
 426                 tracetoss(e, WarpZone_trace_forent);
 427                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 428                 WarpZone_tracetoss_time -= dt;
 429                 e.origin = trace_endpos;
 430                 e.velocity = -e.velocity;
 431         }
 432         WarpZone_MakeAllOther();
 433 LABEL(fail)
 434         WarpZone_tracetoss_velocity = e.velocity;
 435         v_forward = vf;
 436         v_right = vr;
 437         v_up = vu;
 438         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 439         e.velocity = v0;
 440         e.origin = o0;
 441 }
 442
 443 void WarpZone_TraceToss(entity e, entity forent)
 444 {
 445         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 446 }
 447
 448 entity WarpZone_TrailParticles_trace_callback_own;
 449 float WarpZone_TrailParticles_trace_callback_eff;
 450 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 451 {
 452         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 453 }
 454
 455 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 456 {
 457         WarpZone_TrailParticles_trace_callback_own = own;
 458         WarpZone_TrailParticles_trace_callback_eff = eff;
 459         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 460 }
 461
 462 #ifdef CSQC
 463 float WarpZone_TrailParticles_trace_callback_f;
 464 float WarpZone_TrailParticles_trace_callback_flags;
 465 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 466 {
 467         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 468 }
 469
 470 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 471 {
 472         WarpZone_TrailParticles_trace_callback_own = own;
 473         WarpZone_TrailParticles_trace_callback_eff = eff;
 474         WarpZone_TrailParticles_trace_callback_f = f;
 475         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 476         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 477 }
 478 #endif
 479
 480 float WarpZone_PlaneDist(entity wz, vector v)
 481 {
 482         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 483 }
 484
 485 float WarpZone_TargetPlaneDist(entity wz, vector v)
 486 {
 487         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 488 }
 489
 490 vector WarpZone_TransformOrigin(entity wz, vector v)
 491 {
 492         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 493 }
 494
 495 vector WarpZone_TransformVelocity(entity wz, vector v)
 496 {
 497         return AnglesTransform_Apply(wz.warpzone_transform, v);
 498 }
 499
 500 vector WarpZone_TransformAngles(entity wz, vector v)
 501 {
 502         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 503 }
 504
 505 vector WarpZone_TransformVAngles(entity wz, vector ang)
 506 {
 507 #ifdef KEEP_ROLL
 508         float roll;
 509         roll = ang.z;
 510         ang.z = 0;
 511 #endif
 512
 513         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 514
 515 #ifdef KEEP_ROLL
 516         ang = AnglesTransform_Normalize(ang, true);
 517         ang = AnglesTransform_CancelRoll(ang);
 518         ang.z = roll;
 519 #else
 520         ang = AnglesTransform_Normalize(ang, false);
 521 #endif
 522
 523         return ang;
 524 }
 525
 526 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 527 {
 528         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 529 }
 530
 531 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 532 {
 533         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 534 }
 535
 536 vector WarpZone_UnTransformAngles(entity wz, vector v)
 537 {
 538         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 539 }
 540
 541 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 542 {
 543         float roll;
 544
 545         roll = ang.z;
 546         ang.z = 0;
 547
 548         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 549         ang = AnglesTransform_Normalize(ang, true);
 550         ang = AnglesTransform_CancelRoll(ang);
 551
 552         ang.z = roll;
 553         return ang;
 554 }
 555
 556 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 557 {
 558         vector nearest;
 559         nearest.x = bound(mi.x, org.x, ma.x);
 560         nearest.y = bound(mi.y, org.y, ma.y);
 561         nearest.z = bound(mi.z, org.z, ma.z);
 562         return nearest;
 563 }
 564
 565 bool WarpZoneLib_BadEntity(entity e)
 566 {
 567         if (is_pure(e)) return true;
 568         string s = e.classname;
 569
 570         //if (s == "net_linked") return true; // actually some real entities are linked without classname, fail
 571         if (s == "") return true;
 572
 573         if (startsWith(s, "target_")) return true;
 574
 575         if (startsWith(s, "info_")) return true;
 576
 577         return false;
 578 }
 579
 580 .float WarpZone_findradius_hit;
 581 .entity WarpZone_findradius_next;
 582 void WarpZone_FindRadius_Recurse(
 583     /** blast origin of current search */
 584     vector org,
 585     float rad,
 586     /** original blast origin */
 587     vector org0,
 588     /** how to untransform (victim to blast system) */
 589     vector transform,
 590     vector shift,
 591     bool needlineofsight)
 592 {
 593         if (rad <= 0) return;
 594         entity wz = NULL;
 595         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 596                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 597                 if (needlineofsight)
 598                 {
 599                         traceline(org, p, MOVE_NOMONSTERS, it);
 600                         if (trace_fraction < 1) continue;
 601                 }
 602                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 603                 {
 604                         it.WarpZone_findradius_nearest = p;
 605                         it.WarpZone_findradius_dist = org0 - p;
 606                         it.WarpZone_findradius_findorigin = org;
 607                         it.WarpZone_findradius_findradius = rad;
 608                         if (it.classname == "warpzone_refsys")
 609                         {
 610                                 // ignore, especially: do not overwrite the refsys parameters
 611                         }
 612                         else if (it.classname == "trigger_warpzone")
 613                         {
 614                                 it.WarpZone_findradius_next = wz;
 615                                 wz = it;
 616                                 it.WarpZone_findradius_hit = 1;
 617                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 618                                 it.enemy.WarpZone_findradius_hit = 1;
 619                         }
 620                         else
 621                         {
 622                                 it.warpzone_transform = transform;
 623                                 it.warpzone_shift = shift;
 624                                 it.WarpZone_findradius_hit = 1;
 625                         }
 626                 }
 627     });
 628         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 629         {
 630                 if (WarpZoneLib_BadEntity(e)) continue;
 631
 632                 vector org0_new = WarpZone_TransformOrigin(e, org);
 633                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 634                 vector org_new = trace_endpos;
 635
 636                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 637                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 638                 WarpZone_FindRadius_Recurse(
 639                         org_new,
 640                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 641                         org0_new,
 642                         transform_new, shift_new,
 643                         needlineofsight);
 644                 e.WarpZone_findradius_hit = 0;
 645                 e.enemy.WarpZone_findradius_hit = 0;
 646         }
 647 }
 648 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 649 {
 650     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 651     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 652         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 653         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 654         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 655         return list_first;
 656 }
 657
 658 .entity WarpZone_refsys;
 659 void WarpZone_RefSys_GC(entity this)
 660 {
 661         // garbage collect unused reference systems
 662         this.nextthink = time + 1;
 663         if(this.owner.WarpZone_refsys != this)
 664                 delete(this);
 665 }
 666 void WarpZone_RefSys_CheckCreate(entity me)
 667 {
 668         if(me.WarpZone_refsys.owner != me)
 669         {
 670                 me.WarpZone_refsys = new(warpzone_refsys);
 671                 me.WarpZone_refsys.owner = me;
 672                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 673                 me.WarpZone_refsys.nextthink = time + 1;
 674                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 675         }
 676 }
 677 void WarpZone_RefSys_Clear(entity me)
 678 {
 679         if(me.WarpZone_refsys)
 680         {
 681                 delete(me.WarpZone_refsys);
 682                 me.WarpZone_refsys = NULL;
 683         }
 684 }
 685 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 686 {
 687         if(t != '0 0 0' || s != '0 0 0')
 688         {
 689                 WarpZone_RefSys_CheckCreate(me);
 690                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 691         }
 692 }
 693 void WarpZone_RefSys_Add(entity me, entity wz)
 694 {
 695         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 696 }
 697 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 698 {
 699         if(t != '0 0 0' || s != '0 0 0')
 700         {
 701                 WarpZone_RefSys_CheckCreate(me);
 702                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 703         }
 704 }
 705 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 706 {
 707         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 708 }
 709 .vector WarpZone_refsys_incremental_shift;
 710 .vector WarpZone_refsys_incremental_transform;
 711 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 712 {
 713         //vector t, s;
 714         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 715         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 716                 return;
 717         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 718         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 719         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 720         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 721 }
 722 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 723 {
 724         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 725         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 726 }
 727 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 728 {
 729         if(from.WarpZone_refsys)
 730                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 731         if(to.WarpZone_refsys)
 732                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 733         return org;
 734 }
 735 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 736 {
 737         if(from.WarpZone_refsys)
 738                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 739         if(to.WarpZone_refsys)
 740                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 741         return vel;
 742 }
 743 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 744 {
 745         if(from.WarpZone_refsys)
 746                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 747         if(to.WarpZone_refsys)
 748                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 749         return ang;
 750 }
 751 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 752 {
 753         if(from.WarpZone_refsys)
 754                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 755         if(to.WarpZone_refsys)
 756                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 757         return ang;
 758 }
 759 void WarpZone_RefSys_Copy(entity me, entity from)
 760 {
 761         if(from.WarpZone_refsys)
 762         {
 763                 WarpZone_RefSys_CheckCreate(me);
 764                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 765                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 766         }
 767         else
 768                 WarpZone_RefSys_Clear(me);
 769 }
 770 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 771 {
 772         entity e;
 773         e = spawn();
 774         WarpZone_RefSys_Copy(e, me);
 775         return e;
 776 }
 777
 778 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
 779 {
 780         return !WarpZoneLib_BoxTouchesBrush(toucher.absmin, toucher.absmax, this, toucher);
 781 }
 782
 783
 784 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 785 {
 786         float eps = 0.0625;
 787         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 788         if (trace_startsolid)
 789                 return;
 790         if (trace_fraction < 1)
 791         {
 792                 // hit something
 793                 // adjust origin in the other direction...
 794                 setorigin(e, e.origin - by * (1 - trace_fraction));
 795         }
 796 }
 797
 798 bool WarpZoneLib_MoveOutOfSolid(entity e)
 799 {
 800         vector o = e.origin;
 801         traceline(o, o, MOVE_WORLDONLY, e);
 802         if (trace_startsolid)
 803                 return false;
 804
 805         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 806         if (!trace_startsolid)
 807                 return true;
 808
 809         vector m0 = e.mins;
 810         vector m1 = e.maxs;
 811         e.mins = '0 0 0';
 812         e.maxs = '0 0 0';
 813         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
 814         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
 815         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
 816         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
 817         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
 818         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
 819         setorigin(e, e.origin);
 820
 821         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 822         if (trace_startsolid)
 823         {
 824                 setorigin(e, o);
 825                 return false;
 826         }
 827
 828         return true;
 829 }