qcsrc/menu/gamecommand.qc

   1 void GameCommand_Init()
   2 {
   3         // make gg call menu QC theCommands
   4         localcmd("alias qc_cmd \"menu_cmd $*\"\n");
   5 }
   6
   7 string _dumptree_space;
   8 void _dumptree_open(entity pass, entity me)
   9 {
  10         string s;
  11         s = me.toString(me);
  12         if(s == "")
  13                 s = me.classname;
  14         else
  15                 s = strcat(me.classname, ": ", s);
  16         print(_dumptree_space, etos(me), " (", s, ")");
  17         if(me.firstChild)
  18         {
  19                 print(" {\n");
  20                 _dumptree_space = strcat(_dumptree_space, "  ");
  21         }
  22         else
  23                 print("\n");
  24 }
  25 void _dumptree_close(entity pass, entity me)
  26 {
  27         if(me.firstChild)
  28         {
  29                 _dumptree_space = substring(_dumptree_space, 0, strlen(_dumptree_space) - 2);
  30                 print(_dumptree_space, "}\n");
  31         }
  32 }
  33
  34 void GameCommand(string theCommand)
  35 {
  36         float argc;
  37         argc = tokenize_console(theCommand);
  38
  39         if(argv(0) == "help" || argc == 0)
  40         {
  41                 print("Usage: menu_cmd theCommand..., where possible theCommands are:\n");
  42                 print("  sync - reloads all cvars on the current menu page\n");
  43                 print("  directmenu ITEM - select a menu item as main item\n");
  44                 GameCommand_Generic("help");
  45                 return;
  46         }
  47
  48         if(GameCommand_Generic(theCommand))
  49                 return;
  50
  51         if(argv(0) == "sync")
  52         {
  53                 loadAllCvars(main);
  54                 return;
  55         }
  56
  57         if(argv(0) == "directmenu") if(argc == 2)
  58         {
  59                 // switch to a menu item
  60                 if(!isdemo()) // don't allow this command in demos
  61                         m_goto(argv(1));
  62                 return;
  63         }
  64
  65         if(argv(0) == "directpanelhudmenu")
  66         {
  67                 highlightedPanel = stof(argv(1));
  68                 // switch to a menu item
  69                 m_goto(strcat("HUD", HUD_Panel_GetName(highlightedPanel)));
  70                 return;
  71         }
  72
  73         if(argv(0) == "skinselect")
  74         {
  75                 m_goto_skin_selector();
  76                 return;
  77         }
  78
  79         if(argv(0) == "videosettings")
  80         {
  81                 m_goto_video_settings();
  82                 return;
  83         }
  84
  85         if(argv(0) == "dumptree")
  86         {
  87                 _dumptree_space = "";
  88                 depthfirst(main, parent, firstChild, nextSibling, _dumptree_open, _dumptree_close, NULL);
  89                 return;
  90         }
  91
  92         if(argv(0) == "setresolution")
  93         {
  94                 updateConwidths();
  95                 return;
  96         }
  97
  98 #if 0
  99         if(argv(0) == "tokentest")
 100         {
 101                 string s;
 102                 float i, n;
 103
 104                 print("SANE tokenizer:\n");
 105                 s = cvar_string("tokentest");
 106                 n = tokenize_console_force_builtin(s);
 107                 for(i = -n; i < n; ++i)
 108                 {
 109                         print("token ", ftos(i), ": '", argv(i), "' = ");
 110                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 111                 }
 112                 print(".\n");
 113
 114                 print("INSANE tokenizer:\n");
 115                 s = cvar_string("tokentest");
 116                 n = tokenize(s);
 117                 for(i = -n; i < n; ++i)
 118                 {
 119                         print("token ", ftos(i), ": '", argv(i), "' = ");
 120                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 121                 }
 122                 print(".\n");
 123
 124                 print("EMULATED tokenizer:\n");
 125                 s = cvar_string("tokentest");
 126                 n = tokenize_console_force_emulation(s);
 127                 for(i = -n; i < n; ++i)
 128                 {
 129                         print("token ", ftos(i), ": '", argv(i), "' = ");
 130                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 131                 }
 132                 print(".\n");
 133                 return;
 134         }
 135 #endif
 136
 137         print("Invalid theCommand. For a list of supported theCommands, try menu_cmd help.\n");
 138 }