927e07f67423b67f77a470b46621bdb81e05da20
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / slider.c
1 // Note:
2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
3 #ifdef INTERFACE
4 CLASS(Slider) EXTENDS(Label)
5         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector))
6         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string))
7         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float))
8         METHOD(Slider, draw, void(entity))
9         METHOD(Slider, keyDown, float(entity, float, float, float))
10         METHOD(Slider, mousePress, float(entity, vector))
11         METHOD(Slider, mouseDrag, float(entity, vector))
12         METHOD(Slider, mouseRelease, float(entity, vector))
13         METHOD(Slider, focusEnter, void(entity))
14         METHOD(Slider, valueToText, string(entity, float))
15         METHOD(Slider, toString, string(entity))
16         METHOD(Slider, setValue, void(entity, float))
17         METHOD(Slider, setSliderValue, void(entity, float))
18         METHOD(Slider, showNotify, void(entity))
19         ATTRIB(Slider, src, string, string_null)
20         ATTRIB(Slider, focusable, float, 1)
21         ATTRIB(Slider, value, float, 0)
22         ATTRIB(Slider, animated, float, 1)
23         ATTRIB(Slider, sliderValue, float, 0)
24         ATTRIB(Slider, valueMin, float, 0)
25         ATTRIB(Slider, valueMax, float, 0)
26         ATTRIB(Slider, valueStep, float, 0)
27         ATTRIB(Slider, valueDigits, float, 0)
28         ATTRIB(Slider, valueKeyStep, float, 0)
29         ATTRIB(Slider, valuePageStep, float, 0)
30         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
31         ATTRIB(Slider, textSpace, float, 0)
32         ATTRIB(Slider, controlWidth, float, 0)
33         ATTRIB(Slider, pressed, float, 0)
34         ATTRIB(Slider, pressOffset, float, 0)
35         ATTRIB(Slider, previousValue, float, 0)
36         ATTRIB(Slider, tolerance, vector, '0 0 0')
37         ATTRIB(Slider, disabled, float, 0)
38         ATTRIB(Slider, color, vector, '1 1 1')
39         ATTRIB(Slider, color2, vector, '1 1 1')
40         ATTRIB(Slider, colorD, vector, '1 1 1')
41         ATTRIB(Slider, colorC, vector, '1 1 1')
42         ATTRIB(Slider, colorF, vector, '1 1 1')
43         ATTRIB(Slider, disabledAlpha, float, 0.3)
44 ENDCLASS(Slider)
45 #endif
46
47 #ifdef IMPLEMENTATION
48 void Slider_setValue(entity me, float val)
49 {
50         if (me.animated) {
51                 anim.stopObjAnim(anim, me);
52                 anim.removeObjAnim(anim, me);
53                 makeHostedEasing(me, Slider_setSliderValue, easingQuadInOut, 1, me.sliderValue, val);
54         } else {
55                 me.setSliderValue(me, val);
56         }
57         me.value = val;
58 }
59 void Slider_setSliderValue(entity me, float val)
60 {
61         me.sliderValue = val;
62 }
63 string Slider_toString(entity me)
64 {
65         return sprintf(_("%d (%s)"), me.value, me.valueToText(me, me.value));
66 }
67 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
68 {
69         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
70         me.controlWidth = absSize_y / absSize_x;
71 }
72 string Slider_valueToText(entity me, float val)
73 {
74         if(almost_in_bounds(me.valueMin, val, me.valueMax))
75                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
76         return "";
77 }
78 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
79 {
80         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
81         me.textSpace = theTextSpace;
82         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
83         me.src = gfx;
84 }
85 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
86 {
87         me.value = theValue;
88         me.sliderValue = theValue;
89         me.valueStep = theValueStep;
90         me.valueMin = theValueMin;
91         me.valueMax = theValueMax;
92         me.valueKeyStep = theValueKeyStep;
93         me.valuePageStep = theValuePageStep;
94         me.valueDigits = 3;
95         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
96                 me.valueDigits = 2;
97         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
98                 me.valueDigits = 1;
99         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
100                 me.valueDigits = 0;
101 }
102 float Slider_keyDown(entity me, float key, float ascii, float shift)
103 {
104         float inRange;
105         if(me.disabled)
106                 return 0;
107         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
108         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELUP)
109         {
110                 if(inRange)
111                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
112                 else
113                         me.setValue(me, me.valueMax);
114                 return 1;
115         }
116         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELDOWN)
117         {
118                 if(inRange)
119                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
120                 else
121                         me.setValue(me, me.valueMin);
122                 return 1;
123         }
124         if(key == K_PGUP || key == K_KP_PGUP)
125         {
126                 if(inRange)
127                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
128                 else
129                         me.setValue(me, me.valueMax);
130                 return 1;
131         }
132         if(key == K_PGDN || key == K_KP_PGDN)
133         {
134                 if(inRange)
135                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
136                 else
137                         me.setValue(me, me.valueMin);
138                 return 1;
139         }
140         if(key == K_HOME || key == K_KP_HOME)
141         {
142                 me.setValue(me, me.valueMin);
143                 return 1;
144         }
145         if(key == K_END || key == K_KP_END)
146         {
147                 me.setValue(me, me.valueMax);
148                 return 1;
149         }
150         // TODO more keys
151         return 0;
152 }
153 float Slider_mouseDrag(entity me, vector pos)
154 {
155         float hit;
156         float v, animed;
157         if(me.disabled)
158                 return 0;
159
160         anim.finishObjAnim(anim, me);
161         animed = me.animated;
162         me.animated = false;
163
164         if(me.pressed)
165         {
166                 hit = 1;
167                 if(pos_x < 0 - me.tolerance_x) hit = 0;
168                 if(pos_y < 0 - me.tolerance_y) hit = 0;
169                 if(pos_x >= 1 - me.textSpace + me.tolerance_x) hit = 0;
170                 if(pos_y >= 1 + me.tolerance_y) hit = 0;
171                 if(hit)
172                 {
173                         v = median(0, (pos_x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
174                         if(me.valueStep)
175                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
176                         me.setValue(me, v);
177                 }
178                 else
179                         me.setValue(me, me.previousValue);
180         }
181
182         me.animated = animed;
183
184         return 1;
185 }
186 float Slider_mousePress(entity me, vector pos)
187 {
188         float controlCenter;
189         if(me.disabled)
190                 return 0;
191         if(pos_x < 0) return 0;
192         if(pos_y < 0) return 0;
193         if(pos_x >= 1 - me.textSpace) return 0;
194         if(pos_y >= 1) return 0;
195         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
196         if(fabs(pos_x - controlCenter) <= 0.5 * me.controlWidth)
197         {
198                 me.pressed = 1;
199                 me.pressOffset = pos_x - controlCenter;
200                 me.previousValue = me.value;
201                 //me.mouseDrag(me, pos);
202         }
203         else
204         {
205                 float clickValue, pageValue, inRange;
206                 clickValue = median(0, (pos_x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
207                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
208                 if(pos_x < controlCenter)
209                 {
210                         pageValue = me.value - me.valuePageStep;
211                         if(me.valueStep)
212                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
213                         pageValue = max(pageValue, clickValue);
214                         if(inRange)
215                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
216                         else
217                                 me.setValue(me, me.valueMax);
218                 }
219                 else
220                 {
221                         pageValue = me.value + me.valuePageStep;
222                         if(me.valueStep)
223                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
224                         pageValue = min(pageValue, clickValue);
225                         if(inRange)
226                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
227                         else
228                                 me.setValue(me, me.valueMax);
229                 }
230                 if(pageValue == clickValue)
231                 {
232                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
233                         me.pressed = 1;
234                         me.pressOffset = pos_x - controlCenter;
235                         me.previousValue = me.value;
236                         //me.mouseDrag(me, pos);
237                 }
238         }
239         return 1;
240 }
241 float Slider_mouseRelease(entity me, vector pos)
242 {
243         if(cvar("menu_sounds"))
244                 localsound("sound/misc/menu2.wav");
245         me.pressed = 0;
246         if(me.disabled)
247                 return 0;
248         return 1;
249 }
250 void Slider_showNotify(entity me)
251 {
252         me.focusable = !me.disabled;
253 }
254 void Slider_focusEnter(entity me)
255 {
256         if(cvar("menu_sounds") > 1)
257                 localsound("sound/misc/menu1.wav");
258         SUPER(Slider).focusEnter(me);
259 }
260 void Slider_draw(entity me)
261 {
262         float controlLeft;
263         float save;
264         me.focusable = !me.disabled;
265         save = draw_alpha;
266         if(me.disabled)
267                 draw_alpha *= me.disabledAlpha;
268         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
269         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
270         {
271                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
272                 if(me.disabled)
273                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
274                 else if(me.pressed)
275                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
276                 else if(me.focused)
277                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
278                 else
279                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
280         }
281         me.setText(me, me.valueToText(me, me.value));
282         draw_alpha = save;
283         SUPER(Slider).draw(me);
284         me.text = string_null; // TEMPSTRING!
285 }
286 #endif