Merge commit 'origin/master' into diabolik/nexmodel
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / image.c
1 #ifdef INTERFACE
2 CLASS(Image) EXTENDS(Item)
3         METHOD(Image, configureImage, void(entity, string))
4         METHOD(Image, draw, void(entity))
5         METHOD(Image, toString, string(entity))
6         METHOD(Image, resizeNotify, void(entity, vector, vector, vector, vector))
7         METHOD(Image, updateAspect, void(entity))
8         ATTRIB(Image, src, string, string_null)
9         ATTRIB(Image, color, vector, '1 1 1')
10         ATTRIB(Image, forcedAspect, float, 0)
11         ATTRIB(Image, imgOrigin, vector, '0 0 0')
12         ATTRIB(Image, imgSize, vector, '0 0 0')
13 ENDCLASS(Image)
14 #endif
15
16 #ifdef IMPLEMENTATION
17 string Image_toString(entity me)
18 {
19         return me.src;
20 }
21 void Image_configureImage(entity me, string path)
22 {
23         me.src = path;
24 }
25 void Image_draw(entity me)
26 {
27         draw_Picture(me.imgOrigin, me.src, me.imgSize, me.color, 1);
28 }
29 void Image_updateAspect(entity me)
30 {
31         float asp;
32         if(me.size_x <= 0 || me.size_y <= 0)
33                 return;
34         if(me.forcedAspect == 0)
35         {
36                 me.imgOrigin = '0 0 0';
37                 me.imgSize = '1 1 0';
38         }
39         else
40         {
41                 if(me.forcedAspect < 0)
42                 {
43                         vector sz;
44                         sz = draw_PictureSize(me.src);
45                         asp = sz_x / sz_y;
46                 }
47                 else
48                         asp = me.forcedAspect;
49                 if(me.size_x > asp * me.size_y)
50                 {
51                         // x too large, so center x-wise
52                         me.imgSize = eY + eX * (me.size_y * asp / me.size_x);
53                 }
54                 else
55                 {
56                         // y too large, so center y-wise
57                         me.imgSize = eX + eY * (me.size_x / (asp * me.size_y));
58                 }
59                 me.imgOrigin = '0.5 0.5 0' - 0.5 * me.imgSize;
60         }
61 }
62 void Image_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
63 {
64         SUPER(Image).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
65         me.updateAspect(me);
66 }
67 #endif