qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include "../../server/t_items.qh"
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include "../../common/weapons/all.qh"
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 .vector(vector, vector) camera_transform;
  41 float autocvar_cl_warpzone_usetrace = 1;
  42 vector WarpZone_camera_transform(vector org, vector ang)
  43 {SELFPARAM();
  44         vector vf, vr, vu;
  45         if(self.warpzone_fadestart)
  46                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  47                         return org;
  48                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  49                         // unneeded on client, on server this helps a lot
  50         vf = v_forward;
  51         vr = v_right;
  52         vu = v_up;
  53         org = WarpZone_TransformOrigin(self, org);
  54         vf = WarpZone_TransformVelocity(self, vf);
  55         vr = WarpZone_TransformVelocity(self, vr);
  56         vu = WarpZone_TransformVelocity(self, vu);
  57         if(autocvar_cl_warpzone_usetrace)
  58                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  59         else
  60                 trace_endpos = self.warpzone_targetorigin;
  61         v_forward = vf;
  62         v_right = vr;
  63         v_up = vu;
  64         return org;
  65 }
  66
  67 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  68 {
  69         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  70         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  71         e.warpzone_origin = my_org;
  72         e.warpzone_targetorigin = other_org;
  73         e.warpzone_angles = my_ang;
  74         e.warpzone_targetangles = other_ang;
  75         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  76         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  77         e.camera_transform = WarpZone_camera_transform;
  78 }
  79
  80 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  81 {SELFPARAM();
  82         // a fixed camera view
  83         if(self.warpzone_fadestart)
  84                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  85                         return org;
  86                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  87                         // unneeded on client, on server this helps a lot
  88         trace_endpos = self.warpzone_origin;
  89         makevectors(self.warpzone_angles);
  90         return self.warpzone_origin;
  91 }
  92
  93 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  94 {
  95         e.warpzone_origin = my_org;
  96         e.warpzone_angles = my_ang;
  97         e.camera_transform = WarpZone_Camera_camera_transform;
  98 }
  99
 100 .entity enemy;
 101
 102 vector WarpZoneLib_BoxTouchesBrush_mins;
 103 vector WarpZoneLib_BoxTouchesBrush_maxs;
 104 entity WarpZoneLib_BoxTouchesBrush_ent;
 105 entity WarpZoneLib_BoxTouchesBrush_ignore;
 106 float WarpZoneLib_BoxTouchesBrush_Recurse()
 107 {
 108         float s;
 109         entity se;
 110         float f;
 111
 112         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 113 #ifdef CSQC
 114         if (trace_networkentity)
 115         {
 116                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
 117                 // we cannot continue, as a player blocks us...
 118                 // so, abort
 119                 return 0;
 120         }
 121 #endif
 122         if (!trace_ent)
 123                 return 0;
 124         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 125                 return 1;
 126
 127         se = trace_ent;
 128         s = se.solid;
 129         se.solid = SOLID_NOT;
 130         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 131         se.solid = s;
 132
 133         return f;
 134 }
 135
 136 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 137 {
 138     float f, s;
 139
 140     if(!e.modelindex || e.warpzone_isboxy)
 141         return 1;
 142
 143     s = e.solid;
 144     e.solid = SOLID_BSP;
 145     WarpZoneLib_BoxTouchesBrush_mins = mi;
 146     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 147     WarpZoneLib_BoxTouchesBrush_ent = e;
 148     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 149     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 150     e.solid = s;
 151
 152     return f;
 153 }
 154
 155 entity WarpZone_Find(vector mi, vector ma)
 156 {
 157         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 158         entity e;
 159         if(!warpzone_warpzones_exist)
 160                 return world;
 161         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 162                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 163                         return e;
 164         return world;
 165 }
 166
 167 void WarpZone_MakeAllSolid()
 168 {
 169         entity e;
 170         if(!warpzone_warpzones_exist)
 171                 return;
 172         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 173                 e.solid = SOLID_BSP;
 174 }
 175
 176 void WarpZone_MakeAllOther()
 177 {
 178         entity e;
 179         if(!warpzone_warpzones_exist)
 180                 return;
 181         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 182                 e.solid = SOLID_TRIGGER;
 183 }
 184
 185 void WarpZone_Trace_InitTransform()
 186 {
 187         if(!WarpZone_trace_transform)
 188         {
 189                 WarpZone_trace_transform = new(warpzone_trace_transform);
 190                 make_pure(WarpZone_trace_transform);
 191         }
 192         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 193 }
 194 void WarpZone_Trace_AddTransform(entity wz)
 195 {
 196         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 197 }
 198
 199 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 200 {
 201         float nomonsters_adjusted;
 202         float frac, sol, i;
 203         float contentshack;
 204         vector o0, e0;
 205         entity wz;
 206         vector vf, vr, vu;
 207
 208         WarpZone_trace_forent = forent;
 209         WarpZone_trace_firstzone = world;
 210         WarpZone_trace_lastzone = world;
 211         WarpZone_Trace_InitTransform();
 212         if(!warpzone_warpzones_exist)
 213         {
 214                 if(nomonsters == MOVE_NOTHING)
 215                 {
 216                         trace_endpos = end;
 217                         trace_fraction = 1;
 218                         if(cb)
 219                                 cb(org, trace_endpos, end);
 220                         return;
 221                 }
 222                 else
 223                 {
 224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 225                         if(cb)
 226                                 cb(org, trace_endpos, end);
 227                         return;
 228                 }
 229         }
 230
 231         vf = v_forward;
 232         vr = v_right;
 233         vu = v_up;
 234         o0 = org;
 235         e0 = end;
 236
 237         switch(nomonsters)
 238         {
 239                 case MOVE_WORLDONLY:
 240                 case MOVE_NOTHING:
 241                         nomonsters_adjusted = MOVE_NOMONSTERS;
 242                         break;
 243                 default:
 244                         nomonsters_adjusted = nomonsters;
 245                         break;
 246         }
 247         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 248                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 249
 250         // if starting in warpzone, first transform
 251         wz = WarpZone_Find(org + mi, org + ma);
 252         if(wz)
 253         {
 254                 WarpZone_trace_firstzone = wz;
 255                 WarpZone_trace_lastzone = wz;
 256                 if(zone && wz != zone)
 257                 {
 258                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 259                         sol = 1;
 260                         trace_fraction = 0;
 261                         trace_endpos = org;
 262                         goto fail;
 263                 }
 264                 WarpZone_Trace_AddTransform(wz);
 265                 org = WarpZone_TransformOrigin(wz, org);
 266                 end = WarpZone_TransformOrigin(wz, end);
 267         }
 268         WarpZone_MakeAllSolid();
 269         sol = -1;
 270         frac = 0;
 271         i = 16;
 272         for (;;)
 273         {
 274                 if(--i < 1)
 275                 {
 276                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
 277                         trace_ent = world;
 278                         break;
 279                 }
 280                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 281                 if(cb)
 282                         cb(org, trace_endpos, end);
 283                 if(sol < 0)
 284                         sol = trace_startsolid;
 285
 286                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 287                 if(trace_fraction >= 1)
 288                         break;
 289                 if(trace_ent.classname != "trigger_warpzone")
 290                 {
 291                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 292                         {
 293                                 // continue the trace, ignoring this hit (we only care for warpzones)
 294                                 org = trace_endpos + normalize(end - org);
 295                                 continue;
 296                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 297                                 // otherwise, players could block entrances that way
 298                         }
 299                         break;
 300                 }
 301                 if(trace_ent == wz)
 302                 {
 303                         // FIXME can this check be removed? Do we really need it?
 304                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
 305                         trace_ent = world;
 306                         break;
 307                 }
 308                 wz = trace_ent;
 309                 if(!WarpZone_trace_firstzone)
 310                         WarpZone_trace_firstzone = wz;
 311                 WarpZone_trace_lastzone = wz;
 312                 if(zone && wz != zone)
 313                         break;
 314                 WarpZone_Trace_AddTransform(wz);
 315                 // we hit a warpzone... so, let's perform the trace after the warp again
 316                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 317                 end = WarpZone_TransformOrigin(wz, end);
 318
 319                 // we got warped, so let's step back a bit
 320                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 321                 org = trace_endpos;
 322         }
 323         WarpZone_MakeAllOther();
 324 :fail
 325         if(contentshack)
 326                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 327         trace_startsolid = sol;
 328         v_forward = vf;
 329         v_right = vr;
 330         v_up = vu;
 331 }
 332
 333 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 334 {
 335         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 336 }
 337
 338 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 339 {
 340         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 341 }
 342
 343 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 344 {
 345         float g, dt, i;
 346         vector vf, vr, vu, v0, o0;
 347         entity wz;
 348
 349         o0 = e.origin;
 350         v0 = e.velocity;
 351         g = cvar("sv_gravity") * e.gravity;
 352
 353         WarpZone_trace_forent = forent;
 354         WarpZone_trace_firstzone = world;
 355         WarpZone_trace_lastzone = world;
 356         WarpZone_Trace_InitTransform();
 357         WarpZone_tracetoss_time = 0;
 358         if(!warpzone_warpzones_exist)
 359         {
 360                 tracetoss(e, WarpZone_trace_forent);
 361                 if(cb)
 362                         cb(e.origin, trace_endpos, trace_endpos);
 363                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 364                 WarpZone_tracetoss_time += dt;
 365                 e.velocity_z -= dt * g;
 366                 WarpZone_tracetoss_velocity = e.velocity;
 367                 e.velocity = v0;
 368                 return;
 369         }
 370
 371         vf = v_forward;
 372         vr = v_right;
 373         vu = v_up;
 374
 375         // if starting in warpzone, first transform
 376         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 377         if(wz)
 378         {
 379                 WarpZone_trace_firstzone = wz;
 380                 WarpZone_trace_lastzone = wz;
 381                 if(zone && wz != zone)
 382                 {
 383                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 384
 385                         WarpZone_tracetoss_time = 0;
 386                         trace_endpos = o0;
 387                         goto fail;
 388                 }
 389                 WarpZone_Trace_AddTransform(wz);
 390                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 391                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 392         }
 393         WarpZone_MakeAllSolid();
 394         i = 16;
 395         for (;;)
 396         {
 397                 if(--i < 1)
 398                 {
 399                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
 400                         trace_ent = world;
 401                         break;
 402                 }
 403                 tracetoss(e, WarpZone_trace_forent);
 404                 if(cb)
 405                         cb(e.origin, trace_endpos, trace_endpos);
 406                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 407                 WarpZone_tracetoss_time += dt;
 408                 e.origin = trace_endpos;
 409                 e.velocity_z -= dt * g;
 410                 if(trace_fraction >= 1)
 411                         break;
 412                 if(trace_ent.classname != "trigger_warpzone")
 413                         break;
 414                 if(trace_ent == wz)
 415                 {
 416                         // FIXME can this check be removed? Do we really need it?
 417                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
 418                         trace_ent = world;
 419                         break;
 420                 }
 421                 wz = trace_ent;
 422                 if(!WarpZone_trace_firstzone)
 423                         WarpZone_trace_firstzone = wz;
 424                 WarpZone_trace_lastzone = wz;
 425                 if(zone && wz != zone)
 426                         break;
 427                 WarpZone_Trace_AddTransform(wz);
 428                 // we hit a warpzone... so, let's perform the trace after the warp again
 429                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 430                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 431
 432                 // we got warped, so let's step back a bit
 433                 e.velocity = -e.velocity;
 434                 tracetoss(e, WarpZone_trace_forent);
 435                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 436                 WarpZone_tracetoss_time -= dt;
 437                 e.origin = trace_endpos;
 438                 e.velocity = -e.velocity;
 439         }
 440         WarpZone_MakeAllOther();
 441 :fail
 442         WarpZone_tracetoss_velocity = e.velocity;
 443         v_forward = vf;
 444         v_right = vr;
 445         v_up = vu;
 446         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 447         e.velocity = v0;
 448         e.origin = o0;
 449 }
 450
 451 void WarpZone_TraceToss(entity e, entity forent)
 452 {
 453         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 454 }
 455
 456 entity WarpZone_TrailParticles_trace_callback_own;
 457 float WarpZone_TrailParticles_trace_callback_eff;
 458 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 459 {
 460         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 461 }
 462
 463 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 464 {
 465         WarpZone_TrailParticles_trace_callback_own = own;
 466         WarpZone_TrailParticles_trace_callback_eff = eff;
 467         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 468 }
 469
 470 #ifdef CSQC
 471 float WarpZone_TrailParticles_trace_callback_f;
 472 float WarpZone_TrailParticles_trace_callback_flags;
 473 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 474 {
 475         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 476 }
 477
 478 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 479 {
 480         WarpZone_TrailParticles_trace_callback_own = own;
 481         WarpZone_TrailParticles_trace_callback_eff = eff;
 482         WarpZone_TrailParticles_trace_callback_f = f;
 483         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 484         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 485 }
 486 #endif
 487
 488 float WarpZone_PlaneDist(entity wz, vector v)
 489 {
 490         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 491 }
 492
 493 float WarpZone_TargetPlaneDist(entity wz, vector v)
 494 {
 495         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 496 }
 497
 498 vector WarpZone_TransformOrigin(entity wz, vector v)
 499 {
 500         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 501 }
 502
 503 vector WarpZone_TransformVelocity(entity wz, vector v)
 504 {
 505         return AnglesTransform_Apply(wz.warpzone_transform, v);
 506 }
 507
 508 vector WarpZone_TransformAngles(entity wz, vector v)
 509 {
 510         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 511 }
 512
 513 vector WarpZone_TransformVAngles(entity wz, vector ang)
 514 {
 515 #ifdef KEEP_ROLL
 516         float roll;
 517         roll = ang.z;
 518         ang.z = 0;
 519 #endif
 520
 521         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 522
 523 #ifdef KEEP_ROLL
 524         ang = AnglesTransform_Normalize(ang, true);
 525         ang = AnglesTransform_CancelRoll(ang);
 526         ang.z = roll;
 527 #else
 528         ang = AnglesTransform_Normalize(ang, false);
 529 #endif
 530
 531         return ang;
 532 }
 533
 534 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 535 {
 536         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 537 }
 538
 539 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 540 {
 541         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 542 }
 543
 544 vector WarpZone_UnTransformAngles(entity wz, vector v)
 545 {
 546         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 547 }
 548
 549 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 550 {
 551         float roll;
 552
 553         roll = ang.z;
 554         ang.z = 0;
 555
 556         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 557         ang = AnglesTransform_Normalize(ang, true);
 558         ang = AnglesTransform_CancelRoll(ang);
 559
 560         ang.z = roll;
 561         return ang;
 562 }
 563
 564 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 565 {
 566         vector nearest;
 567         nearest.x = bound(mi.x, org.x, ma.x);
 568         nearest.y = bound(mi.y, org.y, ma.y);
 569         nearest.z = bound(mi.z, org.z, ma.z);
 570         return nearest;
 571 }
 572
 573 bool WarpZoneLib_BadEntity(entity e)
 574 {
 575         string s = e.classname;
 576         if (is_pure(e)) return true;
 577         switch (s)
 578         {
 579                 case "entcs_sender":
 580                 case "entcs_receiver":
 581                 // case "net_linked": // actually some real entities are linked without classname, fail
 582                 case "":
 583                         return true;
 584         }
 585
 586         if (startsWith(s, "target_")) return true;
 587
 588         if (startsWith(s, "info_")) return true;
 589
 590         return false;
 591 }
 592
 593 .float WarpZone_findradius_hit;
 594 .entity WarpZone_findradius_next;
 595 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 596 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 597 {
 598         vector org_new;
 599         vector org0_new;
 600         vector shift_new, transform_new;
 601         vector p;
 602         entity e, e0;
 603         entity wz;
 604         if(rad <= 0)
 605                 return;
 606         e0 = findradius(org, rad);
 607         wz = world;
 608
 609         for(e = e0; e; e = e.chain)
 610         {
 611                 if(WarpZoneLib_BadEntity(e))
 612                         continue;
 613                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 614                 if(needlineofsight)
 615                 {
 616                         traceline(org, p, MOVE_NOMONSTERS, e);
 617                         if(trace_fraction < 1)
 618                                 continue;
 619                 }
 620                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 621                 {
 622                         e.WarpZone_findradius_nearest = p;
 623                         e.WarpZone_findradius_dist = org0 - p;
 624                         e.WarpZone_findradius_findorigin = org;
 625                         e.WarpZone_findradius_findradius = rad;
 626                         if(e.classname == "warpzone_refsys")
 627                         {
 628                                 // ignore, especially: do not overwrite the refsys parameters
 629                         }
 630                         else if(e.classname == "trigger_warpzone")
 631                         {
 632                                 e.WarpZone_findradius_next = wz;
 633                                 wz = e;
 634                                 e.WarpZone_findradius_hit = 1;
 635                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 636                                 e.enemy.WarpZone_findradius_hit = 1;
 637                         }
 638                         else
 639                         {
 640                                 e.warpzone_transform = transform;
 641                                 e.warpzone_shift = shift;
 642                                 e.WarpZone_findradius_hit = 1;
 643                         }
 644                 }
 645         }
 646         for(e = wz; e; e = e.WarpZone_findradius_next)
 647         {
 648                 if(WarpZoneLib_BadEntity(e))
 649                         continue;
 650
 651                 org0_new = WarpZone_TransformOrigin(e, org);
 652                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 653                 org_new = trace_endpos;
 654
 655                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 656                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 657                 WarpZone_FindRadius_Recurse(
 658                         org_new,
 659                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 660                         org0_new,
 661                         transform_new, shift_new,
 662                         needlineofsight);
 663                 e.WarpZone_findradius_hit = 0;
 664                 e.enemy.WarpZone_findradius_hit = 0;
 665         }
 666 }
 667 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 668 {
 669         entity e0, e;
 670         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 671         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 672         for(e = e0; e; e = e.chain)
 673                 e.WarpZone_findradius_hit = 0;
 674         return e0;
 675 }
 676
 677 .entity WarpZone_refsys;
 678 void WarpZone_RefSys_GC()
 679 {SELFPARAM();
 680         // garbage collect unused reference systems
 681         self.nextthink = time + 1;
 682         if(self.owner.WarpZone_refsys != self)
 683                 remove(self);
 684 }
 685 void WarpZone_RefSys_CheckCreate(entity me)
 686 {
 687         if(me.WarpZone_refsys.owner != me)
 688         {
 689                 me.WarpZone_refsys = new(warpzone_refsys);
 690                 me.WarpZone_refsys.owner = me;
 691                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 692                 me.WarpZone_refsys.nextthink = time + 1;
 693                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 694         }
 695 }
 696 void WarpZone_RefSys_Clear(entity me)
 697 {
 698         if(me.WarpZone_refsys)
 699         {
 700                 remove(me.WarpZone_refsys);
 701                 me.WarpZone_refsys = world;
 702         }
 703 }
 704 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 705 {
 706         if(t != '0 0 0' || s != '0 0 0')
 707         {
 708                 WarpZone_RefSys_CheckCreate(me);
 709                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 710         }
 711 }
 712 void WarpZone_RefSys_Add(entity me, entity wz)
 713 {
 714         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 715 }
 716 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 717 {
 718         if(t != '0 0 0' || s != '0 0 0')
 719         {
 720                 WarpZone_RefSys_CheckCreate(me);
 721                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 722         }
 723 }
 724 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 725 {
 726         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 727 }
 728 .vector WarpZone_refsys_incremental_shift;
 729 .vector WarpZone_refsys_incremental_transform;
 730 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 731 {
 732         //vector t, s;
 733         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 734         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 735                 return;
 736         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 737         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 738         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 739         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 740 }
 741 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 742 {
 743         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 744         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 745 }
 746 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 747 {
 748         if(from.WarpZone_refsys)
 749                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 750         if(to.WarpZone_refsys)
 751                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 752         return org;
 753 }
 754 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 755 {
 756         if(from.WarpZone_refsys)
 757                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 758         if(to.WarpZone_refsys)
 759                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 760         return vel;
 761 }
 762 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 763 {
 764         if(from.WarpZone_refsys)
 765                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 766         if(to.WarpZone_refsys)
 767                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 768         return ang;
 769 }
 770 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 771 {
 772         if(from.WarpZone_refsys)
 773                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 774         if(to.WarpZone_refsys)
 775                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 776         return ang;
 777 }
 778 void WarpZone_RefSys_Copy(entity me, entity from)
 779 {
 780         if(from.WarpZone_refsys)
 781         {
 782                 WarpZone_RefSys_CheckCreate(me);
 783                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 784                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 785         }
 786         else
 787                 WarpZone_RefSys_Clear(me);
 788 }
 789 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 790 {
 791         entity e;
 792         e = spawn();
 793         WarpZone_RefSys_Copy(e, me);
 794         return e;
 795 }
 796
 797 float WarpZoneLib_ExactTrigger_Touch()
 798 {SELFPARAM();
 799         return !WarpZoneLib_BoxTouchesBrush(other.absmin, other.absmax, self, other);
 800 }
 801
 802
 803 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 804 {
 805         float eps = 0.0625;
 806         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 807         if (trace_startsolid)
 808                 return;
 809         if (trace_fraction < 1)
 810         {
 811                 // hit something
 812                 // adjust origin in the other direction...
 813                 setorigin(e,e.origin - by * (1 - trace_fraction));
 814         }
 815 }
 816
 817 float WarpZoneLib_MoveOutOfSolid(entity e)
 818 {
 819         vector o, m0, m1;
 820
 821         o = e.origin;
 822         traceline(o, o, MOVE_WORLDONLY, e);
 823         if (trace_startsolid)
 824                 return false;
 825
 826         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 827         if (!trace_startsolid)
 828                 return true;
 829
 830         m0 = e.mins;
 831         m1 = e.maxs;
 832         e.mins = '0 0 0';
 833         e.maxs = '0 0 0';
 834         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m0_x);
 835         e.mins_x = m0_x;
 836         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m1_x);
 837         e.maxs_x = m1_x;
 838         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m0_y);
 839         e.mins_y = m0_y;
 840         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m1_y);
 841         e.maxs_y = m1_y;
 842         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m0_z);
 843         e.mins_z = m0_z;
 844         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m1_z);
 845         e.maxs_z = m1_z;
 846         setorigin(e, e.origin);
 847
 848         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 849         if (trace_startsolid)
 850         {
 851                 setorigin(e, o);
 852                 return false;
 853         }
 854
 855         return true;
 856 }