qcsrc/menu/menu.qc

   1 #include "menu.qh"
   2
   3 #include "item.qh"
   4
   5 #include "anim/animhost.qh"
   6
   7 #include "item/dialog.qh"
   8 #include "item/listbox.qh"
   9 #include "item/nexposee.qh"
  10
  11 #include "xonotic/commandbutton.qh"
  12 #include "xonotic/mainwindow.qh"
  13 #include "xonotic/serverlist.qh"
  14 #include "xonotic/slider_resolution.qh"
  15
  16 .string cvarName;
  17
  18 #include "xonotic/util.qh"
  19
  20 #include "../common/items/all.qh"
  21 #include <common/weapons/all.qh>
  22 #include "../common/mapinfo.qh"
  23 #include "../common/mutators/base.qh"
  24
  25 int mouseButtonsPressed;
  26 vector menuMousePos;
  27 int menuShiftState;
  28 float menuPrevTime;
  29 float menuAlpha;
  30 float menuLogoAlpha;
  31 float prevMenuAlpha;
  32 bool menuInitialized;
  33 bool menuNotTheFirstFrame;
  34 int menuMouseMode;
  35
  36 float conwidth_s, conheight_s;
  37 float vidwidth_s, vidheight_s, vidpixelheight_s;
  38 float realconwidth, realconheight;
  39
  40 void m_sync()
  41 {
  42         updateCompression();
  43         vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // Force updateConwidths on next draw
  44
  45         loadAllCvars(main);
  46 }
  47
  48 void m_gamestatus()
  49 {
  50         gamestatus = 0;
  51         if (isserver()) gamestatus |= GAME_ISSERVER;
  52         if (clientstate() == CS_CONNECTED || isdemo()) gamestatus |= GAME_CONNECTED;
  53         if (cvar("developer")) gamestatus |= GAME_DEVELOPER;
  54 }
  55
  56 void m_init()
  57 {
  58         bool restarting = false;
  59         cvar_set("_menu_alpha", "0");
  60         prvm_language = cvar_string("prvm_language");
  61         if (prvm_language == "")
  62         {
  63                 prvm_language = "en";
  64                 cvar_set("prvm_language", prvm_language);
  65                 localcmd("\nmenu_restart\n");
  66                 restarting = true;
  67         }
  68         prvm_language = strzone(prvm_language);
  69         cvar_set("_menu_prvm_language", prvm_language);
  70
  71 #ifdef WATERMARK
  72                 LOG_INFOF("^4MQC Build information: ^1%s\n", WATERMARK);
  73 #endif
  74
  75         // list all game dirs (TEST)
  76         if (cvar("developer"))
  77         {
  78                 for (int i = 0; ; ++i)
  79                 {
  80                         string s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
  81                         if (!s) break;
  82                         LOG_TRACE(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
  83                 }
  84         }
  85
  86         // needs to be done so early because of the constants they create
  87         static_init();
  88         static_init_late();
  89         static_init_precache();
  90
  91         RegisterSLCategories();
  92
  93         float ddsload = cvar("r_texture_dds_load");
  94         float texcomp = cvar("gl_texturecompression");
  95         updateCompression();
  96         if (ddsload != cvar("r_texture_dds_load") || texcomp != cvar("gl_texturecompression")) localcmd("\nr_restart\n");
  97
  98         if (!restarting)
  99         {
 100                 if (cvar("_menu_initialized"))  // always show menu after menu_restart
 101                         m_display();
 102                 else m_hide();
 103                 cvar_set("_menu_initialized", "1");
 104         }
 105 }
 106
 107 const float MENU_ASPECT = 1280 / 1024;
 108
 109 void draw_reset_cropped()
 110 {
 111         draw_reset(conwidth, conheight, 0.5 * (realconwidth - conwidth), 0.5 * (realconheight - conheight));
 112 }
 113 void draw_reset_full()
 114 {
 115         draw_reset(realconwidth, realconheight, 0, 0);
 116 }
 117
 118 void UpdateConWidthHeight(float w, float h, float p)
 119 {
 120         if (w != vidwidth_s || h != vidheight_s || p != vidpixelheight_s)
 121         {
 122                 if (updateConwidths(w, h, p)) localcmd(sprintf("\nexec %s\n", cvar_string("menu_font_cfg")));
 123                 vidwidth_s = w;
 124                 vidheight_s = h;
 125                 vidpixelheight_s = p;
 126         }
 127         conwidth_s = conwidth;
 128         conheight_s = conheight;
 129         realconwidth = cvar("vid_conwidth");
 130         realconheight = cvar("vid_conheight");
 131         if (realconwidth / realconheight > MENU_ASPECT)
 132         {
 133                 // widescreen
 134                 conwidth = realconheight * MENU_ASPECT;
 135                 conheight = realconheight;
 136         }
 137         else
 138         {
 139                 // squarescreen
 140                 conwidth = realconwidth;
 141                 conheight = realconwidth / MENU_ASPECT;
 142         }
 143         if (main)
 144         {
 145                 if (conwidth_s != conwidth || conheight_s != conheight)
 146                 {
 147                         draw_reset_cropped();
 148                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 149                 }
 150         }
 151         else
 152         {
 153                 vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // retry next frame
 154         }
 155 }
 156
 157 string m_goto_buffer;
 158 void m_init_delayed()
 159 {
 160         draw_reset_cropped();
 161
 162         menuInitialized = false;
 163         if (!preMenuInit()) return;
 164         menuInitialized = true;
 165
 166         int fh = -1;
 167         if (cvar_string("menu_skin") != "")
 168         {
 169                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 170                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 171         }
 172         if (fh < 0 && cvar_defstring("menu_skin") != "")
 173         {
 174                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
 175                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 176                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 177         }
 178         if (fh < 0)
 179         {
 180                 draw_currentSkin = "gfx/menu/default";
 181                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 182         }
 183         if (fh < 0) error("cannot load any menu skin\n");
 184         draw_currentSkin = strzone(draw_currentSkin);
 185         for (string s; (s = fgets(fh)); )
 186         {
 187                 // these two are handled by skinlist.qc
 188                 if (substring(s, 0, 6) == "title ") continue;
 189                 if (substring(s, 0, 7) == "author ") continue;
 190                 int n = tokenize_console(s);
 191                 if (n < 2) continue;
 192                 Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 193         }
 194         fclose(fh);
 195
 196         int glob = search_begin(strcat(draw_currentSkin, "/*.tga"), true, true);
 197         if (glob >= 0)
 198         {
 199                 for (int i = 0, n = search_getsize(glob); i < n; ++i)
 200                         precache_pic(search_getfilename(glob, i));
 201                 search_end(glob);
 202         }
 203
 204         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 205
 206         anim = NEW(AnimHost);
 207         main = NEW(MainWindow);
 208         main.configureMainWindow(main);
 209
 210         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 211         main.focused = true;
 212         menuShiftState = 0;
 213         menuMousePos = '0.5 0.5 0';
 214
 215         m_sync();
 216
 217         if (m_goto_buffer)
 218         {
 219                 m_goto(m_goto_buffer);
 220                 strunzone(m_goto_buffer);
 221                 m_goto_buffer = string_null;
 222         }
 223
 224         if (Menu_Active) m_display();  // delayed menu display
 225 }
 226
 227 void m_keyup(float key, float ascii)
 228 {
 229         if (!menuInitialized) return;
 230         if (!Menu_Active) return;
 231         draw_reset_cropped();
 232         main.keyUp(main, key, ascii, menuShiftState);
 233         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 234         {
 235                 --mouseButtonsPressed;
 236                 if (!mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 237                 if (mouseButtonsPressed < 0)
 238                 {
 239                         mouseButtonsPressed = 0;
 240                         LOG_TRACE("Warning: released an already released button\n");
 241                 }
 242         }
 243         if (key == K_ALT) menuShiftState &= ~S_ALT;
 244         if (key == K_CTRL) menuShiftState &= ~S_CTRL;
 245         if (key == K_SHIFT) menuShiftState &= ~S_SHIFT;
 246 }
 247
 248 void m_keydown(float key, float ascii)
 249 {
 250         if (!menuInitialized) return;
 251         if (!Menu_Active) return;
 252
 253         if (menuMouseMode && key >= K_MOUSE1 && key <= K_MOUSE3)
 254         {
 255                 // detect a click outside of the game window
 256                 vector p = getmousepos();
 257                 if (p.x < 0 || p.x > realconwidth || p.y < 0 || p.y > realconheight)
 258                 {
 259                         ++mouseButtonsPressed;
 260                         return;
 261                 }
 262         }
 263
 264         if (keyGrabber)
 265         {
 266                 entity e = keyGrabber;
 267                 keyGrabber = NULL;
 268                 e.keyGrabbed(e, key, ascii);
 269         }
 270         else
 271         {
 272                 draw_reset_cropped();
 273                 if (!mouseButtonsPressed && key >= K_MOUSE1 && key <= K_MOUSE3) main.mousePress(main, menuMousePos);
 274                 if (!main.keyDown(main, key, ascii, menuShiftState))
 275                 {
 276                         // disable menu on unhandled ESC
 277                         if (key == K_ESCAPE)
 278                                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))  // don't back out to console only
 279                                         m_hide();
 280                 }
 281         }
 282         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 283         {
 284                 ++mouseButtonsPressed;
 285                 if (mouseButtonsPressed > 10)
 286                 {
 287                         mouseButtonsPressed = 10;
 288                         LOG_TRACE("Warning: pressed an already pressed button\n");
 289                 }
 290         }
 291         if (key == K_ALT) menuShiftState |= S_ALT;
 292         if (key == K_CTRL) menuShiftState |= S_CTRL;
 293         if (key == K_SHIFT) menuShiftState |= S_SHIFT;
 294 }
 295
 296 enum {
 297         SCALEMODE_CROP,
 298         SCALEMODE_LETTERBOX,
 299         SCALEMODE_WIDTH,
 300         SCALEMODE_HEIGHT,
 301         SCALEMODE_STRETCH,
 302 };
 303 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
 304 {
 305         vector sz = draw_PictureSize(img);
 306         bool width_is_larger = (sz.x * draw_scale.y >= sz.y * draw_scale.x);
 307         vector isz_w = '1 0 0' + '0 1 0' * ((sz.y / sz.x) * (draw_scale.x / draw_scale.y));
 308         vector isz_h = '0 1 0' + '1 0 0' * ((sz.x / sz.y) * (draw_scale.y / draw_scale.x));
 309         vector isz;
 310         switch (scalemode)
 311         {
 312                 default:
 313                 case SCALEMODE_CROP:
 314                         isz = (width_is_larger ? isz_h : isz_w);
 315                         break;
 316                 case SCALEMODE_LETTERBOX:
 317                         isz = (width_is_larger ? isz_w : isz_h);
 318                         break;
 319                 case SCALEMODE_WIDTH:
 320                         isz = isz_w;
 321                         break;
 322                 case SCALEMODE_HEIGHT:
 323                         isz = isz_h;
 324                         break;
 325                 case SCALEMODE_STRETCH:
 326                         isz = '1 1 0';
 327                         break;
 328         }
 329         vector org = eX * (algn.x * (1 - isz.x)) + eY * (algn.y * (1 - isz.y));
 330         draw_Picture(org, img, isz, '1 1 1', a);
 331 }
 332
 333 void drawBackground(string img, float a, string algn, float force1)
 334 {
 335         if (main.mainNexposee.ModalController_state == 0) return;
 336         vector v = '0 0 0';
 337         int scalemode = SCALEMODE_CROP;
 338         for (int i = 0, l = 0; i < strlen(algn); ++i)
 339         {
 340                 string c = substring(algn, i, 1);
 341                 switch (c)
 342                 {
 343                         case "c":
 344                                 scalemode = SCALEMODE_CROP;
 345                                 goto nopic;
 346                         case "l":
 347                                 scalemode = SCALEMODE_LETTERBOX;
 348                                 goto nopic;
 349                         case "h":
 350                                 scalemode = SCALEMODE_HEIGHT;
 351                                 goto nopic;
 352                         case "w":
 353                                 scalemode = SCALEMODE_WIDTH;
 354                                 goto nopic;
 355                         case "s":
 356                                 scalemode = SCALEMODE_STRETCH;
 357                                 goto nopic;
 358                         case "1": case "4": case "7":
 359                                 v.x = 0.0;
 360                                 break;
 361                         case "2": case "5": case "8":
 362                                 v.x = 0.5;
 363                                 break;
 364                         case "3": case "6": case "9":
 365                                 v.x = 1.0;
 366                                 break;
 367                         default:
 368                                 v.x = random();
 369                                 break;
 370                 }
 371                 switch (c)
 372                 {
 373                         case "7": case "8": case "9":
 374                                 v.y = 0.0;
 375                                 break;
 376                         case "4": case "5": case "6":
 377                                 v.y = 0.5;
 378                                 break;
 379                         case "1": case "2": case "3":
 380                                 v.y = 1.0;
 381                                 break;
 382                         default:
 383                                 v.y = random();
 384                                 break;
 385                 }
 386                 if (l == 0)
 387                 {
 388                         draw_Picture_Aligned(v, scalemode, img, a);
 389                 }
 390                 else if (force1)
 391                 {
 392                         // force all secondary layers to use alpha 1. Prevents ugly issues
 393                         // with overlap. It's a flag because it cannot be used for the
 394                         // ingame background
 395                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), 1);
 396                 }
 397                 else
 398                 {
 399                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), a);
 400                 }
 401                 ++l;
 402 LABEL(nopic)
 403         }
 404 }
 405
 406 int menu_tooltips;
 407 int menu_tooltips_old;
 408 vector menuTooltipAveragedMousePos;
 409 entity menuTooltipItem;
 410 vector menuTooltipOrigin;
 411 vector menuTooltipSize;
 412 float menuTooltipAlpha;
 413 string menuTooltipText;
 414 int menuTooltipState;  // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 415 bool m_testmousetooltipbox(vector pos)
 416 {
 417         return !(
 418             (pos.x >= menuTooltipOrigin.x && pos.x < menuTooltipOrigin.x + menuTooltipSize.x)
 419             && (pos.y >= menuTooltipOrigin.y && pos.y < menuTooltipOrigin.y + menuTooltipSize.y)
 420                 );
 421 }
 422 bool m_testtooltipbox(vector tooltippos)
 423 {
 424         if (tooltippos.x < 0) return false;
 425         if (tooltippos.y < 0) return false;
 426         if (tooltippos.x + menuTooltipSize.x > 1) return false;
 427         if (tooltippos.y + menuTooltipSize.y > 1) return false;
 428         menuTooltipOrigin = tooltippos;
 429         return true;
 430 }
 431 bool m_allocatetooltipbox(vector pos)
 432 {
 433         vector avoidplus;
 434         avoidplus.x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
 435         avoidplus.y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
 436         avoidplus.z = 0;
 437
 438         vector avoidminus;
 439         avoidminus.x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize.x;
 440         avoidminus.y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize.y;
 441         avoidminus.z = 0;
 442
 443         // bottom right
 444         vector v = pos + avoidplus;
 445         if (m_testtooltipbox(v)) return true;
 446
 447         // bottom center
 448         v.x = pos.x - menuTooltipSize.x * 0.5;
 449         if (m_testtooltipbox(v)) return true;
 450
 451         // bottom left
 452         v.x = pos.x - avoidminus.x;
 453         if (m_testtooltipbox(v)) return true;
 454
 455         // top left
 456         v.y = pos.y - avoidminus.y;
 457         if (m_testtooltipbox(v)) return true;
 458
 459         // top center
 460         v.x = pos.x - menuTooltipSize.x * 0.5;
 461         if (m_testtooltipbox(v)) return true;
 462
 463         // top right
 464         v.x = pos.x + avoidplus.x;
 465         if (m_testtooltipbox(v)) return true;
 466
 467         return false;
 468 }
 469 entity m_findtooltipitem(entity root, vector pos)
 470 {
 471         entity best = NULL;
 472         for (entity it = root; it.instanceOfContainer; )
 473         {
 474                 while (it.instanceOfNexposee && it.focusedChild)
 475                 {
 476                         it = it.focusedChild;
 477                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
 478                 }
 479                 if (it.instanceOfNexposee)
 480                 {
 481                         it = it.itemFromPoint(it, pos);
 482                         if (it.tooltip) best = it;
 483                         else if (menu_tooltips == 2 && (it.cvarName || it.onClickCommand)) best = it;
 484                         it = NULL;
 485                 }
 486                 else if (it.instanceOfModalController)
 487                 {
 488                         it = it.focusedChild;
 489                 }
 490                 else
 491                 {
 492                         it = it.itemFromPoint(it, pos);
 493                 }
 494                 if (!it) break;
 495                 if (it.tooltip) best = it;
 496                 else if (menu_tooltips == 2 && (it.cvarName || it.onClickCommand)) best = it;
 497                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
 498         }
 499
 500         return best;
 501 }
 502 string gettooltip()
 503 {
 504         if (menu_tooltips == 2)
 505         {
 506                 string s;
 507                 if (menuTooltipItem.cvarName)
 508                 {
 509                         if (getCvarsMulti(menuTooltipItem)) s =
 510                                     strcat("[", menuTooltipItem.cvarName, " ", getCvarsMulti(menuTooltipItem), "]");
 511                         else s = strcat("[", menuTooltipItem.cvarName, "]");
 512                 }
 513                 else if (menuTooltipItem.onClickCommand)
 514                 {
 515                         s = strcat("<", menuTooltipItem.onClickCommand, ">");
 516                 }
 517                 else
 518                 {
 519                         return menuTooltipItem.tooltip;
 520                 }
 521                 if (menuTooltipItem.tooltip) return strcat(menuTooltipItem.tooltip, " ", s);
 522                 return s;
 523         }
 524         return menuTooltipItem.tooltip;
 525 }
 526 void m_tooltip(vector pos)
 527 {
 528         static string prev_tooltip;
 529         entity it;
 530         menu_tooltips = cvar("menu_tooltips");
 531         if (!menu_tooltips)
 532         {
 533                 // don't return immediately, fade out the active tooltip first
 534                 if (menuTooltipItem == NULL) return;
 535                 it = NULL;
 536                 menu_tooltips_old = menu_tooltips;
 537         }
 538         else
 539         {
 540                 float f = bound(0, frametime * 2, 1);
 541                 menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
 542                 if (vdist(pos - menuTooltipAveragedMousePos, <, 0.01))
 543                 {
 544                         it = m_findtooltipitem(main, pos);
 545
 546                         if (it.instanceOfListBox && it.isScrolling(it)) it = NULL;
 547
 548                         if (it && prev_tooltip != it.tooltip)
 549                         {
 550                                 // fade out if tooltip of a certain item has changed
 551                                 menuTooltipState = 3;
 552                                 if (prev_tooltip) strunzone(prev_tooltip);
 553                                 prev_tooltip = strzone(it.tooltip);
 554                         }
 555                         else if (menuTooltipItem && !m_testmousetooltipbox(pos))
 556                         {
 557                                 menuTooltipState = 3;  // fade out if mouse touches it
 558                         }
 559                 }
 560                 else
 561                 {
 562                         it = NULL;
 563                 }
 564         }
 565         vector fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
 566
 567         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 568         if (it != menuTooltipItem)
 569         {
 570                 switch (menuTooltipState)
 571                 {
 572                         case 0:
 573                                 if (menuTooltipItem)
 574                                 {
 575                                         // another item: fade out first
 576                                         menuTooltipState = 2;
 577                                 }
 578                                 else
 579                                 {
 580                                         // new item: fade in
 581                                         menuTooltipState = 1;
 582                                         menuTooltipItem = it;
 583
 584                                         menuTooltipOrigin.x = -1;  // unallocated
 585
 586                                         if (menuTooltipText) strunzone(menuTooltipText);
 587                                         menuTooltipText = strzone(gettooltip());
 588
 589                                         int i = 0;
 590                                         float w = 0;
 591                                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining; ++i)
 592                                         {
 593                                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 594                                                 float f = draw_TextWidth(s, false, fontsize);
 595                                                 if (f > w) w = f;
 596                                         }
 597                                         menuTooltipSize.x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
 598                                         menuTooltipSize.y = i * fontsize.y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
 599                                         menuTooltipSize.z = 0;
 600                                 }
 601                                 break;
 602                         case 1:
 603                                 // changing item while fading in: fade out first
 604                                 menuTooltipState = 2;
 605                                 break;
 606                         case 2:
 607                                 // changing item while fading out: can't
 608                                 break;
 609                 }
 610         }
 611         else if (menuTooltipState == 2)  // re-fade in?
 612         {
 613                 menuTooltipState = 1;
 614         }
 615
 616         switch (menuTooltipState)
 617         {
 618                 case 1:  // fade in
 619                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
 620                         if (menuTooltipAlpha == 1) menuTooltipState = 0;
 621                         break;
 622                 case 2:  // fade out
 623                 case 3:  // forced fade out
 624                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
 625                         if (menuTooltipAlpha == 0)
 626                         {
 627                                 menuTooltipState = 0;
 628                                 menuTooltipItem = NULL;
 629                         }
 630                         break;
 631         }
 632
 633         if (menuTooltipItem == NULL)
 634         {
 635                 if (menuTooltipText)
 636                 {
 637                         strunzone(menuTooltipText);
 638                         menuTooltipText = string_null;
 639                 }
 640                 return;
 641         }
 642         else
 643         {
 644                 if (menu_tooltips != menu_tooltips_old)
 645                 {
 646                         if (menu_tooltips != 0 && menu_tooltips_old != 0) menuTooltipItem = NULL; // reload tooltip next frame
 647                         menu_tooltips_old = menu_tooltips;
 648                 }
 649                 else if (menuTooltipOrigin.x < 0)                                             // unallocated?
 650                 {
 651                         m_allocatetooltipbox(pos);
 652                 }
 653                 if (menuTooltipOrigin.x >= 0)
 654                 {
 655                         // draw the tooltip!
 656                         vector p = SKINBORDER_TOOLTIP;
 657                         p.x *= 1 / conwidth;
 658                         p.y *= 1 / conheight;
 659                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
 660                         p = menuTooltipOrigin;
 661                         p.x += SKINMARGIN_TOOLTIP_x / conwidth;
 662                         p.y += SKINMARGIN_TOOLTIP_y / conheight;
 663                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining; p.y += fontsize.y)
 664                         {
 665                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 666                                 draw_Text(p, s, fontsize, SKINCOLOR_TOOLTIP, SKINALPHA_TOOLTIP * menuTooltipAlpha, false);
 667                         }
 668                 }
 669         }
 670 }
 671
 672 void m_draw(float width, float height)
 673 {
 674         if (clientstate() == CS_DISCONNECTED) m_toggle(true);
 675         m_gamestatus();
 676
 677         execute_next_frame();
 678
 679         menuMouseMode = cvar("menu_mouse_absolute");
 680
 681         if (anim) anim.tickAll(anim);
 682
 683         UpdateConWidthHeight(width, height, cvar("vid_pixelheight"));
 684
 685         if (!menuInitialized)
 686         {
 687                 // TODO draw an info image about this situation
 688                 m_init_delayed();
 689                 return;
 690         }
 691         if (!menuNotTheFirstFrame)
 692         {
 693                 menuNotTheFirstFrame = true;
 694                 if (Menu_Active && !cvar("menu_video_played"))
 695         {
 696             localcmd("cd loop $menu_cdtrack; play sound/announcer/default/welcome.wav\n");
 697             menuLogoAlpha = -0.8;  // no idea why, but when I start this at zero, it jumps instead of fading FIXME
 698         }
 699                 // ALWAYS set this cvar; if we start but menu is not active, this means we want no background music!
 700                 localcmd("set menu_video_played 1\n");
 701         }
 702
 703         float t = gettime();
 704         float realFrametime = frametime = min(0.2, t - menuPrevTime);
 705         menuPrevTime = t;
 706         time += frametime;
 707
 708         t = cvar("menu_slowmo");
 709         if (t)
 710         {
 711                 frametime *= t;
 712                 realFrametime *= t;
 713         }
 714         else
 715         {
 716                 t = 1;
 717         }
 718
 719         if (Menu_Active)
 720         {
 721                 if (getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU)
 722                     && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 723                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 724                 else m_hide();
 725         }
 726
 727         if (cvar("cl_capturevideo")) frametime = t / cvar("cl_capturevideo_fps");  // make capturevideo work smoothly
 728
 729         prevMenuAlpha = menuAlpha;
 730         if (Menu_Active)
 731         {
 732                 if (menuAlpha == 0 && menuLogoAlpha < 2)
 733                 {
 734                         menuLogoAlpha += 2 * frametime;
 735                 }
 736                 else
 737                 {
 738                         menuAlpha = min(1, menuAlpha + 5 * frametime);
 739                         menuLogoAlpha = 2;
 740                 }
 741         }
 742         else
 743         {
 744                 menuAlpha = max(0, menuAlpha - 5 * frametime);
 745                 menuLogoAlpha = 2;
 746         }
 747
 748         draw_reset_cropped();
 749
 750         if (!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 751         {
 752                 if (menuLogoAlpha > 0)
 753                 {
 754                         draw_reset_full();
 755                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
 756                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, true);
 757                         draw_reset_cropped();
 758                         if (menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 759                         {
 760                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 761                                 draw_drawMousePointer(menuMousePos);
 762                                 draw_alpha = 1;
 763                         }
 764                 }
 765         }
 766         else if (SKINALPHA_BACKGROUND_INGAME)
 767         {
 768                 if (menuAlpha > 0)
 769                 {
 770                         draw_reset_full();
 771                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME,
 772                                 SKINALIGN_BACKGROUND_INGAME, false);
 773                         draw_reset_cropped();
 774                 }
 775         }
 776
 777         if (menuAlpha != prevMenuAlpha) cvar_set("_menu_alpha", ftos(menuAlpha));
 778
 779         draw_reset_cropped();
 780         preMenuDraw();
 781         draw_reset_cropped();
 782
 783         if (menuAlpha <= 0)
 784         {
 785                 if (prevMenuAlpha > 0) main.initializeDialog(main, main.firstChild);
 786                 draw_reset_cropped();
 787                 postMenuDraw();
 788                 return;
 789         }
 790
 791         draw_alpha *= menuAlpha;
 792
 793         if (!Menu_Active)
 794         {
 795                 // do not update mouse position
 796                 // it prevents mouse jumping to '0 0 0' when menu is fading out
 797         }
 798         else if (menuMouseMode)
 799         {
 800                 vector newMouse = globalToBox(getmousepos(), draw_shift, draw_scale);
 801                 if (newMouse != '0 0 0' && newMouse != menuMousePos)
 802                 {
 803                         menuMousePos = newMouse;
 804                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 805                         else main.mouseMove(main, menuMousePos);
 806                 }
 807         }
 808         else if (frametime > 0)
 809         {
 810                 vector dMouse = getmousepos() * (frametime / realFrametime);  // for capturevideo
 811                 if (dMouse != '0 0 0')
 812                 {
 813                         vector minpos = globalToBox('0 0 0', draw_shift, draw_scale);
 814                         vector maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
 815                         dMouse = globalToBoxSize(dMouse, draw_scale);
 816                         menuMousePos += dMouse * cvar("menu_mouse_speed");
 817                         menuMousePos.x = bound(minpos.x, menuMousePos.x, maxpos.x);
 818                         menuMousePos.y = bound(minpos.y, menuMousePos.y, maxpos.y);
 819                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 820                         else main.mouseMove(main, menuMousePos);
 821                 }
 822         }
 823         main.draw(main);
 824
 825         m_tooltip(menuMousePos);
 826
 827         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 828
 829         draw_drawMousePointer(menuMousePos);
 830
 831         draw_reset_cropped();
 832         postMenuDraw();
 833
 834         frametime = 0;
 835 }
 836
 837 void m_display()
 838 {
 839         Menu_Active = true;
 840         setkeydest(KEY_MENU);
 841         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 842
 843         if (!menuInitialized) return;
 844
 845         if (mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 846         mouseButtonsPressed = 0;
 847
 848         main.focusEnter(main);
 849         main.showNotify(main);
 850 }
 851
 852 void m_hide()
 853 {
 854         Menu_Active = false;
 855         setkeydest(KEY_GAME);
 856         setmousetarget(MT_CLIENT);
 857
 858         if (!menuInitialized) return;
 859
 860         main.focusLeave(main);
 861         main.hideNotify(main);
 862 }
 863
 864 void m_toggle(int mode)
 865 {
 866         if (Menu_Active)
 867         {
 868                 if (mode == 1) return;
 869                 m_hide();
 870         }
 871         else
 872         {
 873                 if (mode == 0) return;
 874                 m_display();
 875         }
 876 }
 877
 878 void Shutdown()
 879 {
 880         m_hide();
 881         FOREACH_ENTITY_ORDERED(it.destroy, {
 882                 if (it.classname == "vtbl") continue;
 883                 it.destroy(it);
 884         });
 885 }
 886
 887 void m_focus_item_chain(entity outermost, entity innermost)
 888 {
 889         if (innermost.parent != outermost) m_focus_item_chain(outermost, innermost.parent);
 890         innermost.parent.setFocus(innermost.parent, innermost);
 891 }
 892
 893 void m_activate_window(entity wnd)
 894 {
 895         entity par = wnd.parent;
 896         if (par) m_activate_window(par);
 897
 898         if (par.instanceOfModalController)
 899         {
 900                 if (wnd.tabSelectingButton)
 901                         // tabs
 902                         TabButton_Click(wnd.tabSelectingButton, wnd);
 903                 else
 904                         // root
 905                         par.initializeDialog(par, wnd);
 906         }
 907         else if (par.instanceOfNexposee)
 908         {
 909                 // nexposee (sorry for violating abstraction here)
 910                 par.selectedChild = wnd;
 911                 par.animationState = 1;
 912                 Container_setFocus(par, NULL);
 913         }
 914         else if (par.instanceOfContainer)
 915         {
 916                 // other containers
 917                 if (par.focused) par.setFocus(par, wnd);
 918         }
 919 }
 920
 921 void m_setpointerfocus(entity wnd)
 922 {
 923         if (!wnd.instanceOfContainer) return;
 924         entity focus = wnd.preferredFocusedGrandChild(wnd);
 925         if (!focus) return;
 926         menuMousePos = focus.origin + 0.5 * focus.size;
 927         menuMousePos.x *= 1 / conwidth;
 928         menuMousePos.y *= 1 / conheight;
 929         entity par = wnd.parent;
 930         if (par.focused) par.setFocus(par, wnd);
 931         if (wnd.focused) m_focus_item_chain(wnd, focus);
 932 }
 933
 934 void m_goto(string itemname)
 935 {
 936         if (!menuInitialized)
 937         {
 938                 if (m_goto_buffer) strunzone(m_goto_buffer);
 939                 m_goto_buffer = strzone(itemname);
 940                 return;
 941         }
 942         if (itemname == "")  // this can be called by GameCommand
 943         {
 944                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 945                 {
 946                         m_hide();
 947                 }
 948                 else
 949                 {
 950                         m_activate_window(main.mainNexposee);
 951                         m_display();
 952                 }
 953         }
 954         else
 955         {
 956                 entity e;
 957                 for (e = NULL; (e = find(e, name, itemname)); )
 958                         if (e.classname != "vtbl") break;
 959
 960                 if ((e) && (!e.requiresConnection || (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))))
 961                 {
 962                         m_hide();
 963                         m_activate_window(e);
 964                         m_setpointerfocus(e);
 965                         m_display();
 966                 }
 967         }
 968 }
 969
 970 void m_play_focus_sound()
 971 {
 972         static float menuLastFocusSoundTime;
 973         if (cvar("menu_sounds") < 2) return;
 974         if (time - menuLastFocusSoundTime <= 0.25) return;
 975         localsound(MENU_SOUND_FOCUS);
 976         menuLastFocusSoundTime = time;
 977 }
 978
 979 void m_play_click_sound(string soundfile)
 980 {
 981         if (!cvar("menu_sounds")) return;
 982         localsound(soundfile);
 983 }