get rid of some dead code
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / borderimage.c
1 #ifdef INTERFACE
2 CLASS(BorderImage) EXTENDS(Label)
3         METHOD(BorderImage, configureBorderImage, void(entity, string, float, vector, string, float))
4         METHOD(BorderImage, resizeNotify, void(entity, vector, vector, vector, vector))
5         METHOD(BorderImage, draw, void(entity))
6         ATTRIB(BorderImage, src, string, string_null)
7         ATTRIB(BorderImage, borderHeight, float, 0)
8         ATTRIB(BorderImage, borderVec, vector, '0 0 0')
9         ATTRIB(BorderImage, color, vector, '1 1 1')
10         ATTRIB(BorderImage, closeButton, entity, NULL)
11         ATTRIB(BorderImage, realFontSize_Nexposeed, vector, '0 0 0')
12         ATTRIB(BorderImage, realOrigin_Nexposeed, vector, '0 0 0')
13         ATTRIB(BorderImage, isNexposeeTitleBar, float, 0)
14         ATTRIB(BorderImage, zoomedOutTitleBarPosition, float, 0)
15         ATTRIB(BorderImage, zoomedOutTitleBar, float, 0)
16 ENDCLASS(BorderImage)
17 #endif
18
19 #ifdef IMPLEMENTATION
20 void BorderImage_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
21 {
22         me.isNexposeeTitleBar = 0;
23         if(me.zoomedOutTitleBar)
24                 if(me.parent.parent.instanceOfNexposee)
25                         if(me.parent.instanceOfDialog)
26                                 if(me == me.parent.frame)
27                                         me.isNexposeeTitleBar = 1;
28         if(me.isNexposeeTitleBar)
29         {
30                 vector scrs;
31                 scrs = eX * conwidth + eY * conheight;
32                 SUPER(BorderImage).resizeNotify(me, relOrigin, relSize, boxToGlobal(me.parent.Nexposee_smallOrigin, '0 0 0', scrs), boxToGlobalSize(me.parent.Nexposee_smallSize, scrs));
33                 me.realOrigin_y = me.realFontSize_y * me.zoomedOutTitleBarPosition;
34                 me.realOrigin_Nexposeed = me.realOrigin;
35                 me.realFontSize_Nexposeed = me.realFontSize;
36         }
37         SUPER(BorderImage).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
38         me.borderVec_x = me.borderHeight / absSize_x;
39         me.borderVec_y = me.borderHeight / absSize_y;
40         me.realOrigin_y = 0.5 * (me.borderVec_y - me.realFontSize_y);
41         if(me.closeButton)
42         {
43                 // move the close button to the right place
44                 me.closeButton.Container_origin = '1 0 0' * (1 - me.borderVec_x);
45                 me.closeButton.Container_size = me.borderVec;
46                 me.closeButton.color = me.color;
47                 me.closeButton.colorC = me.color;
48                 me.closeButton.colorF = me.color;
49         }
50 }
51 void BorderImage_configureBorderImage(entity me, string theTitle, float sz, vector theColor, string path, float theBorderHeight)
52 {
53         me.configureLabel(me, theTitle, sz, 0.5);
54         me.src = path;
55         me.color = theColor;
56         me.borderHeight = theBorderHeight;
57 }
58 void BorderImage_draw(entity me)
59 {
60         if(me.src)
61                 draw_BorderPicture('0 0 0', me.src, '1 1 0', me.color, 1, me.borderVec);
62         if(me.fontSize > 0)
63         {
64                 vector ro, rf, df;
65                 if(me.isNexposeeTitleBar)
66                 {
67                         // me.parent.Nexposee_animationFactor 0 (small) or 1 (full)
68                         // default values are for 1
69                         ro = me.realOrigin;
70                         rf = me.realFontSize;
71                         df = draw_fontscale;
72                         me.realOrigin = ro * me.parent.Nexposee_animationFactor + me.realOrigin_Nexposeed * (1 - me.parent.Nexposee_animationFactor);
73                         me.realFontSize = rf * me.parent.Nexposee_animationFactor + me.realFontSize_Nexposeed * (1 - me.parent.Nexposee_animationFactor);
74                         draw_fontscale = globalToBoxSize(boxToGlobalSize(df, me.realFontSize), rf);
75                 }
76
77                 SUPER(BorderImage).draw(me);
78
79                 if(me.isNexposeeTitleBar)
80                 {
81                         // me.Nexposee_animationState 0 (small) or 1 (full)
82                         // default values are for 1
83                         me.realOrigin = ro;
84                         me.realFontSize = rf;
85                         draw_fontscale = df;
86                 }
87         }
88 };
89 #endif