qcsrc/menu/gamecommand.qc

   1 void GameCommand_Init()
   2 {
   3         // make gg call menu QC theCommands
   4         localcmd("alias qc_cmd \"menu_cmd $*\"\n");
   5 }
   6
   7 string _dumptree_space;
   8 void _dumptree_open(entity pass, entity me)
   9 {
  10         string s;
  11         s = me.toString(me);
  12         if(s == "")
  13                 s = me.classname;
  14         else
  15                 s = strcat(me.classname, ": ", s);
  16         print(_dumptree_space, etos(me), " (", s, ")");
  17         if(me.firstChild)
  18         {
  19                 print(" {\n");
  20                 _dumptree_space = strcat(_dumptree_space, "  ");
  21         }
  22         else
  23                 print("\n");
  24 }
  25 void _dumptree_close(entity pass, entity me)
  26 {
  27         if(me.firstChild)
  28         {
  29                 _dumptree_space = substring(_dumptree_space, 0, strlen(_dumptree_space) - 2);
  30                 print(_dumptree_space, "}\n");
  31         }
  32 }
  33
  34 float curl_uri_get_pos;
  35 float curl_uri_get_exec[URI_GET_CURL_END - URI_GET_CURL + 1];
  36 string curl_uri_get_cvar[URI_GET_CURL_END - URI_GET_CURL + 1];
  37 void Curl_URI_Get_Callback(float id, float status, string data)
  38 {
  39         float i;
  40         float do_exec;
  41         string do_cvar;
  42         i = id - URI_GET_CURL;
  43         do_exec = curl_uri_get_exec[i];
  44         do_cvar = curl_uri_get_cvar[i];
  45         if(status != 0)
  46         {
  47                 print(sprintf(_("error: status is %d\n"), status));
  48                 return;
  49         }
  50         if(do_exec)
  51                 localcmd(data);
  52         if(do_cvar)
  53                 cvar_set(do_cvar, data);
  54         if(!do_exec && !do_cvar)
  55                 print(data);
  56 }
  57
  58 void GameCommand(string theCommand)
  59 {
  60         float argc;
  61         argc = tokenize_console(theCommand);
  62
  63         if(argv(0) == "help" || argc == 0)
  64         {
  65                 print(_("Usage: menu_cmd command..., where possible commands are:\n"));
  66                 print(_("  sync - reloads all cvars on the current menu page\n"));
  67                 print(_("  directmenu ITEM - select a menu item as main item\n"));
  68                 GameCommand_Generic("help");
  69                 return;
  70         }
  71
  72         if(GameCommand_Generic(theCommand))
  73                 return;
  74
  75         if(argv(0) == "sync")
  76         {
  77                 loadAllCvars(main);
  78                 updateCompression();
  79                 return;
  80         }
  81
  82         if(argv(0) == "directmenu") if(argc == 2)
  83         {
  84                 // switch to a menu item
  85                 if(!isdemo()) // don't allow this command in demos
  86                         m_goto(argv(1));
  87                 return;
  88         }
  89
  90         if(argv(0) == "directpanelhudmenu")
  91         {
  92                 // switch to a menu item
  93                 m_goto(strcat("HUD", argv(1)));
  94                 return;
  95         }
  96
  97         if(argv(0) == "skinselect")
  98         {
  99                 m_goto_skin_selector();
 100                 return;
 101         }
 102
 103         if(argv(0) == "languageselect")
 104         {
 105                 m_goto_language_selector();
 106                 return;
 107         }
 108
 109         if(argv(0) == "videosettings")
 110         {
 111                 m_goto_video_settings();
 112                 return;
 113         }
 114
 115         if(argv(0) == "dumptree")
 116         {
 117                 _dumptree_space = "";
 118                 depthfirst(main, parent, firstChild, nextSibling, _dumptree_open, _dumptree_close, NULL);
 119                 return;
 120         }
 121
 122         if(argv(0) == "setresolution")
 123         {
 124                 updateConwidths();
 125                 return;
 126         }
 127
 128         if(argv(0) == "setcompression")
 129         {
 130                 updateCompression();
 131                 return;
 132         }
 133
 134         if(argv(0) == "curl")
 135         {
 136                 float do_exec;
 137                 string do_cvar;
 138                 float key;
 139                 float i, j;
 140                 string url;
 141                 float buf;
 142                 float r;
 143
 144                 do_exec = FALSE;
 145                 do_cvar = string_null;
 146                 key = -1;
 147
 148                 for(i = 1; i+1 < argc; ++i)
 149                 {
 150                         if(argv(i) == "--cvar" && i+2 < argc)
 151                         {
 152                                 ++i;
 153                                 do_cvar = argv(i);
 154                                 continue;
 155                         }
 156                         if(argv(i) == "--exec")
 157                         {
 158                                 do_exec = TRUE;
 159                                 continue;
 160                         }
 161                         if(argv(i) == "--key" && i+2 < argc)
 162                         {
 163                                 ++i;
 164                                 key = stof(argv(i));
 165                                 continue;
 166                         }
 167                         break;
 168                 }
 169
 170                 // now, argv(i) is the URL
 171                 // following args may be POST parameters
 172                 url = argv(i);
 173                 ++i;
 174                 buf = buf_create();
 175                 j = 0;
 176                 for(; i+1 < argc; i += 2)
 177                         bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 178                 if(i < argc)
 179                         bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 180
 181                 if(j == 0) // no args: GET
 182                         r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 183                 else // with args: POST
 184                         r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 185
 186                 if(r)
 187                 {
 188                         curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 189                         curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 190                         curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 191                 }
 192                 else
 193                         print(_("error creating curl handle\n"));
 194
 195                 buf_del(buf);
 196
 197                 return;
 198         }
 199
 200 #if 0
 201         if(argv(0) == "tokentest")
 202         {
 203                 string s;
 204                 float i, n;
 205
 206                 print("SANE tokenizer:\n");
 207                 s = cvar_string("tokentest");
 208                 n = tokenize_console_force_builtin(s);
 209                 for(i = -n; i < n; ++i)
 210                 {
 211                         print("token ", ftos(i), ": '", argv(i), "' = ");
 212                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 213                 }
 214                 print(".\n");
 215
 216                 print("INSANE tokenizer:\n");
 217                 s = cvar_string("tokentest");
 218                 n = tokenize(s);
 219                 for(i = -n; i < n; ++i)
 220                 {
 221                         print("token ", ftos(i), ": '", argv(i), "' = ");
 222                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 223                 }
 224                 print(".\n");
 225
 226                 print("EMULATED tokenizer:\n");
 227                 s = cvar_string("tokentest");
 228                 n = tokenize_console_force_emulation(s);
 229                 for(i = -n; i < n; ++i)
 230                 {
 231                         print("token ", ftos(i), ": '", argv(i), "' = ");
 232                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 233                 }
 234                 print(".\n");
 235                 return;
 236         }
 237 #endif
 238
 239         print(_("Invalid command. For a list of supported commands, try menu_cmd help.\n"));
 240 }