Merge commit 'origin/master' into diabolik/nexmodel
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / inputbox.c
1 #ifdef INTERFACE
2 CLASS(InputBox) EXTENDS(Label)
3         METHOD(InputBox, configureInputBox, void(entity, string, float, float, string))
4         METHOD(InputBox, draw, void(entity))
5         METHOD(InputBox, setText, void(entity, string))
6         METHOD(InputBox, enterText, void(entity, string))
7         METHOD(InputBox, keyDown, float(entity, float, float, float))
8         METHOD(InputBox, mouseRelease, float(entity, vector))
9         METHOD(InputBox, mousePress, float(entity, vector))
10         METHOD(InputBox, mouseDrag, float(entity, vector))
11         METHOD(InputBox, showNotify, void(entity))
12
13         ATTRIB(InputBox, src, string, string_null)
14
15         ATTRIB(InputBox, cursorPos, float, 0) // characters
16         ATTRIB(InputBox, scrollPos, float, 0) // widths
17
18         ATTRIB(InputBox, focusable, float, 1)
19         ATTRIB(InputBox, disabled, float, 0)
20         ATTRIB(InputBox, lastChangeTime, float, 0)
21         ATTRIB(InputBox, dragScrollTimer, float, 0)
22         ATTRIB(InputBox, dragScrollPos, vector, '0 0 0')
23         ATTRIB(InputBox, pressed, float, 0)
24         ATTRIB(InputBox, editColorCodes, float, 1)
25         ATTRIB(InputBox, forbiddenCharacters, string, "")
26         ATTRIB(InputBox, color, vector, '1 1 1')
27         ATTRIB(InputBox, colorF, vector, '1 1 1')
28         ATTRIB(InputBox, maxLength, float, 255)
29 ENDCLASS(InputBox)
30 void InputBox_Clear_Click(entity btn, entity me);
31 #endif
32
33 #ifdef IMPLEMENTATION
34 void InputBox_configureInputBox(entity me, string theText, float theCursorPos, float theFontSize, string gfx)
35 {
36         SUPER(InputBox).configureLabel(me, theText, theFontSize, 0.0);
37         me.src = gfx;
38         me.cursorPos = theCursorPos;
39 }
40
41 void InputBox_setText(entity me, string txt)
42 {
43         if(me.text)
44                 strunzone(me.text);
45         SUPER(InputBox).setText(me, strzone(txt));
46 }
47
48 void InputBox_Clear_Click(entity btn, entity me)
49 {
50         me.setText(me, "");
51 }
52
53 float InputBox_mouseDrag(entity me, vector pos)
54 {
55         float p;
56         me.dragScrollPos = pos;
57         p = me.scrollPos + pos_x - me.keepspaceLeft;
58         me.cursorPos = draw_TextLengthUpToWidth(me.text, p, 0, me.realFontSize);
59         me.lastChangeTime = time;
60         return 1;
61 }
62
63 float InputBox_mousePress(entity me, vector pos)
64 {
65         me.dragScrollTimer = time;
66         me.pressed = 1;
67         return InputBox_mouseDrag(me, pos);
68 }
69
70 float InputBox_mouseRelease(entity me, vector pos)
71 {
72         me.pressed = 0;
73         return InputBox_mouseDrag(me, pos);
74 }
75
76 void InputBox_enterText(entity me, string ch)
77 {
78         float i;
79         for(i = 0; i < strlen(ch); ++i)
80                 if(strstrofs(me.forbiddenCharacters, substring(ch, i, 1), 0) > -1)
81                         return;
82         if(strlen(ch) + strlen(me.text) > me.maxLength)
83                 return;
84         me.setText(me, strcat(substring(me.text, 0, me.cursorPos), ch, substring(me.text, me.cursorPos, strlen(me.text) - me.cursorPos)));
85         me.cursorPos += strlen(ch);
86 }
87
88 float InputBox_keyDown(entity me, float key, float ascii, float shift)
89 {
90         me.lastChangeTime = time;
91         me.dragScrollTimer = time;
92         if(ascii >= 32 && ascii != 127)
93         {
94                 me.enterText(me, chr(ascii));
95                 return 1;
96         }
97         switch(key)
98         {
99                 case K_LEFTARROW:
100                         me.cursorPos -= 1;
101                         return 1;
102                 case K_RIGHTARROW:
103                         me.cursorPos += 1;
104                         return 1;
105                 case K_HOME:
106                         me.cursorPos = 0;
107                         return 1;
108                 case K_END:
109                         me.cursorPos = strlen(me.text);
110                         return 1;
111                 case K_BACKSPACE:
112                         if(me.cursorPos > 0)
113                         {
114                                 me.cursorPos -= 1;
115                                 me.setText(me, strcat(substring(me.text, 0, me.cursorPos), substring(me.text, me.cursorPos + 1, strlen(me.text) - me.cursorPos - 1)));
116                         }
117                         return 1;
118                 case K_DEL:
119                         if(shift & S_CTRL)
120                                 me.setText(me, "");
121                         else
122                                 me.setText(me, strcat(substring(me.text, 0, me.cursorPos), substring(me.text, me.cursorPos + 1, strlen(me.text) - me.cursorPos - 1)));
123                         return 1;
124         }
125         return 0;
126 }
127
128 void InputBox_draw(entity me)
129 {
130 #define CURSOR "_"
131         float cursorPosInWidths, totalSizeInWidths;
132
133         if(me.pressed)
134                 me.mouseDrag(me, me.dragScrollPos); // simulate mouseDrag event
135
136         me.focusable = !me.disabled;
137         if(me.disabled)
138                 draw_alpha *= me.disabledAlpha;
139
140         if(me.src)
141         {
142                 if(me.focused && !me.disabled)
143                         draw_ButtonPicture('0 0 0', strcat(me.src, "_f"), '1 1 0', me.colorF, 1);
144                 else
145                         draw_ButtonPicture('0 0 0', strcat(me.src, "_n"), '1 1 0', me.color, 1);
146         }
147
148         me.cursorPos = bound(0, me.cursorPos, strlen(me.text));
149         cursorPosInWidths = draw_TextWidth(substring(me.text, 0, me.cursorPos), 0, me.realFontSize);
150         totalSizeInWidths = draw_TextWidth(strcat(me.text, CURSOR), 0, me.realFontSize);
151
152         if(me.dragScrollTimer < time)
153         {
154                 float save;
155                 save = me.scrollPos;
156                 me.scrollPos = bound(cursorPosInWidths - (0.875 - me.keepspaceLeft - me.keepspaceRight), me.scrollPos, cursorPosInWidths - 0.125);
157                 if(me.scrollPos != save)
158                         me.dragScrollTimer = time + 0.2;
159         }
160         me.scrollPos = min(me.scrollPos, totalSizeInWidths - (1 - me.keepspaceRight - me.keepspaceLeft));
161         me.scrollPos = max(0, me.scrollPos);
162
163         draw_SetClipRect(eX * me.keepspaceLeft, eX * (1 - me.keepspaceLeft - me.keepspaceRight) + eY);
164         if(me.editColorCodes)
165         {
166                 string ch, ch2;
167                 float i, n;
168                 vector theColor;
169                 float theAlpha;    //float theVariableAlpha;
170                 vector p;
171                 vector theTempColor;
172                 float component;
173                 
174                 p = me.realOrigin - eX * me.scrollPos;
175                 theColor = '1 1 1';
176                 theAlpha = 1;    //theVariableAlpha = 1; // changes when ^ax found
177                 
178                 n = strlen(me.text);
179                 for(i = 0; i < n; ++i)
180                 {
181                         ch = substring(me.text, i, 1);
182                         if(ch == "^")
183                         {
184                                 float w;
185                                 ch2 = substring(me.text, i+1, 1);
186                                 w = draw_TextWidth(strcat(ch, ch2), 0, me.realFontSize);
187                                 if(ch2 == "^")
188                                 {
189                                         draw_Fill(p, eX * w + eY * me.realFontSize_y, '1 1 1', 0.5);
190                                         draw_Text(p + eX * 0.25 * w, "^", me.realFontSize, theColor, theAlpha, 0);
191                                 }
192                                 else if(ch2 == "0" || stof(ch2)) // digit?
193                                 {
194                                         switch(stof(ch2))
195                                         {
196                                                 case 0: theColor = '0 0 0'; theAlpha = 1; break;
197                                                 case 1: theColor = '1 0 0'; theAlpha = 1; break;
198                                                 case 2: theColor = '0 1 0'; theAlpha = 1; break;
199                                                 case 3: theColor = '1 1 0'; theAlpha = 1; break;
200                                                 case 4: theColor = '0 0 1'; theAlpha = 1; break;
201                                                 case 5: theColor = '0 1 1'; theAlpha = 1; break;
202                                                 case 6: theColor = '1 0 1'; theAlpha = 1; break;
203                                                 case 7: theColor = '1 1 1'; theAlpha = 1; break;
204                                                 case 8: theColor = '1 1 1'; theAlpha = 0.5; break;
205                                                 case 9: theColor = '0.5 0.5 0.5'; theAlpha = 1; break;
206                                         }
207                                         draw_Fill(p, eX * w + eY * me.realFontSize_y, '1 1 1', 0.5);
208                                         draw_Text(p, strcat(ch, ch2), me.realFontSize, theColor, theAlpha, 0);
209                                 }
210                                 else if(ch2 == "x") // ^x found
211                                 {
212                                         theColor = '1 1 1';
213                                         theTempColor = '0 0 0';
214                                         
215                                         component = HEXDIGIT_TO_DEC(substring(me.text, i+2, 1));
216                                         if (component >= 0) // ^xr found
217                                         {
218                                                 theTempColor_x = component/15;
219                                                 
220                                                 component = HEXDIGIT_TO_DEC(substring(me.text, i+3, 1));
221                                                 if (component >= 0) // ^xrg found
222                                                 {
223                                                         theTempColor_y = component/15;
224                                                         
225                                                         component = HEXDIGIT_TO_DEC(substring(me.text, i+4, 1));
226                                                         if (component >= 0) // ^xrgb found
227                                                         {
228                                                                 theTempColor_z = component/15;
229                                                                 theColor = theTempColor;
230                                                                 w = draw_TextWidth(substring(me.text, i, 5), 0, me.realFontSize);
231                                                                 
232                                                                 draw_Fill(p, eX * w + eY * me.realFontSize_y, '1 1 1', 0.5);
233                                                                 draw_Text(p, substring(me.text, i, 5), me.realFontSize, theColor, 1, 0);    // theVariableAlpha instead of 1 using alpha tags ^ax
234                                                                 i += 3;
235                                                         }
236                                                         else
237                                                         {
238                                                                 // blue missing
239                                                                 w = draw_TextWidth(substring(me.text, i, 4), 0, me.realFontSize);
240                                                                 draw_Fill(p, eX * w + eY * me.realFontSize_y, eZ, 0.5);
241                                                                 draw_Text(p, substring(me.text, i, 4), me.realFontSize, '1 1 1', theAlpha, 0);
242                                                                 i += 2;
243                                                         }
244                                                 }
245                                                 else
246                                                 {
247                                                         // green missing
248                                                         w = draw_TextWidth(substring(me.text, i, 3), 0, me.realFontSize);
249                                                         draw_Fill(p, eX * w + eY * me.realFontSize_y, eY, 0.5);
250                                                         draw_Text(p, substring(me.text, i, 3), me.realFontSize, '1 1 1', theAlpha, 0);
251                                                         i += 1;
252                                                 }
253                                         }
254                                         else
255                                         {
256                                                 // red missing
257                                                 //w = draw_TextWidth(substring(me.text, i, 2), 0) * me.realFontSize_x;
258                                                 draw_Fill(p, eX * w + eY * me.realFontSize_y, eX, 0.5);
259                                                 draw_Text(p, substring(me.text, i, 2), me.realFontSize, '1 1 1', theAlpha, 0);
260                                         }
261                                 }
262                                 /*else if(ch2 == "a") // ^a found
263                                 {
264                                         draw_Fill(p, eX * w + eY * me.realFontSize_y, '1 1 1', 0.5);
265                                         draw_Text(p, substring(me.text, i, 2), me.realFontSize, theColor, 0.8, 0);
266                                         
267                                         component = str2chr(me.text, i+2);
268                                         if (component >= '0' && component <= '9')
269                                                 component = component - '0';
270                                         else if (component >= 'a' && component <= 'f')
271                                                 component = component - 87;
272                                         else if (component >= 'A' && component <= 'F')
273                                                 component = component - 55;
274                                         else
275                                                 component = -1;
276                                         
277                                         if (component >= 0) // ^ah found
278                                         {
279                                                 // FIX ME: overflow here
280                                                 if (component == 20 && theVariableAlpha <= 0.97)
281                                                         theVariableAlpha = theVariableAlpha + 0.0625;
282                                                 else if (component == 30 && theVariableAlpha >= 0.03)
283                                                         theVariableAlpha = theVariableAlpha - 0.0625;
284                                                 else
285                                                         theVariableAlpha = component*0.0625;
286                                                 
287                                                 draw_Fill(p, eX * draw_TextWidth(substring(me.text, i, 3), 0, me.realFontSize) + eY * me.realFontSize_y, '0.8 0.8 0.8', 0.5);
288                                                 draw_Text(p, strcat(ch, ch2), me.realFontSize, theColor, 0.8, 0);
289                                         }
290                                 }*/
291                                 else
292                                 {
293                                         draw_Fill(p, eX * w + eY * me.realFontSize_y, '1 1 1', 0.5);
294                                         draw_Text(p, strcat(ch, ch2), me.realFontSize, theColor, theAlpha, 0);
295                                 }
296                                 p += w * eX;
297                                 ++i;
298                                 continue;
299                         }
300                         draw_Text(p, ch, me.realFontSize, theColor, theAlpha, 0); // TODO theVariableAlpha
301                         p += eX * draw_TextWidth(ch, 0, me.realFontSize);
302                 }
303         }
304         else
305                 draw_Text(me.realOrigin - eX * me.scrollPos, me.text, me.realFontSize, '1 1 1', 1, 0);
306                 // skipping SUPER(InputBox).draw(me);
307         if(!me.focused || (time - me.lastChangeTime) < floor(time - me.lastChangeTime) + 0.5)
308                 draw_Text(me.realOrigin + eX * (cursorPosInWidths - me.scrollPos), CURSOR, me.realFontSize, '1 1 1', 1, 0);
309
310         draw_ClearClip();
311 }
312
313 void InputBox_showNotify(entity me)
314 {
315         me.focusable = !me.disabled;
316 }
317 #endif