Merge branch 'master' into samual/combined_updates
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / image.c
1 #ifdef INTERFACE
2 CLASS(Image) EXTENDS(Item)
3         METHOD(Image, configureImage, void(entity, string))
4         METHOD(Image, draw, void(entity))
5         METHOD(Image, toString, string(entity))
6         METHOD(Image, resizeNotify, void(entity, vector, vector, vector, vector))
7         METHOD(Image, updateAspect, void(entity))
8         METHOD(Image, initZoom, void(entity))
9         METHOD(Image, setZoom, void(entity, float, float))
10         METHOD(Image, drag_setStartPos, float(entity, vector))
11         METHOD(Image, drag, float(entity, vector))
12         ATTRIB(Image, src, string, string_null)
13         ATTRIB(Image, color, vector, '1 1 1')
14         ATTRIB(Image, forcedAspect, float, 0) // special values: -1 keep image aspect ratio, -2 keep image size but bound to the containing box, -3 always keep image size
15         ATTRIB(Image, zoomBox, float, 0) // used by forcedAspect -2 when the image is larger than the containing box
16         ATTRIB(Image, zoomFactor, float, 1)
17         ATTRIB(Image, zoomOffset, vector, '0.5 0.5 0')
18         ATTRIB(Image, zoomSnapToTheBox, float, 1) // snap the zoomed in image to the box borders when zooming/dragging it
19         ATTRIB(Image, zoomTime, float, 0)
20         ATTRIB(Image, zoomLimitedByTheBox, float, 0) // forbids zoom if image would be larger than the containing box
21         ATTRIB(Image, zoomMax, float, 0)
22         ATTRIB(Image, start_zoomOffset, vector, '0 0 0')
23         ATTRIB(Image, start_coords, vector, '0 0 0')
24         ATTRIB(Image, imgOrigin, vector, '0 0 0')
25         ATTRIB(Image, imgSize, vector, '0 0 0')
26 ENDCLASS(Image)
27 #endif
28
29 #ifdef IMPLEMENTATION
30 string Image_toString(entity me)
31 {
32         return me.src;
33 }
34 void Image_configureImage(entity me, string path)
35 {
36         me.src = path;
37 }
38 void Image_initZoom(entity me)
39 {
40         me.zoomOffset = '0.5 0.5 0';
41         me.zoomFactor = 1;
42         if (me.forcedAspect == -2)
43                 me.zoomBox = -1; // calculate zoomBox at the first updateAspect call
44         if (me.zoomLimitedByTheBox)
45                 me.zoomMax = -1; // calculate zoomMax at the first updateAspect call
46 }
47
48 void Image_draw(entity me)
49 {
50         if(me.imgSize_x > 1 || me.imgSize_y > 1)
51                 draw_SetClip();
52         draw_Picture(me.imgOrigin, me.src, me.imgSize, me.color, 1);
53         if(me.imgSize_x > 1 || me.imgSize_y > 1)
54                 draw_ClearClip();
55         SUPER(Image).draw(me);
56 }
57 void Image_updateAspect(entity me)
58 {
59         float asp = 0;
60         if(me.size_x <= 0 || me.size_y <= 0)
61                 return;
62         if(me.forcedAspect == 0)
63         {
64                 me.imgOrigin = '0 0 0';
65                 me.imgSize = '1 1 0';
66         }
67         else
68         {
69                 vector sz = '0 0 0';
70                 if(me.forcedAspect < 0)
71                 {
72                         sz = draw_PictureSize(me.src);
73                         if(sz_x <= 0 || sz_y <= 0)
74                         {
75                                 // image is broken or doesn't exist, set the size for the placeholder image
76                                 sz_x = me.size_x;
77                                 sz_y = me.size_y;
78                         }
79                         asp = sz_x / sz_y;
80                 }
81                 else
82                         asp = me.forcedAspect;
83
84                 if(me.forcedAspect <= -2)
85                 {
86                         me.imgSize_x = sz_x / me.size_x;
87                         me.imgSize_y = sz_y / me.size_y;
88                         if(me.zoomBox < 0 && (me.imgSize_x > 1 || me.imgSize_y > 1))
89                         {
90                                 // image larger than the containing box, zoom it out to fit into the box
91                                 if(me.size_x > asp * me.size_y)
92                                         me.zoomBox = (me.size_y * asp / me.size_x) / me.imgSize_x;
93                                 else
94                                         me.zoomBox = (me.size_x / (asp * me.size_y)) / me.imgSize_y;
95                                 me.zoomFactor = me.zoomBox;
96                         }
97                 }
98                 else
99                 {
100                         if(me.size_x > asp * me.size_y)
101                         {
102                                 // x too large, so center x-wise
103                                 me.imgSize = eY + eX * (me.size_y * asp / me.size_x);
104                         }
105                         else
106                         {
107                                 // y too large, so center y-wise
108                                 me.imgSize = eX + eY * (me.size_x / (asp * me.size_y));
109                         }
110                 }
111         }
112
113         if (me.zoomMax < 0)
114         {
115                 if(me.zoomBox > 0)
116                         me.zoomMax = me.zoomBox;
117                 else
118                 {
119                         if(me.size_x > asp * me.size_y)
120                                 me.zoomMax = (me.size_y * asp / me.size_x) / me.imgSize_x;
121                         else
122                                 me.zoomMax = (me.size_x / (asp * me.size_y)) / me.imgSize_y;
123                 }
124         }
125
126         if (me.zoomMax > 0 && me.zoomFactor > me.zoomMax)
127                 me.zoomFactor = me.zoomMax;
128         if (me.zoomFactor)
129                 me.imgSize = me.imgSize * me.zoomFactor;
130
131         if(me.imgSize_x > 1 || me.imgSize_y > 1)
132         {
133                 if(me.zoomSnapToTheBox)
134                 {
135                         if(me.imgSize_x > 1)
136                                 me.zoomOffset_x = bound(0.5/me.imgSize_x, me.zoomOffset_x, 1 - 0.5/me.imgSize_x);
137                         else
138                                 me.zoomOffset_x = bound(1 - 0.5/me.imgSize_x, me.zoomOffset_x, 0.5/me.imgSize_x);
139
140                         if(me.imgSize_y > 1)
141                                 me.zoomOffset_y = bound(0.5/me.imgSize_y, me.zoomOffset_y, 1 - 0.5/me.imgSize_y);
142                         else
143                                 me.zoomOffset_y = bound(1 - 0.5/me.imgSize_y, me.zoomOffset_y, 0.5/me.imgSize_y);
144                 }
145                 else
146                 {
147                         me.zoomOffset_x = bound(0, me.zoomOffset_x, 1);
148                         me.zoomOffset_y = bound(0, me.zoomOffset_y, 1);
149                 }
150         }
151         else
152                 me.zoomOffset = '0.5 0.5 0';
153
154         me.imgOrigin_x = 0.5 - me.zoomOffset_x * me.imgSize_x;
155         me.imgOrigin_y = 0.5 - me.zoomOffset_y * me.imgSize_y;
156 }
157 float Image_drag_setStartPos(entity me, vector coords)
158 {
159         //if(me.imgSize_x > 1 || me.imgSize_y > 1) // check disabled: mousewheel zoom may start from a non-zoomed-in image
160         {
161                 me.start_zoomOffset = me.zoomOffset;
162                 me.start_coords = coords;
163         }
164         return 1;
165 }
166 float Image_drag(entity me, vector coords)
167 {
168         if(me.imgSize_x > 1 || me.imgSize_y > 1)
169         {
170                 me.zoomOffset_x = me.start_zoomOffset_x + (me.start_coords_x - coords_x) / me.imgSize_x;
171                 me.zoomOffset_y = me.start_zoomOffset_y + (me.start_coords_y - coords_y) / me.imgSize_y;
172                 me.updateAspect(me);
173         }
174         return 1;
175 }
176 void Image_setZoom(entity me, float z, float atMousePosition)
177 {
178         float prev_zoomFactor;
179         prev_zoomFactor = me.zoomFactor;
180         if (z < 0) // multiply by the current zoomFactor (but can also snap to real dimensions or to box)
181         {
182                 me.zoomFactor *= -z;
183                 float realSize_in_the_middle, boxSize_in_the_middle;
184                 realSize_in_the_middle = ((prev_zoomFactor - 1) * (me.zoomFactor - 1) < 0);
185                 boxSize_in_the_middle = (me.zoomBox > 0 && (prev_zoomFactor - me.zoomBox) * (me.zoomFactor - me.zoomBox) < 0);
186                 if (realSize_in_the_middle && boxSize_in_the_middle)
187                 {
188                         // snap to real dimensions or to box
189                         if (prev_zoomFactor < me.zoomFactor)
190                                 me.zoomFactor = min(1, me.zoomBox);
191                         else
192                                 me.zoomFactor = max(1, me.zoomBox);
193                 }
194                 else if (realSize_in_the_middle)
195                         me.zoomFactor = 1; // snap to real dimensions
196                 else if (boxSize_in_the_middle)
197                         me.zoomFactor = me.zoomBox; // snap to box
198         }
199         else if (z == 0) // reset (no zoom)
200         {
201                 if (me.zoomBox > 0)
202                         me.zoomFactor = me.zoomBox;
203                 else
204                         me.zoomFactor = 1;
205         }
206         else // directly set
207                 me.zoomFactor = z;
208         me.zoomFactor = bound(1/16, me.zoomFactor, 16);
209         if (me.zoomMax > 0 && me.zoomFactor > me.zoomMax)
210                 me.zoomFactor = me.zoomMax;
211         if (prev_zoomFactor != me.zoomFactor)
212         {
213                 me.zoomTime = time;
214                 if (atMousePosition)
215                 {
216                         me.zoomOffset_x = me.start_zoomOffset_x + (me.start_coords_x - 0.5) / me.imgSize_x;
217                         me.zoomOffset_y = me.start_zoomOffset_y + (me.start_coords_y - 0.5) / me.imgSize_y;
218                         // updateAspect will reset zoomOffset to '0.5 0.5 0' if
219                         // with this zoomFactor the image will not be zoomed in
220                         // (updateAspect will check the new values of imgSize).
221                 }
222         }
223         me.updateAspect(me);
224 }
225 void Image_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
226 {
227         SUPER(Image).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
228         me.updateAspect(me);
229 }
230 #endif