Merge commit 'origin/master' into diabolik/nexmodel
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / modalcontroller.c
1 #ifdef INTERFACE
2 CLASS(ModalController) EXTENDS(Container)
3         METHOD(ModalController, resizeNotify, void(entity, vector, vector, vector, vector))
4         METHOD(ModalController, draw, void(entity))
5         METHOD(ModalController, addItem, void(entity, entity, vector, vector, float))
6         METHOD(ModalController, showChild, void(entity, entity, vector, vector, float))
7         METHOD(ModalController, hideChild, void(entity, entity, float))
8         METHOD(ModalController, hideAll, void(entity, float))
9         METHOD(ModalController, addItem, void(entity, entity, vector, vector, float))
10         METHOD(ModalController, addTab, void(entity, entity, entity))
11
12         METHOD(ModalController, initializeDialog, void(entity, entity))
13
14         METHOD(ModalController, switchState, void(entity, entity, float, float))
15         ATTRIB(ModalController, origin, vector, '0 0 0')
16         ATTRIB(ModalController, size, vector, '0 0 0')
17         ATTRIB(ModalController, previousButton, entity, NULL)
18         ATTRIB(ModalController, fadedAlpha, float, 0.3)
19 ENDCLASS(ModalController)
20
21 .entity tabSelectingButton;
22 .vector origin;
23 .vector size;
24 void TabButton_Click(entity button, entity tab); // assumes a button has set the above fields to its own absolute origin, its size, and the tab to activate
25 void DialogOpenButton_Click(entity button, entity tab); // assumes a button has set the above fields to its own absolute origin, its size, and the tab to activate
26 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
27 void DialogCloseButton_Click(entity button, entity tab); // assumes a button has set the above fields to the tab to close
28 #endif
29
30 #ifdef IMPLEMENTATION
31
32 // modal dialog controller
33 // handles a stack of dialog elements
34 // each element can have one of the following states:
35 //   0: hidden (fading out)
36 //   1: visible (zooming in)
37 //   2: greyed out (inactive)
38 // While an animation is running, no item has focus. When an animation is done,
39 // the topmost item gets focus.
40 // The items are assumed to be added in overlapping order, that is, the lowest
41 // window must get added first.
42 //
43 // Possible uses:
44 // - to control a modal dialog:
45 //   - show modal dialog: me.showChild(me, childItem, buttonAbsOrigin, buttonAbsSize, 0) // childItem also gets focus
46 //   - dismiss modal dialog: me.hideChild(me, childItem, 0) // childItem fades out and relinquishes focus
47 //   - show first screen in m_show: me.hideAll(me, 1); me.showChild(me, me.firstChild, '0 0 0', '0 0 0', 1);
48 // - to show a temporary dialog instead of the menu (teamselect): me.hideAll(me, 1); me.showChild(me, teamSelectDialog, '0 0 0', '0 0 0', 1);
49 // - as a tabbed dialog control:
50 //   - to initialize: me.hideAll(me, 1); me.showChild(me, me.firstChild, '0 0 0', '0 0 0', 1);
51 //   - to show a tab: me.hideChild(me, currentTab, 0); me.showChild(me, newTab, buttonAbsOrigin, buttonAbsSize, 0);
52
53 .vector ModalController_initialSize;
54 .vector ModalController_initialOrigin;
55 .vector ModalController_initialFontScale;
56 .float ModalController_initialAlpha;
57 .vector ModalController_buttonSize;
58 .vector ModalController_buttonOrigin;
59 .float ModalController_state;
60 .float ModalController_factor;
61 .entity ModalController_controllingButton;
62
63 void ModalController_initializeDialog(entity me, entity root)
64 {
65         me.hideAll(me, 1);
66         me.showChild(me, root, '0 0 0', '0 0 0', 1); // someone else animates for us
67 }
68
69 void TabButton_Click(entity button, entity tab)
70 {
71         if(tab.ModalController_state == 1)
72                 return;
73         tab.parent.hideAll(tab.parent, 0);
74         button.forcePressed = 1;
75         tab.ModalController_controllingButton = button;
76         tab.parent.showChild(tab.parent, tab, button.origin, button.size, 0);
77 }
78
79 void DialogOpenButton_Click(entity button, entity tab)
80 {
81         DialogOpenButton_Click_withCoords(button, tab, button.origin, button.size);
82 }
83
84 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize)
85 {
86         if(tab.ModalController_state)
87                 return;
88         if(button)
89                 button.forcePressed = 1;
90         tab.ModalController_controllingButton = button;
91         tab.parent.showChild(tab.parent, tab, theOrigin, theSize, 0);
92 }
93
94 void DialogCloseButton_Click(entity button, entity tab)
95 {
96         tab.parent.hideChild(tab.parent, tab, 0);
97 }
98
99 void ModalController_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
100 {
101         me.resizeNotifyLie(me, relOrigin, relSize, absOrigin, absSize, ModalController_initialOrigin, ModalController_initialSize, ModalController_initialFontScale);
102 }
103
104 void ModalController_switchState(entity me, entity other, float state, float skipAnimation)
105 {
106         float previousState;
107         previousState = other.ModalController_state;
108         if(state == previousState && !skipAnimation)
109                 return;
110         other.ModalController_state = state;
111         switch(state)
112         {
113                 case 0:
114                         other.ModalController_factor = 1 - other.Container_alpha / other.ModalController_initialAlpha;
115                         // fading out
116                         break;
117                 case 1:
118                         other.ModalController_factor = other.Container_alpha / other.ModalController_initialAlpha;
119                         if(previousState == 0 && !skipAnimation)
120                         {
121                                 other.Container_origin = other.ModalController_buttonOrigin;
122                                 other.Container_size = other.ModalController_buttonSize;
123                         }
124                         // zooming in
125                         break;
126                 case 2:
127                         other.ModalController_factor = bound(0, (1 - other.Container_alpha / other.ModalController_initialAlpha) / me.fadedAlpha, 1);
128                         // fading out halfway
129                         break;
130         }
131         if(skipAnimation)
132                 other.ModalController_factor = 1;
133 }
134
135 void ModalController_draw(entity me)
136 {
137         entity e;
138         entity front;
139         float animating;
140         float f; // animation factor
141         float df; // animation step size
142         float prevFactor, targetFactor;
143         vector targetOrigin, targetSize; float targetAlpha;
144         vector fs;
145         animating = 0;
146
147         for(e = me.firstChild; e; e = e.nextSibling)
148                 if(e.ModalController_state)
149                 {
150                         if(front)
151                                 me.switchState(me, front, 2, 0);
152                         front = e;
153                 }
154         if(front)
155                 me.switchState(me, front, 1, 0);
156
157         df = frametime * 3; // animation speed
158
159         for(e = me.firstChild; e; e = e.nextSibling)
160         {
161                 f = (e.ModalController_factor = min(1, e.ModalController_factor + df));
162                 if(e.ModalController_state)
163                         if(f < 1)
164                                 animating = 1;
165
166                 if(f < 1)
167                 {
168                         prevFactor   = (1 - f) / (1 - f + df);
169                         targetFactor =     df  / (1 - f + df);
170                 }
171                 else
172                 {
173                         prevFactor = 0;
174                         targetFactor = 1;
175                 }
176
177                 if(e.ModalController_state == 2)
178                 {
179                         // fading out partially
180                         targetOrigin = e.Container_origin; // stay as is
181                         targetSize = e.Container_size; // stay as is
182                         targetAlpha = me.fadedAlpha * e.ModalController_initialAlpha;
183                 }
184                 else if(e.ModalController_state == 1)
185                 {
186                         // zooming in
187                         targetOrigin = e.ModalController_initialOrigin;
188                         targetSize = e.ModalController_initialSize;
189                         targetAlpha = e.ModalController_initialAlpha;
190                 }
191                 else
192                 {
193                         // fading out
194                         if(f < 1)
195                                 animating = 1;
196                         targetOrigin = e.Container_origin; // stay as is
197                         targetSize = e.Container_size; // stay as is
198                         targetAlpha = 0;
199                 }
200
201                 if(f == 1)
202                 {
203                         e.Container_origin = targetOrigin;
204                         e.Container_size = targetSize;
205                         me.setAlphaOf(me, e, targetAlpha);
206                 }
207                 else
208                 {
209                         e.Container_origin = e.Container_origin * prevFactor + targetOrigin * targetFactor;
210                         e.Container_size   = e.Container_size   * prevFactor + targetSize   * targetFactor;
211                         me.setAlphaOf(me, e, e.Container_alpha  * prevFactor + targetAlpha  * targetFactor);
212                 }
213                 // assume: o == to * f_prev + X * (1 - f_prev)
214                 // make:   o' = to * f  + X * (1 - f)
215                 // -->
216                 // X == (o - to * f_prev) / (1 - f_prev)
217                 // o' = to * f + (o - to * f_prev) / (1 - f_prev) * (1 - f)
218                 // --> (maxima)
219                 // o' = (to * (f - f_prev) + o * (1 - f)) / (1 - f_prev)
220
221                 fs = globalToBoxSize(e.Container_size, e.ModalController_initialSize);
222                 e.Container_fontscale_x = fs_x * e.ModalController_initialFontScale_x;
223                 e.Container_fontscale_y = fs_y * e.ModalController_initialFontScale_y;
224         }
225         if(animating || !me.focused)
226                 me.setFocus(me, NULL);
227         else
228                 me.setFocus(me, front);
229         SUPER(ModalController).draw(me);
230 };
231
232 void ModalController_addTab(entity me, entity other, entity tabButton)
233 {
234         me.addItem(me, other, '0 0 0', '1 1 1', 1);
235         tabButton.onClick = TabButton_Click;
236         tabButton.onClickEntity = other;
237         other.tabSelectingButton = tabButton;
238         if(other == me.firstChild)
239         {
240                 tabButton.forcePressed = 1;
241                 other.ModalController_controllingButton = tabButton;
242                 me.showChild(me, other, '0 0 0', '0 0 0', 1);
243         }
244 }
245
246 void ModalController_addItem(entity me, entity other, vector theOrigin, vector theSize, float theAlpha)
247 {
248         SUPER(ModalController).addItem(me, other, theOrigin, theSize, (other == me.firstChild) ? theAlpha : 0);
249         other.ModalController_initialFontScale = other.Container_fontscale;
250         other.ModalController_initialSize = other.Container_size;
251         other.ModalController_initialOrigin = other.Container_origin;
252         other.ModalController_initialAlpha = theAlpha; // hope Container never modifies this
253         if(other.ModalController_initialFontScale == '0 0 0')
254                 other.ModalController_initialFontScale = '1 1 0';
255 }
256
257 void ModalController_showChild(entity me, entity other, vector theOrigin, vector theSize, float skipAnimation)
258 {
259         if(other.ModalController_state == 0 || skipAnimation)
260         {
261                 me.setFocus(me, NULL);
262                 if(!skipAnimation)
263                 {
264                         other.ModalController_buttonOrigin = globalToBox(theOrigin, me.origin, me.size);
265                         other.ModalController_buttonSize = globalToBoxSize(theSize, me.size);
266                 }
267                 me.switchState(me, other, 1, skipAnimation);
268         } // zoom in from button (factor increases)
269 }
270
271 void ModalController_hideAll(entity me, float skipAnimation)
272 {
273         entity e;
274         for(e = me.firstChild; e; e = e.nextSibling)
275                 me.hideChild(me, e, skipAnimation);
276 }
277
278 void ModalController_hideChild(entity me, entity other, float skipAnimation)
279 {
280         if(other.ModalController_state || skipAnimation)
281         {
282                 me.setFocus(me, NULL);
283                 me.switchState(me, other, 0, skipAnimation);
284                 if(other.ModalController_controllingButton)
285                 {
286                         other.ModalController_controllingButton.forcePressed = 0;
287                         other.ModalController_controllingButton = NULL;
288                 }
289         } // just alpha fade out (factor increases and decreases alpha)
290 }
291 #endif