removing the old slider animations is enough
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / item / slider.c
1 // Note:
2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
3 #ifdef INTERFACE
4 CLASS(Slider) EXTENDS(Label)
5         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector))
6         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string))
7         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float))
8         METHOD(Slider, draw, void(entity))
9         METHOD(Slider, keyDown, float(entity, float, float, float))
10         METHOD(Slider, mousePress, float(entity, vector))
11         METHOD(Slider, mouseDrag, float(entity, vector))
12         METHOD(Slider, mouseRelease, float(entity, vector))
13         METHOD(Slider, focusEnter, void(entity))
14         METHOD(Slider, valueToText, string(entity, float))
15         METHOD(Slider, toString, string(entity))
16         METHOD(Slider, setValue, void(entity, float))
17         METHOD(Slider, setSliderValue, void(entity, float))
18         METHOD(Slider, showNotify, void(entity))
19         ATTRIB(Slider, src, string, string_null)
20         ATTRIB(Slider, focusable, float, 1)
21         ATTRIB(Slider, value, float, 0)
22         ATTRIB(Slider, animated, float, 1)
23         ATTRIB(Slider, sliderValue, float, 0)
24         ATTRIB(Slider, valueMin, float, 0)
25         ATTRIB(Slider, valueMax, float, 0)
26         ATTRIB(Slider, valueStep, float, 0)
27         ATTRIB(Slider, valueDigits, float, 0)
28         ATTRIB(Slider, valueKeyStep, float, 0)
29         ATTRIB(Slider, valuePageStep, float, 0)
30         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
31         ATTRIB(Slider, textSpace, float, 0)
32         ATTRIB(Slider, controlWidth, float, 0)
33         ATTRIB(Slider, pressed, float, 0)
34         ATTRIB(Slider, pressOffset, float, 0)
35         ATTRIB(Slider, previousValue, float, 0)
36         ATTRIB(Slider, tolerance, vector, '0 0 0')
37         ATTRIB(Slider, disabled, float, 0)
38         ATTRIB(Slider, color, vector, '1 1 1')
39         ATTRIB(Slider, color2, vector, '1 1 1')
40         ATTRIB(Slider, colorD, vector, '1 1 1')
41         ATTRIB(Slider, colorC, vector, '1 1 1')
42         ATTRIB(Slider, colorF, vector, '1 1 1')
43         ATTRIB(Slider, disabledAlpha, float, 0.3)
44 ENDCLASS(Slider)
45 #endif
46
47 #ifdef IMPLEMENTATION
48 void Slider_setValue(entity me, float val)
49 {
50         if (me.animated) {
51                 anim.removeObjAnim(anim, me);
52                 makeHostedEasing(me, Slider_setSliderValue, easingQuadInOut, 1, me.sliderValue, val);
53         } else {
54                 me.setSliderValue(me, val);
55         }
56         me.value = val;
57 }
58 void Slider_setSliderValue(entity me, float val)
59 {
60         me.sliderValue = val;
61 }
62 string Slider_toString(entity me)
63 {
64         return sprintf(_("%d (%s)"), me.value, me.valueToText(me, me.value));
65 }
66 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
67 {
68         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
69         me.controlWidth = absSize_y / absSize_x;
70 }
71 string Slider_valueToText(entity me, float val)
72 {
73         if(almost_in_bounds(me.valueMin, val, me.valueMax))
74                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
75         return "";
76 }
77 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
78 {
79         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
80         me.textSpace = theTextSpace;
81         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
82         me.src = gfx;
83 }
84 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
85 {
86         me.value = theValue;
87         me.sliderValue = theValue;
88         me.valueStep = theValueStep;
89         me.valueMin = theValueMin;
90         me.valueMax = theValueMax;
91         me.valueKeyStep = theValueKeyStep;
92         me.valuePageStep = theValuePageStep;
93         me.valueDigits = 3;
94         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
95                 me.valueDigits = 2;
96         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
97                 me.valueDigits = 1;
98         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
99                 me.valueDigits = 0;
100 }
101 float Slider_keyDown(entity me, float key, float ascii, float shift)
102 {
103         float inRange;
104         if(me.disabled)
105                 return 0;
106         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
107         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELUP)
108         {
109                 if(inRange)
110                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
111                 else
112                         me.setValue(me, me.valueMax);
113                 return 1;
114         }
115         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELDOWN)
116         {
117                 if(inRange)
118                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
119                 else
120                         me.setValue(me, me.valueMin);
121                 return 1;
122         }
123         if(key == K_PGUP || key == K_KP_PGUP)
124         {
125                 if(inRange)
126                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
127                 else
128                         me.setValue(me, me.valueMax);
129                 return 1;
130         }
131         if(key == K_PGDN || key == K_KP_PGDN)
132         {
133                 if(inRange)
134                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
135                 else
136                         me.setValue(me, me.valueMin);
137                 return 1;
138         }
139         if(key == K_HOME || key == K_KP_HOME)
140         {
141                 me.setValue(me, me.valueMin);
142                 return 1;
143         }
144         if(key == K_END || key == K_KP_END)
145         {
146                 me.setValue(me, me.valueMax);
147                 return 1;
148         }
149         // TODO more keys
150         return 0;
151 }
152 float Slider_mouseDrag(entity me, vector pos)
153 {
154         float hit;
155         float v, animed;
156         if(me.disabled)
157                 return 0;
158
159         anim.removeObjAnim(anim, me);
160         animed = me.animated;
161         me.animated = false;
162
163         if(me.pressed)
164         {
165                 hit = 1;
166                 if(pos_x < 0 - me.tolerance_x) hit = 0;
167                 if(pos_y < 0 - me.tolerance_y) hit = 0;
168                 if(pos_x >= 1 - me.textSpace + me.tolerance_x) hit = 0;
169                 if(pos_y >= 1 + me.tolerance_y) hit = 0;
170                 if(hit)
171                 {
172                         v = median(0, (pos_x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
173                         if(me.valueStep)
174                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
175                         me.setValue(me, v);
176                 }
177                 else
178                         me.setValue(me, me.previousValue);
179         }
180
181         me.animated = animed;
182
183         return 1;
184 }
185 float Slider_mousePress(entity me, vector pos)
186 {
187         float controlCenter;
188         if(me.disabled)
189                 return 0;
190         if(pos_x < 0) return 0;
191         if(pos_y < 0) return 0;
192         if(pos_x >= 1 - me.textSpace) return 0;
193         if(pos_y >= 1) return 0;
194         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
195         if(fabs(pos_x - controlCenter) <= 0.5 * me.controlWidth)
196         {
197                 me.pressed = 1;
198                 me.pressOffset = pos_x - controlCenter;
199                 me.previousValue = me.value;
200                 //me.mouseDrag(me, pos);
201         }
202         else
203         {
204                 float clickValue, pageValue, inRange;
205                 clickValue = median(0, (pos_x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
206                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
207                 if(pos_x < controlCenter)
208                 {
209                         pageValue = me.value - me.valuePageStep;
210                         if(me.valueStep)
211                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
212                         pageValue = max(pageValue, clickValue);
213                         if(inRange)
214                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
215                         else
216                                 me.setValue(me, me.valueMax);
217                 }
218                 else
219                 {
220                         pageValue = me.value + me.valuePageStep;
221                         if(me.valueStep)
222                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
223                         pageValue = min(pageValue, clickValue);
224                         if(inRange)
225                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
226                         else
227                                 me.setValue(me, me.valueMax);
228                 }
229                 if(pageValue == clickValue)
230                 {
231                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
232                         me.pressed = 1;
233                         me.pressOffset = pos_x - controlCenter;
234                         me.previousValue = me.value;
235                         //me.mouseDrag(me, pos);
236                 }
237         }
238         return 1;
239 }
240 float Slider_mouseRelease(entity me, vector pos)
241 {
242         if(cvar("menu_sounds"))
243                 localsound("sound/misc/menu2.wav");
244         me.pressed = 0;
245         if(me.disabled)
246                 return 0;
247         return 1;
248 }
249 void Slider_showNotify(entity me)
250 {
251         me.focusable = !me.disabled;
252 }
253 void Slider_focusEnter(entity me)
254 {
255         if(cvar("menu_sounds") > 1)
256                 localsound("sound/misc/menu1.wav");
257         SUPER(Slider).focusEnter(me);
258 }
259 void Slider_draw(entity me)
260 {
261         float controlLeft;
262         float save;
263         me.focusable = !me.disabled;
264         save = draw_alpha;
265         if(me.disabled)
266                 draw_alpha *= me.disabledAlpha;
267         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
268         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
269         {
270                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
271                 if(me.disabled)
272                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
273                 else if(me.pressed)
274                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
275                 else if(me.focused)
276                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
277                 else
278                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
279         }
280         me.setText(me, me.valueToText(me, me.value));
281         draw_alpha = save;
282         SUPER(Slider).draw(me);
283         me.text = string_null; // TEMPSTRING!
284 }
285 #endif