Merge branch 'master' into TimePath/issue-1170
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / menu.qc
1 ///////////////////////////////////////////////
2 // Menu Source File
3 ///////////////////////
4 // This file belongs to dpmod/darkplaces
5 // AK contains all menu functions (especially the required ones)
6 ///////////////////////////////////////////////
7
8 float mouseButtonsPressed;
9 vector menuMousePos;
10 float menuShiftState;
11 float menuPrevTime;
12 float menuAlpha;
13 float menuLogoAlpha;
14 float prevMenuAlpha;
15 float menuInitialized;
16 float menuNotTheFirstFrame;
17 float menuMouseMode;
18
19 float conwidth_s, conheight_s, vidwidth_s, vidheight_s, vidpixelheight_s,
20       realconwidth, realconheight;
21
22 void m_sync()
23 {
24         updateCompression();
25         vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // Force updateConwidths on next draw.
26
27         loadAllCvars(main);
28 }
29
30 void m_gamestatus()
31 {
32         gamestatus = 0;
33         if(isserver())
34                 gamestatus = gamestatus | GAME_ISSERVER;
35         if(clientstate() == CS_CONNECTED || isdemo())
36                 gamestatus = gamestatus | GAME_CONNECTED;
37         if(cvar("developer"))
38                 gamestatus = gamestatus | GAME_DEVELOPER;
39 }
40
41 void m_init()
42 {
43         float restarting = 0;
44         cvar_set("_menu_alpha", "0");
45         prvm_language = cvar_string("prvm_language");
46         if(prvm_language == "")
47         {
48                 prvm_language = "en";
49                 cvar_set("prvm_language", prvm_language);
50                 localcmd("\nmenu_restart\n");
51                 restarting = 1;
52         }
53         prvm_language = strzone(prvm_language);
54         cvar_set("_menu_prvm_language", prvm_language);
55
56         check_unacceptable_compiler_bugs();
57
58 #ifdef WATERMARK
59         printf(_("^4MQC Build information: ^1%s\n"), WATERMARK);
60 #endif
61
62         // list all game dirs (TEST)
63         if(cvar("developer"))
64         {
65                 float i;
66                 string s;
67                 for(i = 0; ; ++i)
68                 {
69                         s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
70                         if (!s)
71                                 break;
72                         dprint(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
73                 }
74         }
75
76         // needs to be done so early because of the constants they create
77         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
78         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
79
80         RegisterSLCategories();
81
82         float ddsload = cvar("r_texture_dds_load");
83         float texcomp = cvar("gl_texturecompression");
84         updateCompression();
85         if(ddsload != cvar("r_texture_dds_load") || texcomp != cvar("gl_texturecompression"))
86                 localcmd("\nr_restart\n");
87
88         if(!restarting)
89         {
90                 if(cvar("_menu_initialized")) // always show menu after menu_restart
91                         m_display();
92                 else
93                         m_hide();
94                 cvar_set("_menu_initialized", "1");
95         }
96 }
97
98 const float MENU_ASPECT = 1.25; // 1280x1024
99
100 void draw_reset_cropped()
101 {
102         draw_reset(conwidth, conheight, 0.5 * (realconwidth - conwidth), 0.5 * (realconheight - conheight));
103 }
104 void draw_reset_full()
105 {
106         draw_reset(realconwidth, realconheight, 0, 0);
107 }
108
109 void UpdateConWidthHeight(float w, float h, float p)
110 {
111         if (w != vidwidth_s || h != vidheight_s || p != vidpixelheight_s)
112         {
113                 if (updateConwidths(w, h, p))
114                         localcmd(sprintf("\nexec %s\n", cvar_string("menu_font_cfg")));
115                 vidwidth_s = w;
116                 vidheight_s = h;
117                 vidpixelheight_s = p;
118         }
119         conwidth_s = conwidth;
120         conheight_s = conheight;
121         realconwidth = cvar("vid_conwidth");
122         realconheight = cvar("vid_conheight");
123         if(realconwidth / realconheight > MENU_ASPECT)
124         {
125                 // widescreen
126                 conwidth = realconheight * MENU_ASPECT;
127                 conheight = realconheight;
128         }
129         else
130         {
131                 // squarescreen
132                 conwidth = realconwidth;
133                 conheight = realconwidth / MENU_ASPECT;
134         }
135         if(main)
136         {
137                 if(conwidth_s != conwidth || conheight_s != conheight)
138                 {
139                         draw_reset_cropped();
140                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
141                 }
142         }
143         else
144         {
145                 vidwidth_s = vidheight_s = vidpixelheight_s = 0; // retry next frame
146         }
147 }
148
149 string m_goto_buffer;
150 void m_init_delayed()
151 {
152         float fh, glob, n, i;
153         string s;
154
155         draw_reset_cropped();
156
157         menuInitialized = 0;
158         if(!preMenuInit())
159                 return;
160         menuInitialized = 1;
161
162         fh = -1;
163         if(cvar_string("menu_skin") != "")
164         {
165                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
166                 fh = fopen(language_filename(strcat(draw_currentSkin, "/skinvalues.txt")), FILE_READ);
167         }
168         if(fh < 0)
169         if(cvar_defstring("menu_skin") != "")
170         {
171                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
172                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
173                 fh = fopen(language_filename(strcat(draw_currentSkin, "/skinvalues.txt")), FILE_READ);
174         }
175         if(fh < 0)
176         {
177                 draw_currentSkin = "gfx/menu/default";
178                 fh = fopen(language_filename(strcat(draw_currentSkin, "/skinvalues.txt")), FILE_READ);
179         }
180         if(fh < 0)
181         {
182                 error("cannot load any menu skin\n");
183         }
184         draw_currentSkin = strzone(draw_currentSkin);
185         while((s = fgets(fh)))
186         {
187                 // these two are handled by skinlist.qc
188                 if(substring(s, 0, 6) == "title ")
189                         continue;
190                 if(substring(s, 0, 7) == "author ")
191                         continue;
192                 n = tokenize_console(s);
193                 if(n >= 2)
194                         Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
195         }
196         fclose(fh);
197
198         glob = search_begin(strcat(draw_currentSkin, "/*.tga"), TRUE, TRUE);
199         if(glob >= 0)
200         {
201                 n = search_getsize(glob);
202                 for(i = 0; i < n; ++i)
203                         precache_pic(search_getfilename(glob, i));
204                 search_end(glob);
205         }
206
207         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
208
209         loadTooltips();
210         anim = spawnAnimHost();
211         main = spawnMainWindow(); main.configureMainWindow(main);
212         unloadTooltips();
213
214         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
215         main.focused = 1;
216         menuShiftState = 0;
217         menuMousePos = '0.5 0.5 0';
218
219         m_sync();
220
221         if(m_goto_buffer)
222         {
223                 m_goto(m_goto_buffer);
224                 strunzone(m_goto_buffer);
225                 m_goto_buffer = string_null;
226         }
227
228         if(Menu_Active)
229                 m_display(); // delayed menu display
230 }
231
232 void m_keyup (float key, float ascii)
233 {
234         if(!menuInitialized)
235                 return;
236         if(!Menu_Active)
237                 return;
238         draw_reset_cropped();
239         main.keyUp(main, key, ascii, menuShiftState);
240         if(key >= K_MOUSE1 && key <= K_MOUSE3)
241         {
242                 --mouseButtonsPressed;
243                 if(!mouseButtonsPressed)
244                         main.mouseRelease(main, menuMousePos);
245                 if(mouseButtonsPressed < 0)
246                 {
247                         mouseButtonsPressed = 0;
248                         dprint("Warning: released an already released button\n");
249                 }
250         }
251         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
252         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
253         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
254 }
255
256 void m_keydown(float key, float ascii)
257 {
258         if(!menuInitialized)
259                 return;
260         if(!Menu_Active)
261                 return;
262
263         if(menuMouseMode)
264         if(key >= K_MOUSE1 && key <= K_MOUSE3)
265         {
266                 // detect a click outside of the game window
267                 vector p = getmousepos();
268                 if(p_x < 0 || p_x > realconwidth || p_y < 0 || p_y > realconheight)
269                 {
270                         ++mouseButtonsPressed;
271                         return;
272                 }
273         }
274
275         if(keyGrabber)
276         {
277                 entity e;
278                 e = keyGrabber;
279                 keyGrabber = NULL;
280                 e.keyGrabbed(e, key, ascii);
281         }
282         else
283         {
284                 draw_reset_cropped();
285                 if(key >= K_MOUSE1 && key <= K_MOUSE3)
286                         if(!mouseButtonsPressed)
287                                 main.mousePress(main, menuMousePos);
288                 if(!main.keyDown(main, key, ascii, menuShiftState))
289                         if(key == K_ESCAPE)
290                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
291                                         m_hide(); // disable menu on unhandled ESC
292         }
293         if(key >= K_MOUSE1 && key <= K_MOUSE3)
294         {
295                 ++mouseButtonsPressed;
296                 if(mouseButtonsPressed > 10)
297                 {
298                         mouseButtonsPressed = 10;
299                         dprint("Warning: pressed an already pressed button\n");
300                 }
301         }
302         if(key == K_ALT) menuShiftState |= S_ALT;
303         if(key == K_CTRL) menuShiftState |= S_CTRL;
304         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
305 }
306
307 const float SCALEMODE_CROP = 0;
308 const float SCALEMODE_LETTERBOX = 1;
309 const float SCALEMODE_WIDTH = 2;
310 const float SCALEMODE_HEIGHT = 3;
311 const float SCALEMODE_STRETCH = 4;
312 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
313 {
314         vector sz, org, isz, isz_w, isz_h;
315         float width_is_larger;
316
317         sz = draw_PictureSize(img);
318         width_is_larger = (sz_x * draw_scale_y >= sz_y * draw_scale_x);
319         isz_w = '1 0 0' + '0 1 0' * ((sz_y / sz_x) * (draw_scale_x / draw_scale_y));
320         isz_h = '0 1 0' + '1 0 0' * ((sz_x / sz_y) * (draw_scale_y / draw_scale_x));
321
322 #ifdef GMQCC
323         isz = '0 0 0';
324 #endif
325         switch(scalemode)
326         {
327                 default:
328                 case SCALEMODE_CROP:
329                         isz = (width_is_larger ? isz_h : isz_w);
330                         break;
331                 case SCALEMODE_LETTERBOX:
332                         isz = (width_is_larger ? isz_w : isz_h);
333                         break;
334                 case SCALEMODE_WIDTH:
335                         isz = isz_w;
336                         break;
337                 case SCALEMODE_HEIGHT:
338                         isz = isz_h;
339                         break;
340                 case SCALEMODE_STRETCH:
341                         isz = '1 1 0';
342                         break;
343         }
344
345         org = eX * (algn_x * (1 - isz_x)) + eY * (algn_y * (1 - isz_y));
346         draw_Picture(org, img, isz, '1 1 1', a);
347 }
348
349 void drawBackground(string img, float a, string algn, float force1)
350 {
351         if(main.mainNexposee.ModalController_state == 0)
352                 return;
353
354         vector v;
355         float i, l;
356         string c;
357         float scalemode;
358
359         v_z = 0;
360
361         scalemode = SCALEMODE_CROP;
362
363         l = 0;
364         for(i = 0; i < strlen(algn); ++i)
365         {
366                 c = substring(algn, i, 1);
367                 switch(c)
368                 {
369                         case "c": scalemode = SCALEMODE_CROP; goto nopic;
370                         case "l": scalemode = SCALEMODE_LETTERBOX; goto nopic;
371                         case "h": scalemode = SCALEMODE_HEIGHT; goto nopic;
372                         case "w": scalemode = SCALEMODE_WIDTH; goto nopic;
373                         case "s": scalemode = SCALEMODE_STRETCH; goto nopic;
374                         case "1": case "4": case "7": v_x = 0.0; break;
375                         case "2": case "5": case "8": v_x = 0.5; break;
376                         case "3": case "6": case "9": v_x = 1.0; break;
377                         default: v_x = random(); break;
378                 }
379                 switch(c)
380                 {
381                         case "7": case "8": case "9": v_y = 0.0; break;
382                         case "4": case "5": case "6": v_y = 0.5; break;
383                         case "1": case "2": case "3": v_y = 1.0; break;
384                         default: v_y = random(); break;
385                 }
386                 if(l == 0)
387                         draw_Picture_Aligned(v, scalemode, img, a);
388                 else if(force1)
389                         // force all secondary layers to use alpha 1. Prevents ugly issues
390                         // with overlap. It's a flag because it cannot be used for the
391                         // ingame background
392                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l+1)), 1);
393                 else
394                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l+1)), a);
395                 ++l;
396 :nopic
397         }
398 }
399
400 float menu_tooltips;
401 float menu_tooltips_old;
402 vector menuTooltipAveragedMousePos;
403 entity menuTooltipItem;
404 vector menuTooltipOrigin;
405 vector menuTooltipSize;
406 float menuTooltipAlpha;
407 string menuTooltipText;
408 float menuTooltipState; // 0: static, 1: fading in, 2: fading out
409 float m_testmousetooltipbox(vector pos)
410 {
411         if(pos_x >= menuTooltipOrigin_x && pos_x < menuTooltipOrigin_x + menuTooltipSize_x)
412         if(pos_y >= menuTooltipOrigin_y && pos_y < menuTooltipOrigin_y + menuTooltipSize_y)
413                 return FALSE;
414         return TRUE;
415 }
416 float m_testtooltipbox(vector tooltippos)
417 {
418         if(tooltippos_x < 0)
419                 return FALSE;
420         if(tooltippos_y < 0)
421                 return FALSE;
422         if(tooltippos_x + menuTooltipSize_x > 1)
423                 return FALSE;
424         if(tooltippos_y + menuTooltipSize_y > 1)
425                 return FALSE;
426         menuTooltipOrigin = tooltippos;
427         return TRUE;
428 }
429 float m_allocatetooltipbox(vector pos)
430 {
431         vector avoidplus, avoidminus;
432         vector v;
433
434         avoidplus_x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
435         avoidplus_y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
436         avoidplus_z = 0;
437
438         avoidminus_x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize_x;
439         avoidminus_y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize_y;
440         avoidminus_z = 0;
441
442         // bottom right
443         v = pos + avoidplus;
444         if(m_testtooltipbox(v))
445                 return TRUE;
446
447         // bottom center
448         v_x = pos_x - menuTooltipSize_x * 0.5;
449         if(m_testtooltipbox(v))
450                 return TRUE;
451
452         // bottom left
453         v_x = pos_x - avoidminus_x;
454         if(m_testtooltipbox(v))
455                 return TRUE;
456
457         // top left
458         v_y = pos_y - avoidminus_y;
459         if(m_testtooltipbox(v))
460                 return TRUE;
461
462         // top center
463         v_x = pos_x - menuTooltipSize_x * 0.5;
464         if(m_testtooltipbox(v))
465                 return TRUE;
466
467         // top right
468         v_x = pos_x + avoidplus_x;
469         if(m_testtooltipbox(v))
470                 return TRUE;
471
472         return FALSE;
473 }
474 entity m_findtooltipitem(entity root, vector pos)
475 {
476         entity it;
477         entity best;
478
479         best = world;
480         it = root;
481
482         while(it.instanceOfContainer)
483         {
484                 while(it.instanceOfNexposee && it.focusedChild)
485                 {
486                         it = it.focusedChild;
487                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
488                 }
489                 if(it.instanceOfNexposee)
490                 {
491                         it = it.itemFromPoint(it, pos);
492                         if(it.tooltip)
493                                 best = it;
494                         else if(menu_tooltips == 2 && (it.cvarName || it.onClickCommand))
495                                 best = it;
496                         it = world;
497                 }
498                 else if(it.instanceOfModalController)
499                         it = it.focusedChild;
500                 else
501                         it = it.itemFromPoint(it, pos);
502                 if(!it)
503                         break;
504                 if(it.tooltip)
505                         best = it;
506                 else if(menu_tooltips == 2 && (it.cvarName || it.onClickCommand))
507                         best = it;
508                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
509         }
510
511         return best;
512 }
513 string gettooltip()
514 {
515         if (menu_tooltips == 2)
516         {
517                 string s;
518                 if (menuTooltipItem.cvarName)
519                 {
520                         if (getCvarsMulti(menuTooltipItem))
521                                 s = strcat("[", menuTooltipItem.cvarName, " ", getCvarsMulti(menuTooltipItem), "]");
522                         else
523                                 s = strcat("[", menuTooltipItem.cvarName, "]");
524                 }
525                 else if (menuTooltipItem.onClickCommand)
526                         s = strcat("<", menuTooltipItem.onClickCommand, ">");
527                 else
528                         return menuTooltipItem.tooltip;
529                 if (menuTooltipItem.tooltip)
530                         return strcat(menuTooltipItem.tooltip, " ", s);
531                 return s;
532         }
533         return menuTooltipItem.tooltip;
534 }
535 void m_tooltip(vector pos)
536 {
537         float f, i, w;
538         entity it;
539         vector fontsize, p;
540         string s;
541
542         menu_tooltips = cvar("menu_tooltips");
543         if (!menu_tooltips)
544         {
545                 // don't return immediately, fade out the active tooltip first
546                 if (menuTooltipItem == world)
547                         return;
548                 it = world;
549                 menu_tooltips_old = menu_tooltips;
550         }
551         else
552         {
553                 f = bound(0, frametime * 2, 1);
554                 menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
555                 f = vlen(pos - menuTooltipAveragedMousePos);
556                 if(f < 0.01)
557                         it = m_findtooltipitem(main, pos);
558                 else
559                         it = world;
560         }
561         fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
562
563         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out
564         if(it != menuTooltipItem)
565         {
566                 switch(menuTooltipState)
567                 {
568                         case 0:
569                                 if(menuTooltipItem)
570                                 {
571                                         // another item: fade out first
572                                         menuTooltipState = 2;
573                                 }
574                                 else
575                                 {
576                                         // new item: fade in
577                                         menuTooltipState = 1;
578                                         menuTooltipItem = it;
579
580                                         menuTooltipOrigin_x = -1; // unallocated
581
582                                         if (menuTooltipText)
583                                                 strunzone(menuTooltipText);
584                                         menuTooltipText = strzone(gettooltip());
585
586                                         i = 0;
587                                         w = 0;
588                                         getWrappedLine_remaining = menuTooltipText;
589                                         while(getWrappedLine_remaining)
590                                         {
591                                                 s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
592                                                 ++i;
593                                                 f = draw_TextWidth(s, FALSE, fontsize);
594                                                 if(f > w)
595                                                         w = f;
596                                         }
597                                         menuTooltipSize_x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
598                                         menuTooltipSize_y = i * fontsize_y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
599                                         menuTooltipSize_z = 0;
600                                 }
601                                 break;
602                         case 1:
603                                 // changing item while fading in: fade out first
604                                 menuTooltipState = 2;
605                                 break;
606                         case 2:
607                                 // changing item while fading out: can't
608                                 break;
609                 }
610         }
611         else if(menuTooltipState == 2) // re-fade in?
612                 menuTooltipState = 1;
613
614         if(menuTooltipItem)
615                 if(!m_testmousetooltipbox(pos))
616                         menuTooltipState = 2; // fade out if mouse touches it
617
618         switch(menuTooltipState)
619         {
620                 case 1:
621                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
622                         if(menuTooltipAlpha == 1)
623                                 menuTooltipState = 0;
624                         break;
625                 case 2:
626                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
627                         if(menuTooltipAlpha == 0)
628                         {
629                                 menuTooltipState = 0;
630                                 menuTooltipItem = world;
631                         }
632                         break;
633         }
634
635         if(menuTooltipItem == world)
636         {
637                 if (menuTooltipText)
638                 {
639                         strunzone(menuTooltipText);
640                         menuTooltipText = string_null;
641                 }
642                 return;
643         }
644         else
645         {
646                 if(menu_tooltips != menu_tooltips_old)
647                 {
648                         if (menu_tooltips != 0 && menu_tooltips_old != 0)
649                                 menuTooltipItem = world; // reload tooltip next frame
650                         menu_tooltips_old = menu_tooltips;
651                 }
652                 else if(menuTooltipOrigin_x < 0) // unallocated?
653                         m_allocatetooltipbox(pos);
654
655                 if(menuTooltipOrigin_x >= 0)
656                 {
657                         // draw the tooltip!
658                         p = SKINBORDER_TOOLTIP;
659                         p_x *= 1 / conwidth;
660                         p_y *= 1 / conheight;
661                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
662                         p = menuTooltipOrigin;
663                         p_x += SKINMARGIN_TOOLTIP_x / conwidth;
664                         p_y += SKINMARGIN_TOOLTIP_y / conheight;
665                         getWrappedLine_remaining = menuTooltipText;
666                         while(getWrappedLine_remaining)
667                         {
668                                 s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
669                                 draw_Text(p, s, fontsize, SKINCOLOR_TOOLTIP, SKINALPHA_TOOLTIP * menuTooltipAlpha, FALSE);
670                                 p_y += fontsize_y;
671                         }
672                 }
673         }
674 }
675
676 void m_draw(float width, float height)
677 {
678         float t;
679         float realFrametime;
680
681         m_gamestatus();
682
683         execute_next_frame();
684
685         menuMouseMode = cvar("menu_mouse_absolute");
686
687         if (anim)
688                 anim.tickAll(anim);
689
690         UpdateConWidthHeight(width, height, cvar("vid_pixelheight"));
691
692         if(!menuInitialized)
693         {
694                 // TODO draw an info image about this situation
695                 m_init_delayed();
696                 return;
697         }
698         if(!menuNotTheFirstFrame)
699         {
700                 menuNotTheFirstFrame = 1;
701                 if(Menu_Active)
702                 if(!cvar("menu_video_played"))
703                 {
704                         localcmd("cd loop $menu_cdtrack; play sound/announcer/default/welcome.wav\n");
705                         menuLogoAlpha = -0.8; // no idea why, but when I start this at zero, it jumps instead of fading FIXME
706                 }
707                 // ALWAYS set this cvar; if we start but menu is not active, this means we want no background music!
708                 localcmd("set menu_video_played 1\n");
709         }
710
711         t = gettime();
712         realFrametime = frametime = min(0.2, t - menuPrevTime);
713         menuPrevTime = t;
714         time += frametime;
715
716         t = cvar("menu_slowmo");
717         if(t)
718         {
719                 frametime *= t;
720                 realFrametime *= t;
721         }
722         else
723                 t = 1;
724
725         if(Menu_Active)
726         {
727                 if(getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU) && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
728                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
729                 else
730                         m_hide();
731         }
732
733         if(cvar("cl_capturevideo"))
734                 frametime = t / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
735
736         prevMenuAlpha = menuAlpha;
737         if(Menu_Active)
738         {
739                 if(menuAlpha == 0 && menuLogoAlpha < 2)
740                 {
741                         menuLogoAlpha = menuLogoAlpha + frametime * 2;
742                 }
743                 else
744                 {
745                         menuAlpha = min(1, menuAlpha + frametime * 5);
746                         menuLogoAlpha = 2;
747                 }
748         }
749         else
750         {
751                 menuAlpha = max(0, menuAlpha - frametime * 5);
752                 menuLogoAlpha = 2;
753         }
754
755         draw_reset_cropped();
756
757         if(!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
758         {
759                 if(menuLogoAlpha > 0)
760                 {
761                         draw_reset_full();
762                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
763                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, TRUE);
764                         draw_reset_cropped();
765                         if(menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
766                         {
767                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
768                                 draw_drawMousePointer(menuMousePos);
769                                 draw_alpha = 1;
770                         }
771                 }
772         }
773         else if(SKINALPHA_BACKGROUND_INGAME)
774         {
775                 if(menuAlpha > 0)
776                 {
777                         draw_reset_full();
778                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME, SKINALIGN_BACKGROUND_INGAME, FALSE);
779                         draw_reset_cropped();
780                 }
781         }
782
783         if(menuAlpha != prevMenuAlpha)
784                 cvar_set("_menu_alpha", ftos(menuAlpha));
785
786         draw_reset_cropped();
787         preMenuDraw();
788         draw_reset_cropped();
789
790         if(menuAlpha <= 0)
791         {
792                 if(prevMenuAlpha > 0)
793                         main.initializeDialog(main, main.firstChild);
794                 draw_reset_cropped();
795                 postMenuDraw();
796                 return;
797         }
798
799         draw_alpha *= menuAlpha;
800
801         if(!Menu_Active)
802         {
803                 // do not update mouse position
804                 // it prevents mouse jumping to '0 0 0' when menu is fading out
805         }
806         else if(menuMouseMode)
807         {
808                 vector newMouse;
809                 newMouse = globalToBox(getmousepos(), draw_shift, draw_scale);
810                 if(newMouse != '0 0 0')
811                         if(newMouse != menuMousePos)
812                         {
813                                 menuMousePos = newMouse;
814                                 if(mouseButtonsPressed)
815                                         main.mouseDrag(main, menuMousePos);
816                                 else
817                                         main.mouseMove(main, menuMousePos);
818                         }
819         }
820         else
821         {
822                 if(frametime > 0)
823                 {
824                         vector dMouse, minpos, maxpos;
825                         dMouse = getmousepos() * (frametime / realFrametime); // for capturevideo
826                         if(dMouse != '0 0 0')
827                         {
828                                 minpos = globalToBox('0 0 0', draw_shift, draw_scale);
829                                 maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
830                                 dMouse = globalToBoxSize(dMouse, draw_scale);
831                                 menuMousePos += dMouse * cvar("menu_mouse_speed");
832                                 menuMousePos_x = bound(minpos_x, menuMousePos_x, maxpos_x);
833                                 menuMousePos_y = bound(minpos_y, menuMousePos_y, maxpos_y);
834                                 if(mouseButtonsPressed)
835                                         main.mouseDrag(main, menuMousePos);
836                                 else
837                                         main.mouseMove(main, menuMousePos);
838                         }
839                 }
840         }
841         main.draw(main);
842
843         m_tooltip(menuMousePos);
844
845         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
846
847         draw_drawMousePointer(menuMousePos);
848
849         draw_reset_cropped();
850         postMenuDraw();
851
852         frametime = 0;
853 }
854
855 void m_display()
856 {
857         Menu_Active = true;
858         setkeydest(KEY_MENU);
859         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
860
861         if(!menuInitialized)
862                 return;
863
864         if(mouseButtonsPressed)
865                 main.mouseRelease(main, menuMousePos);
866         mouseButtonsPressed = 0;
867
868         main.focusEnter(main);
869         main.showNotify(main);
870 }
871
872 void m_hide()
873 {
874         Menu_Active = false;
875         setkeydest(KEY_GAME);
876         setmousetarget(MT_CLIENT);
877
878         if(!menuInitialized)
879                 return;
880
881         main.focusLeave(main);
882         main.hideNotify(main);
883 }
884
885 void m_toggle(float mode)
886 {
887         if(Menu_Active)
888         {
889                 if (mode == 1)
890                         return;
891                 m_hide();
892         }
893         else
894         {
895                 if (mode == 0)
896                         return;
897                 m_display();
898         }
899 }
900
901 void Shutdown()
902 {
903         entity e;
904
905         m_hide();
906         for(e = NULL; (e = nextent(e)) != NULL; )
907         {
908                 if(e.classname != "vtbl")
909                         if(e.destroy)
910                                 e.destroy(e);
911         }
912 }
913
914 void m_focus_item_chain(entity outermost, entity innermost)
915 {
916         if(innermost.parent != outermost)
917                 m_focus_item_chain(outermost, innermost.parent);
918         innermost.parent.setFocus(innermost.parent, innermost);
919 }
920
921 void m_activate_window(entity wnd)
922 {
923         entity par;
924         par = wnd.parent;
925         if(par)
926                 m_activate_window(par);
927
928         if(par.instanceOfModalController)
929         {
930                 if(wnd.tabSelectingButton)
931                         // tabs
932                         TabButton_Click(wnd.tabSelectingButton, wnd);
933                 else
934                         // root
935                         par.initializeDialog(par, wnd);
936         }
937         else if(par.instanceOfNexposee)
938         {
939                 // nexposee (sorry for violating abstraction here)
940                 par.selectedChild = wnd;
941                 par.animationState = 1;
942                 Container_setFocus(par, NULL);
943         }
944         else if(par.instanceOfContainer)
945         {
946                 // other containers
947                 if(par.focused)
948                         par.setFocus(par, wnd);
949         }
950 }
951
952 void m_setpointerfocus(entity wnd)
953 {
954         if(wnd.instanceOfContainer)
955         {
956                 entity focus = wnd.preferredFocusedGrandChild(wnd);
957                 if(focus)
958                 {
959                         menuMousePos = focus.origin + 0.5 * focus.size;
960                         menuMousePos_x *= 1 / conwidth;
961                         menuMousePos_y *= 1 / conheight;
962                         if(wnd.focused) // why does this never happen?
963                                 m_focus_item_chain(wnd, focus);
964                 }
965         }
966 }
967
968 void m_goto(string itemname)
969 {
970         entity e;
971         if(!menuInitialized)
972         {
973                 if(m_goto_buffer)
974                         strunzone(m_goto_buffer);
975                 m_goto_buffer = strzone(itemname);
976                 return;
977         }
978         if(itemname == "") // this can be called by GameCommand
979         {
980                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
981                 {
982                         m_hide();
983                 }
984                 else
985                 {
986                         m_activate_window(main.mainNexposee);
987                         m_display();
988                 }
989         }
990         else
991         {
992                 for(e = NULL; (e = find(e, name, itemname)); )
993                         if(e.classname != "vtbl")
994                                 break;
995
996                 if((e) && (!e.requiresConnection || (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))))
997                 {
998                         m_hide();
999                         m_activate_window(e);
1000                         m_setpointerfocus(e);
1001                         m_display();
1002                 }
1003         }
1004 }