7bec34ea0b0a1ff91aad1c9ed91d051f34ca7fc9
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / menu.qc
1 ///////////////////////////////////////////////
2 // Menu Source File
3 ///////////////////////
4 // This file belongs to dpmod/darkplaces
5 // AK contains all menu functions (especially the required ones)
6 ///////////////////////////////////////////////
7
8 float mouseButtonsPressed;
9 vector menuMousePos;
10 float menuShiftState;
11 float menuPrevTime;
12 float menuAlpha;
13 float menuLogoAlpha;
14 float prevMenuAlpha;
15 float menuInitialized;
16 float menuNotTheFirstFrame;
17 float menuMouseMode;
18
19 void SUB_Null() { };
20
21 void() m_init =
22 {
23         cvar_set("_menu_alpha", "0");
24
25         check_unacceptable_compiler_bugs();
26
27 #ifdef WATERMARK
28         print("^4MQC Build information: ", WATERMARK(), "\n");
29 #endif
30
31         // list all game dirs (TEST)
32         if(cvar("developer"))
33         {
34                 float i;
35                 string s;
36                 for(i = 0; ; ++i)
37                 {
38                         s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
39                         if not(s)
40                                 break;
41                         print(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
42                 }
43         }
44 }
45
46 float MENU_ASPECT = 1.25; // 1280x1024
47 float MENU_MINHEIGHT = 600;
48 float conwidth_s, conheight_s, realconwidth, realconheight, screenconwidth, screenconheight;
49 void draw_reset_cropped()
50 {
51         draw_reset(screenconwidth, screenconheight, 0.5 * (realconwidth - screenconwidth), 0.5 * (realconheight - screenconheight));
52 }
53 void draw_reset_full()
54 {
55         draw_reset(realconwidth, realconheight, 0, 0);
56 }
57 void UpdateConWidthHeight()
58 {
59         conwidth_s = conwidth;
60         conheight_s = conheight;
61         realconwidth = cvar("vid_conwidth");
62         realconheight = cvar("vid_conheight");
63         if(realconwidth / realconheight > MENU_ASPECT)
64         {
65                 // widescreen
66                 conwidth = realconheight * MENU_ASPECT;
67                 conheight = realconheight;
68         }
69         else
70         {
71                 // squarescreen
72                 conwidth = realconwidth;
73                 conheight = realconwidth / MENU_ASPECT;
74         }
75         screenconwidth = conwidth;
76         screenconheight = conheight;
77         if(conwidth < MENU_MINHEIGHT * MENU_ASPECT)
78         {
79                 conheight *= MENU_MINHEIGHT * MENU_ASPECT / conwidth;
80                 conwidth = MENU_MINHEIGHT * MENU_ASPECT;
81         }
82         if(conheight < MENU_MINHEIGHT)
83         {
84                 conwidth *= MENU_MINHEIGHT / conheight;
85                 conheight = MENU_MINHEIGHT;
86         }
87         if(main)
88         {
89                 if(conwidth_s != conwidth || conheight_s != conheight)
90                 {
91                         draw_reset_cropped();
92                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
93                 }
94         }
95 }
96
97 void() m_init_delayed =
98 {
99         float fh, glob, n, i;
100         string s;
101
102         conwidth = conheight = -1;
103         UpdateConWidthHeight();
104         draw_reset_cropped();
105
106         menuInitialized = 0;
107         if(!preMenuInit())
108                 return;
109         menuInitialized = 1;
110         GameCommand_Init();
111
112         RegisterWeapons();
113
114         fh = -1;
115         if(cvar_string("menu_skin") != "")
116         {
117                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
118                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
119         }
120         if(fh < 0)
121         if(cvar_defstring("menu_skin") != "")
122         {
123                 draw_currentSkin = strcat("gfx/menu/", cvar_defstring("menu_skin"));
124                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
125         }
126         if(fh < 0)
127         {
128                 draw_currentSkin = "gfx/menu/default";
129                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
130         }
131         draw_currentSkin = strzone(draw_currentSkin);
132         while((s = fgets(fh)))
133         {
134                 // these two are handled by skinlist.qc
135                 if(substring(s, 0, 6) == "title ")
136                         continue;
137                 if(substring(s, 0, 7) == "author ")
138                         continue;
139                 n = tokenize_console(s);
140                 if(n >= 2)
141                         Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
142         }
143         fclose(fh);
144
145         glob = search_begin(strcat(draw_currentSkin, "/*.tga"), TRUE, TRUE);
146         if(glob >= 0)
147         {
148                 n = search_getsize(glob);
149                 for(i = 0; i < n; ++i)
150                         precache_pic(search_getfilename(glob, i));
151                 search_end(glob);
152         }
153
154         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
155
156         loadTooltips();
157         anim = spawnAnimHost();
158         main = spawnMainWindow(); main.configureMainWindow(main);
159         unloadTooltips();
160
161         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
162         main.focused = 1;
163         menuShiftState = 0;
164         menuMousePos = '0.5 0.5 0';
165
166         if(Menu_Active)
167                 m_display(); // delayed menu display
168 };
169
170 void(float key, float ascii) m_keyup =
171 {
172         if(!menuInitialized)
173                 return;
174         if(!Menu_Active)
175                 return;
176         draw_reset_cropped();
177         main.keyUp(main, key, ascii, menuShiftState);
178         if(key >= K_MOUSE1 && key <= K_MOUSE3)
179         {
180                 --mouseButtonsPressed;
181                 if(!mouseButtonsPressed)
182                         main.mouseRelease(main, menuMousePos);
183                 if(mouseButtonsPressed < 0)
184                 {
185                         mouseButtonsPressed = 0;
186                         print("Warning: released an already released button\n");
187                 }
188         }
189         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
190         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
191         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
192 };
193
194 void(float key, float ascii) m_keydown =
195 {
196         if(!menuInitialized)
197                 return;
198         if(!Menu_Active)
199                 return;
200         if(keyGrabber)
201         {
202                 entity e;
203                 e = keyGrabber;
204                 keyGrabber = NULL;
205                 e.keyGrabbed(e, key, ascii);
206         }
207         else
208         {
209                 draw_reset_cropped();
210                 if(key >= K_MOUSE1 && key <= K_MOUSE3)
211                         if(!mouseButtonsPressed)
212                                 main.mousePress(main, menuMousePos);
213                 if(!main.keyDown(main, key, ascii, menuShiftState))
214                         if(key == K_ESCAPE)
215                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
216                                         m_hide(); // disable menu on unhandled ESC
217         }
218         if(key >= K_MOUSE1 && key <= K_MOUSE3)
219         {
220                 ++mouseButtonsPressed;
221                 if(mouseButtonsPressed > 10)
222                 {
223                         mouseButtonsPressed = 10;
224                         print("Warning: pressed an already pressed button\n");
225                 }
226         }
227         if(key == K_ALT) menuShiftState |= S_ALT;
228         if(key == K_CTRL) menuShiftState |= S_CTRL;
229         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
230 };
231
232 float SCALEMODE_CROP = 0;
233 float SCALEMODE_LETTERBOX = 1;
234 float SCALEMODE_WIDTH = 2;
235 float SCALEMODE_HEIGHT = 3;
236 float SCALEMODE_STRETCH = 4;
237 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
238 {
239         vector sz, org, isz, isz_w, isz_h;
240         float width_is_larger;
241
242         sz = draw_PictureSize(img);
243         width_is_larger = (sz_x * draw_scale_y >= sz_y * draw_scale_x);
244         isz_w = '1 0 0' + '0 1 0' * ((sz_y / sz_x) * (draw_scale_x / draw_scale_y)); 
245         isz_h = '0 1 0' + '1 0 0' * ((sz_x / sz_y) * (draw_scale_y / draw_scale_x)); 
246
247         switch(scalemode)
248         {
249                 default:
250                 case SCALEMODE_CROP:
251                         isz = (width_is_larger ? isz_h : isz_w);
252                         break;
253                 case SCALEMODE_LETTERBOX:
254                         isz = (width_is_larger ? isz_w : isz_h);
255                         break;
256                 case SCALEMODE_WIDTH:
257                         isz = isz_w;
258                         break;
259                 case SCALEMODE_HEIGHT:
260                         isz = isz_h;
261                         break;
262                 case SCALEMODE_STRETCH:
263                         isz = '1 1 0';
264                         break;
265         }
266
267         org = eX * (algn_x * (1 - isz_x)) + eY * (algn_y * (1 - isz_y));
268         draw_Picture(org, img, isz, '1 1 1', a);
269 }
270
271 void(string img, float a, string algn, float force1) drawBackground =
272 {
273         if(main.mainNexposee.ModalController_state == 0)
274                 return;
275
276         vector v;
277         float i, l;
278         string c;
279         float scalemode;
280
281         v_z = 0;
282
283         scalemode = SCALEMODE_CROP;
284
285         for(i = 0; i < strlen(algn); ++i)
286         {
287                 c = substring(algn, i, 1);
288                 switch(c)
289                 {
290                         case "c": scalemode = SCALEMODE_CROP; goto nopic;
291                         case "l": scalemode = SCALEMODE_LETTERBOX; goto nopic;
292                         case "h": scalemode = SCALEMODE_HEIGHT; goto nopic;
293                         case "w": scalemode = SCALEMODE_WIDTH; goto nopic;
294                         case "s": scalemode = SCALEMODE_STRETCH; goto nopic;
295                         case "1": case "4": case "7": v_x = 0.0; break;
296                         case "2": case "5": case "8": v_x = 0.5; break;
297                         case "3": case "6": case "9": v_x = 1.0; break;
298                         default: v_x = random(); break;
299                 }
300                 switch(c)
301                 {
302                         case "7": case "8": case "9": v_y = 0.0; break;
303                         case "4": case "5": case "6": v_y = 0.5; break;
304                         case "1": case "2": case "3": v_y = 1.0; break;
305                         default: v_y = random(); break;
306                 }
307                 if(l == 0)
308                         draw_Picture_Aligned(v, scalemode, img, a);
309                 else if(force1)
310                         // force all secondary layers to use alpha 1. Prevents ugly issues
311                         // with overlap. It's a flag because it cannot be used for the
312                         // ingame background
313                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l+1)), 1);
314                 else
315                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l+1)), a);
316                 ++l;
317 :nopic
318         }
319 }
320
321 vector menuTooltipAveragedMousePos;
322 entity menuTooltipItem;
323 vector menuTooltipOrigin;
324 vector menuTooltipSize;
325 float menuTooltipAlpha;
326 float menuTooltipState; // 0: no tooltip, 1: fading in, 2: displaying, 3: fading out
327 float m_testmousetooltipbox(vector pos)
328 {
329         if(pos_x >= menuTooltipOrigin_x && pos_x < menuTooltipOrigin_x + menuTooltipSize_x)
330         if(pos_y >= menuTooltipOrigin_y && pos_y < menuTooltipOrigin_y + menuTooltipSize_y)
331                 return FALSE;
332         return TRUE;
333 }
334 float m_testtooltipbox(vector tooltippos)
335 {
336         if(tooltippos_x < 0)
337                 return FALSE;
338         if(tooltippos_y < 0)
339                 return FALSE;
340         if(tooltippos_x + menuTooltipSize_x > 1)
341                 return FALSE;
342         if(tooltippos_y + menuTooltipSize_y > 1)
343                 return FALSE;
344         /*
345         menuTooltipOrigin_x = rint(tooltippos_x * cvar("vid_width")) / cvar("vid_width");
346         menuTooltipOrigin_y = rint(tooltippos_y * cvar("vid_height")) / cvar("vid_height");
347         menuTooltipOrigin_z = 0;
348         */
349         menuTooltipOrigin = tooltippos;
350         return TRUE;
351 }
352 float m_allocatetooltipbox(vector pos)
353 {
354         vector avoidplus, avoidminus;
355         vector v;
356
357         avoidplus_x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x) / conwidth;
358         avoidplus_y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y) / conheight;
359         avoidplus_z = 0;
360
361         avoidminus_x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x) / conwidth + menuTooltipSize_x;
362         avoidminus_y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y) / conheight + menuTooltipSize_y;
363         avoidminus_z = 0;
364
365         // bottom right
366         v = pos + avoidplus;
367         if(m_testtooltipbox(v))
368                 return TRUE;
369         
370         // bottom center
371         v_x = pos_x - menuTooltipSize_x * 0.5;
372         if(m_testtooltipbox(v))
373                 return TRUE;
374
375         // bottom left
376         v_x = pos_x - avoidminus_x;
377         if(m_testtooltipbox(v))
378                 return TRUE;
379
380         // top left
381         v_y = pos_y - avoidminus_y;
382         if(m_testtooltipbox(v))
383                 return TRUE;
384
385         // top center
386         v_x = pos_x - menuTooltipSize_x * 0.5;
387         if(m_testtooltipbox(v))
388                 return TRUE;
389         
390         // top right
391         v_x = pos_x + avoidplus_x;
392         if(m_testtooltipbox(v))
393                 return TRUE;
394         
395         return FALSE;
396 }
397 entity m_findtooltipitem(entity root, vector pos)
398 {
399         entity it;
400         entity best;
401
402         best = world;
403         it = root;
404
405         while(it.instanceOfContainer)
406         {
407                 while(it.instanceOfNexposee && it.focusedChild)
408                 {
409                         it = it.focusedChild;
410                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
411                 }
412                 if(it.instanceOfNexposee)
413                 {
414                         it = it.itemFromPoint(it, pos);
415                         if(it.tooltip)
416                                 best = it;
417                         it = world;
418                 }
419                 else if(it.instanceOfModalController)
420                         it = it.focusedChild;
421                 else
422                         it = it.itemFromPoint(it, pos);
423                 if(!it)
424                         break;
425                 if(it.tooltip)
426                         best = it;
427                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
428         }
429
430         return best;
431 }
432 void m_tooltip(vector pos)
433 {
434         float f, i, w;
435         entity it;
436         vector fontsize, p;
437         string s;
438
439         fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
440
441         f = bound(0, frametime * 2, 1);
442         menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
443         f = vlen(pos - menuTooltipAveragedMousePos);
444
445         if(f < 0.01)
446                 it = m_findtooltipitem(main, pos);
447         else    
448                 it = world;
449
450         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out
451         if(it != menuTooltipItem)
452         {
453                 switch(menuTooltipState)
454                 {
455                         case 0:
456                                 if(menuTooltipItem)
457                                 {
458                                         // another item: fade out first
459                                         menuTooltipState = 2;
460                                 }
461                                 else
462                                 {
463                                         // new item: fade in
464                                         menuTooltipState = 1;
465                                         menuTooltipItem = it;
466
467                                         menuTooltipOrigin_x = -1; // unallocated
468                                         i = 0;
469                                         w =  0;
470                                         getWrappedLine_remaining = it.tooltip;
471                                         while(getWrappedLine_remaining)
472                                         {
473                                                 s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
474                                                 ++i;
475                                                 f = draw_TextWidth(s, FALSE, fontsize);
476                                                 if(f > w)
477                                                         w = f;
478                                         }
479                                         menuTooltipSize_x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
480                                         menuTooltipSize_y = i * fontsize_y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
481                                         menuTooltipSize_z = 0;
482                                 }
483                                 break;
484                         case 1:
485                                 // changing item while fading in: fade out first
486                                 menuTooltipState = 2;
487                                 break;
488                         case 2:
489                                 // changing item while fading out: can't
490                                 break;
491                 }
492         }
493         else if(menuTooltipState == 2) // re-fade in?
494                 menuTooltipState = 1;
495
496         if(menuTooltipItem)
497                 if(!m_testmousetooltipbox(pos))
498                         menuTooltipState = 2; // fade out if mouse touches it
499
500         switch(menuTooltipState)
501         {
502                 case 1:
503                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
504                         if(menuTooltipAlpha == 1)
505                                 menuTooltipState = 0;
506                         break;
507                 case 2:
508                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
509                         if(menuTooltipAlpha == 0)
510                         {
511                                 menuTooltipState = 0;
512                                 menuTooltipItem = world;
513                         }
514                         break;
515         }
516
517         if(menuTooltipItem)
518         {
519                 if(menuTooltipOrigin_x < 0) // unallocated?
520                         m_allocatetooltipbox(pos);
521
522                 if(menuTooltipOrigin_x >= 0)
523                 {
524                         // draw the tooltip!
525                         p = SKINBORDER_TOOLTIP;
526                         p_x *= 1 / conwidth;
527                         p_y *= 1 / conheight;
528                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
529                         p = menuTooltipOrigin;
530                         p_x += SKINMARGIN_TOOLTIP_x / conwidth;
531                         p_y += SKINMARGIN_TOOLTIP_y / conheight;
532                         getWrappedLine_remaining = menuTooltipItem.tooltip;
533                         while(getWrappedLine_remaining)
534                         {
535                                 s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
536                                 draw_Text(p, s, fontsize, '1 1 1', SKINALPHA_TOOLTIP * menuTooltipAlpha, FALSE);
537                                 p_y += fontsize_y;
538                         }
539                 }
540         }
541 }
542
543 void() m_draw =
544 {
545         float t;
546         float realFrametime;
547
548         menuMouseMode = cvar("menu_mouse_absolute");
549
550         if (anim)
551                 anim.tickAll(anim);
552
553         if(main)
554                 UpdateConWidthHeight();
555
556         if(!menuInitialized)
557         {
558                 // TODO draw an info image about this situation
559                 m_init_delayed();
560                 return;
561         }
562         if(!menuNotTheFirstFrame)
563         {
564                 menuNotTheFirstFrame = 1;
565                 if(Menu_Active)
566                 if(!cvar("menu_video_played"))
567                 {
568                         localcmd("set menu_video_played 1; cd loop $menu_cdtrack; play sound/announcer/default/welcome.ogg\n");
569                         menuLogoAlpha = -0.8; // no idea why, but when I start this at zero, it jumps instead of fading
570                 }
571         }
572
573         t = gettime();
574         realFrametime = frametime = min(0.2, t - menuPrevTime);
575         menuPrevTime = t;
576         time += frametime;
577
578         t = cvar("menu_slowmo");
579         if(t)
580         {
581                 frametime *= t;
582                 realFrametime *= t;
583         }
584         else
585                 t = 1;
586
587         if(Menu_Active)
588         {
589                 if(getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU) && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
590                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
591                 else
592                         m_hide();
593         }
594
595         if(cvar("cl_capturevideo"))
596                 frametime = t / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
597
598         gamestatus = 0;
599         if(isserver())
600                 gamestatus = gamestatus | GAME_ISSERVER;
601         if(clientstate() == CS_CONNECTED)
602                 gamestatus = gamestatus | GAME_CONNECTED;
603         if(cvar("developer"))
604                 gamestatus = gamestatus | GAME_DEVELOPER;
605
606         prevMenuAlpha = menuAlpha;
607         if(Menu_Active)
608         {
609                 if(menuAlpha == 0 && menuLogoAlpha < 2)
610                 {
611                         menuLogoAlpha = menuLogoAlpha + frametime * 2;
612                 }
613                 else
614                 {
615                         menuAlpha = min(1, menuAlpha + frametime * 5);
616                         menuLogoAlpha = 2;
617                 }
618         }
619         else
620         {
621                 menuAlpha = max(0, menuAlpha - frametime * 5);
622                 menuLogoAlpha = 2;
623         }
624
625         draw_reset_cropped();
626
627         if(!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
628         {
629                 if(menuLogoAlpha > 0)
630                 {
631                         draw_reset_full();
632                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
633                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, TRUE);
634                         draw_reset_cropped();
635                         if(menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
636                         {
637                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
638                                 draw_drawMousePointer(menuMousePos);
639                                 draw_alpha = 1;
640                         }
641                 }
642         }
643         else if(SKINALPHA_BACKGROUND_INGAME)
644         {
645                 if(menuAlpha > 0)
646                 {
647                         draw_reset_full();
648                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME, SKINALIGN_BACKGROUND_INGAME, FALSE);
649                         draw_reset_cropped();
650                 }
651         }
652
653         if(menuAlpha != prevMenuAlpha)
654                 cvar_set("_menu_alpha", ftos(menuAlpha));
655
656         draw_reset_cropped();
657         preMenuDraw();
658         draw_reset_cropped();
659
660         if(menuAlpha <= 0)
661         {
662                 if(prevMenuAlpha > 0)
663                         main.initializeDialog(main, main.firstChild);
664                 draw_reset_cropped();
665                 postMenuDraw();
666                 return;
667         }
668
669         draw_alpha *= menuAlpha;
670
671         if(menuMouseMode)
672         {
673                 vector newMouse;
674                 newMouse = globalToBox(getmousepos(), draw_shift, draw_scale);
675                 if(newMouse != '0 0 0')
676                         if(newMouse != menuMousePos)
677                         {
678                                 menuMousePos = newMouse;
679                                 if(mouseButtonsPressed)
680                                         main.mouseDrag(main, menuMousePos);
681                                 else
682                                         main.mouseMove(main, menuMousePos);
683                         }
684         }
685         else
686         {
687                 if(frametime > 0)
688                 {
689                         vector dMouse, minpos, maxpos;
690                         dMouse = getmousepos() * (frametime / realFrametime); // for capturevideo
691                         if(dMouse != '0 0 0')
692                         {
693                                 minpos = globalToBox('0 0 0', draw_shift, draw_scale);
694                                 maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
695                                 dMouse = globalToBoxSize(dMouse, draw_scale);
696                                 menuMousePos += dMouse * cvar("menu_mouse_speed");
697                                 menuMousePos_x = bound(minpos_x, menuMousePos_x, maxpos_x);
698                                 menuMousePos_y = bound(minpos_y, menuMousePos_y, maxpos_y);
699                                 if(mouseButtonsPressed)
700                                         main.mouseDrag(main, menuMousePos);
701                                 else
702                                         main.mouseMove(main, menuMousePos);
703                         }
704                 }
705         }
706         main.draw(main);
707
708         m_tooltip(menuMousePos);
709
710         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
711
712         draw_drawMousePointer(menuMousePos);
713
714         draw_reset_cropped();
715         postMenuDraw();
716
717         frametime = 0;
718 };
719
720 void() m_display =
721 {
722         Menu_Active = true;
723         setkeydest(KEY_MENU);
724         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
725
726         if(!menuInitialized)
727                 return;
728
729         if(mouseButtonsPressed)
730                 main.mouseRelease(main, menuMousePos);
731         mouseButtonsPressed = 0;
732
733         main.focusEnter(main);
734         main.showNotify(main);
735 };
736
737 void() m_hide =
738 {
739         Menu_Active = false;
740         setkeydest(KEY_GAME);
741         setmousetarget(MT_CLIENT);
742
743         if(!menuInitialized)
744                 return;
745
746         main.focusLeave(main);
747         main.hideNotify(main);
748 };
749
750 void() m_toggle =
751 {
752         if(Menu_Active)
753                 m_hide();
754         else
755                 m_display();
756 };
757
758 void() m_shutdown =
759 {
760         entity e;
761
762         m_hide();
763         for(e = NULL; (e = nextent(e)) != NULL; )
764         {
765                 if(e.classname != "vtbl")
766                         if(e.destroy)
767                                 e.destroy(e);
768         }
769 };
770
771 void m_focus_item_chain(entity outermost, entity innermost)
772 {
773         if(innermost.parent != outermost)
774                 m_focus_item_chain(outermost, innermost.parent);
775         innermost.parent.setFocus(innermost.parent, innermost);
776 }
777
778 void m_activate_window(entity wnd)
779 {
780         entity par;
781         par = wnd.parent;
782         if(par)
783                 m_activate_window(par);
784
785         if(par.instanceOfModalController)
786         {
787                 if(wnd.tabSelectingButton)
788                         // tabs
789                         TabButton_Click(wnd.tabSelectingButton, wnd);
790                 else
791                         // root
792                         par.initializeDialog(par, wnd);
793         }
794         else if(par.instanceOfNexposee)
795         {
796                 // nexposee (sorry for violating abstraction here)
797                 par.selectedChild = wnd;
798                 par.animationState = 1;
799                 Container_setFocus(par, NULL);
800         }
801         else if(par.instanceOfContainer)
802         {
803                 // other containers
804                 if(par.focused)
805                         par.setFocus(par, wnd);
806         }
807 }
808
809 void m_setpointerfocus(entity wnd)
810 {
811         if(wnd.instanceOfContainer)
812         {
813                 entity focus = wnd.preferredFocusedGrandChild(wnd);
814                 if(focus)
815                 {
816                         menuMousePos = focus.origin + 0.5 * focus.size;
817                         menuMousePos_x *= 1 / conwidth;
818                         menuMousePos_y *= 1 / conheight;
819                         if(wnd.focused) // why does this never happen?
820                                 m_focus_item_chain(wnd, focus);
821                 }
822         }
823 }
824
825 void(string itemname) m_goto =
826 {
827         entity e;
828         if(!menuInitialized)
829                 return;
830         if(itemname == "") // this can be called by GameCommand
831         {
832                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
833                         m_hide();
834                 else
835                 {
836                         m_activate_window(main.mainNexposee);
837                         m_display();
838                 }
839         }
840         else
841         {
842                 e = findstring(NULL, name, itemname);
843                 if(e)
844                 {
845                         m_hide();
846                         m_activate_window(e);
847                         m_setpointerfocus(e);
848                         m_display();
849                 }
850         }
851 }
852
853 void() m_goto_skin_selector =
854 {
855         if(!menuInitialized)
856                 return;
857         // TODO add code to switch back to the skin selector (no idea how to do it now)
858         m_goto("skinselector");
859 }
860
861 void() m_goto_video_settings =
862 {
863         if(!menuInitialized)
864                 return;
865         // TODO add code to switch back to the skin selector (no idea how to do it now)
866         m_goto("videosettings");
867 }