qcsrc/menu/item/slider.qc

   1 // Note:
   2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
   3 #ifdef INTERFACE
   4 CLASS(Slider) EXTENDS(Label)
   5         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string))
   7         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float))
   8         METHOD(Slider, draw, void(entity))
   9         METHOD(Slider, keyDown, float(entity, float, float, float))
  10         METHOD(Slider, keyUp, float(entity, float, float, float))
  11         METHOD(Slider, mousePress, float(entity, vector))
  12         METHOD(Slider, mouseDrag, float(entity, vector))
  13         METHOD(Slider, mouseRelease, float(entity, vector))
  14         METHOD(Slider, valueToText, string(entity, float))
  15         METHOD(Slider, toString, string(entity))
  16         METHOD(Slider, setValue, void(entity, float))
  17         METHOD(Slider, setSliderValue, void(entity, float))
  18         METHOD(Slider, showNotify, void(entity))
  19         ATTRIB(Slider, src, string, string_null)
  20         ATTRIB(Slider, focusable, float, 1)
  21         ATTRIB(Slider, allowFocusSound, float, 1)
  22         ATTRIB(Slider, value, float, 0)
  23         ATTRIB(Slider, animated, float, 1)
  24         ATTRIB(Slider, sliderValue, float, 0)
  25         ATTRIB(Slider, valueMin, float, 0)
  26         ATTRIB(Slider, valueMax, float, 0)
  27         ATTRIB(Slider, valueStep, float, 0)
  28         ATTRIB(Slider, valueDigits, float, 0)
  29         ATTRIB(Slider, valueKeyStep, float, 0)
  30         ATTRIB(Slider, valuePageStep, float, 0)
  31         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
  32         ATTRIB(Slider, textSpace, float, 0)
  33         ATTRIB(Slider, controlWidth, float, 0)
  34         ATTRIB(Slider, pressed, float, 0)
  35         ATTRIB(Slider, pressOffset, float, 0)
  36         ATTRIB(Slider, previousValue, float, 0)
  37         ATTRIB(Slider, tolerance, vector, '0 0 0')
  38         ATTRIB(Slider, disabled, float, 0)
  39         ATTRIB(Slider, color, vector, '1 1 1')
  40         ATTRIB(Slider, color2, vector, '1 1 1')
  41         ATTRIB(Slider, colorD, vector, '1 1 1')
  42         ATTRIB(Slider, colorC, vector, '1 1 1')
  43         ATTRIB(Slider, colorF, vector, '1 1 1')
  44         ATTRIB(Slider, disabledAlpha, float, 0.3)
  45 ENDCLASS(Slider)
  46 #endif
  47
  48 #ifdef IMPLEMENTATION
  49 void Slider_setValue(entity me, float val)
  50 {
  51         if (me.animated) {
  52                 anim.removeObjAnim(anim, me);
  53                 makeHostedEasing(me, Slider_setSliderValue, easingQuadInOut, 1, me.sliderValue, val);
  54         } else {
  55                 me.setSliderValue(me, val);
  56         }
  57         me.value = val;
  58 }
  59 void Slider_setSliderValue(entity me, float val)
  60 {
  61         me.sliderValue = val;
  62 }
  63 string Slider_toString(entity me)
  64 {
  65         return sprintf("%d (%s)", me.value, me.valueToText(me, me.value));
  66 }
  67 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  68 {
  69         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  70         me.controlWidth = absSize.y / absSize.x;
  71 }
  72 string Slider_valueToText(entity me, float val)
  73 {
  74         if(almost_in_bounds(me.valueMin, val, me.valueMax))
  75                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
  76         return "";
  77 }
  78 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
  79 {
  80         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
  81         me.textSpace = theTextSpace;
  82         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
  83         me.src = gfx;
  84 }
  85 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
  86 {
  87         me.value = theValue;
  88         me.sliderValue = theValue;
  89         me.valueStep = theValueStep;
  90         me.valueMin = theValueMin;
  91         me.valueMax = theValueMax;
  92         me.valueKeyStep = theValueKeyStep;
  93         me.valuePageStep = theValuePageStep;
  94         me.valueDigits = 3;
  95         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
  96                 me.valueDigits = 2;
  97         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
  98                 me.valueDigits = 1;
  99         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
 100                 me.valueDigits = 0;
 101 }
 102 float Slider_keyDown(entity me, float key, float ascii, float shift)
 103 {
 104         float inRange;
 105         if(me.disabled)
 106                 return 0;
 107         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 108         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELDOWN)
 109         {
 110                 if(inRange)
 111                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
 112                 else
 113                         me.setValue(me, me.valueMax);
 114                 return 1;
 115         }
 116         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELUP)
 117         {
 118                 if(inRange)
 119                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
 120                 else
 121                         me.setValue(me, me.valueMin);
 122                 return 1;
 123         }
 124         if(key == K_PGDN || key == K_KP_PGDN)
 125         {
 126                 if(inRange)
 127                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
 128                 else
 129                         me.setValue(me, me.valueMax);
 130                 return 1;
 131         }
 132         if(key == K_PGUP || key == K_KP_PGUP)
 133         {
 134                 if(inRange)
 135                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
 136                 else
 137                         me.setValue(me, me.valueMin);
 138                 return 1;
 139         }
 140         if(key == K_HOME || key == K_KP_HOME)
 141         {
 142                 me.setValue(me, me.valueMin);
 143                 return 1;
 144         }
 145         if(key == K_END || key == K_KP_END)
 146         {
 147                 me.setValue(me, me.valueMax);
 148                 return 1;
 149         }
 150         // TODO more keys (NOTE also add them to Slider_keyUp)
 151         return 0;
 152 }
 153 float Slider_keyUp(entity me, float key, float ascii, float shift)
 154 {
 155         if(me.disabled)
 156                 return 0;
 157         switch(key)
 158         {
 159                 case K_LEFTARROW:
 160                 case K_KP_LEFTARROW:
 161                 case K_RIGHTARROW:
 162                 case K_KP_RIGHTARROW:
 163                 case K_PGUP:
 164                 case K_KP_PGUP:
 165                 case K_PGDN:
 166                 case K_KP_PGDN:
 167                 case K_HOME:
 168                 case K_KP_HOME:
 169                 case K_END:
 170                 case K_KP_END:
 171                         m_play_click_sound(MENU_SOUND_SLIDE);
 172         }
 173         return 0;
 174 }
 175 float Slider_mouseDrag(entity me, vector pos)
 176 {
 177         float hit;
 178         float v, animed;
 179         if(me.disabled)
 180                 return 0;
 181
 182         anim.removeObjAnim(anim, me);
 183         animed = me.animated;
 184         me.animated = false;
 185
 186         if(me.pressed)
 187         {
 188                 hit = 1;
 189                 if(pos.x < 0 - me.tolerance.x) hit = 0;
 190                 if(pos.y < 0 - me.tolerance.y) hit = 0;
 191                 if(pos.x >= 1 - me.textSpace + me.tolerance.x) hit = 0;
 192                 if(pos.y >= 1 + me.tolerance.y) hit = 0;
 193                 if(hit)
 194                 {
 195                         v = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 196                         if(me.valueStep)
 197                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
 198                         me.setValue(me, v);
 199                 }
 200                 else
 201                         me.setValue(me, me.previousValue);
 202         }
 203
 204         me.animated = animed;
 205
 206         return 1;
 207 }
 208 float Slider_mousePress(entity me, vector pos)
 209 {
 210         float controlCenter;
 211         if(me.disabled)
 212                 return 0;
 213         if(pos.x < 0) return 0;
 214         if(pos.y < 0) return 0;
 215         if(pos.x >= 1 - me.textSpace) return 0;
 216         if(pos.y >= 1) return 0;
 217         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 218         if(fabs(pos.x - controlCenter) <= 0.5 * me.controlWidth)
 219         {
 220                 me.pressed = 1;
 221                 me.pressOffset = pos.x - controlCenter;
 222                 me.previousValue = me.value;
 223                 //me.mouseDrag(me, pos);
 224         }
 225         else
 226         {
 227                 float clickValue, pageValue, inRange;
 228                 clickValue = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 229                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 230                 if(pos.x < controlCenter)
 231                 {
 232                         pageValue = me.value - me.valuePageStep;
 233                         if(me.valueStep)
 234                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
 235                         pageValue = max(pageValue, clickValue);
 236                         if(inRange)
 237                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 238                         else
 239                                 me.setValue(me, me.valueMax);
 240                 }
 241                 else
 242                 {
 243                         pageValue = me.value + me.valuePageStep;
 244                         if(me.valueStep)
 245                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
 246                         pageValue = min(pageValue, clickValue);
 247                         if(inRange)
 248                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 249                         else
 250                                 me.setValue(me, me.valueMax);
 251                 }
 252                 if(pageValue == clickValue)
 253                 {
 254                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 255                         me.pressed = 1;
 256                         me.pressOffset = pos.x - controlCenter;
 257                         me.previousValue = me.value;
 258                         //me.mouseDrag(me, pos);
 259                 }
 260         }
 261         return 1;
 262 }
 263 float Slider_mouseRelease(entity me, vector pos)
 264 {
 265         me.pressed = 0;
 266         if(me.disabled)
 267                 return 0;
 268         m_play_click_sound(MENU_SOUND_SLIDE);
 269         return 1;
 270 }
 271 void Slider_showNotify(entity me)
 272 {
 273         me.focusable = !me.disabled;
 274 }
 275 void Slider_draw(entity me)
 276 {
 277         float controlLeft;
 278         float save;
 279         me.focusable = !me.disabled;
 280         save = draw_alpha;
 281         if(me.disabled)
 282                 draw_alpha *= me.disabledAlpha;
 283         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
 284         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
 285         {
 286                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
 287                 if(me.disabled)
 288                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
 289                 else if(me.pressed)
 290                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
 291                 else if(me.focused)
 292                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
 293                 else
 294                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
 295         }
 296         me.setText(me, me.valueToText(me, me.value));
 297         draw_alpha = save;
 298         SUPER(Slider).draw(me);
 299         me.text = string_null; // TEMPSTRING!
 300 }
 301 #endif