qcsrc/menu/xonotic/campaign.qc

   1 #include "../../common/campaign_common.qh"
   2
   3 #ifdef INTERFACE
   4 CLASS(XonoticCampaignList, XonoticListBox)
   5         METHOD(XonoticCampaignList, configureXonoticCampaignList, void(entity))
   6         ATTRIB(XonoticCampaignList, rowsPerItem, float, 10)
   7         METHOD(XonoticCampaignList, draw, void(entity))
   8         METHOD(XonoticCampaignList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticCampaignList, doubleClickListBoxItem, void(entity, float, vector))
  10         METHOD(XonoticCampaignList, resizeNotify, void(entity, vector, vector, vector, vector))
  11         METHOD(XonoticCampaignList, setSelected, void(entity, float))
  12         METHOD(XonoticCampaignList, keyDown, float(entity, float, float, float))
  13         METHOD(XonoticCampaignList, campaignGo, void(entity, float))
  14         METHOD(XonoticCampaignList, destroy, void(entity))
  15
  16         ATTRIB(XonoticCampaignList, campaignGlob, float, 0)
  17         ATTRIB(XonoticCampaignList, realFontSize, vector, '0 0 0')
  18         ATTRIB(XonoticCampaignList, columnPreviewOrigin, float, 0)
  19         ATTRIB(XonoticCampaignList, columnPreviewSize, float, 0)
  20         ATTRIB(XonoticCampaignList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticCampaignList, columnNameSize, float, 0)
  22         ATTRIB(XonoticCampaignList, columnCheckMarkOrigin, float, 0)
  23         ATTRIB(XonoticCampaignList, columnCheckMarkSize, float, 0)
  24         ATTRIB(XonoticCampaignList, checkMarkOrigin, vector, '0 0 0')
  25         ATTRIB(XonoticCampaignList, checkMarkSize, vector, '0 0 0')
  26         ATTRIB(XonoticCampaignList, realUpperMargin1, float, 0)
  27         ATTRIB(XonoticCampaignList, realUpperMargin2, float, 0)
  28
  29         ATTRIB(XonoticCampaignList, origin, vector, '0 0 0')
  30         ATTRIB(XonoticCampaignList, itemAbsSize, vector, '0 0 0')
  31         ATTRIB(XonoticCampaignList, emptyLineHeight, float, 0.5)
  32
  33         ATTRIB(XonoticCampaignList, campaignIndex, float, 0)
  34         ATTRIB(XonoticCampaignList, cvarName, string, string_null)
  35         METHOD(XonoticCampaignList, loadCvars, void(entity))
  36         METHOD(XonoticCampaignList, saveCvars, void(entity))
  37
  38         ATTRIB(XonoticCampaignList, buttonNext, entity, NULL)
  39         ATTRIB(XonoticCampaignList, buttonPrev, entity, NULL)
  40         ATTRIB(XonoticCampaignList, labelTitle, entity, NULL)
  41 ENDCLASS(XonoticCampaignList)
  42 entity makeXonoticCampaignList();
  43 void CampaignList_LoadMap(entity btn, entity me);
  44 void MultiCampaign_Next(entity btn, entity me);
  45 void MultiCampaign_Prev(entity btn, entity me);
  46 #endif
  47
  48 #ifdef IMPLEMENTATION
  49 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
  50
  51 void rewrapCampaign(float w, float l0, float emptyheight, vector theFontSize)
  52 {
  53         int i, j;
  54         int n;
  55         float l;
  56         string r, s;
  57         for(i = 0; i < campaign_entries; ++i)
  58         {
  59                 l = l0;
  60                 if(campaign_longdesc_wrapped[i])
  61                         strunzone(campaign_longdesc_wrapped[i]);
  62                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  63                 r = "";
  64                 for(j = 0; j < n; ++j)
  65                 {
  66                         s = argv(j);
  67                         if(s == "")
  68                         {
  69                                 l -= emptyheight;
  70                                 r = strcat(r, "\n");
  71                                 continue;
  72                         }
  73
  74                         getWrappedLine_remaining = s;
  75                         while(getWrappedLine_remaining)
  76                         {
  77                                 s = getWrappedLine(w, theFontSize, draw_TextWidth_WithoutColors);
  78                                 if(--l < 0) goto toolong;
  79                                 r = strcat(r, s, "\n");
  80                         }
  81                 }
  82                 goto nottoolong;
  83 :toolong
  84                 while(substring(r, strlen(r) - 1, 1) == "\n")
  85                         r = substring(r, 0, strlen(r) - 1);
  86                 r = strcat(r, "...\n");
  87 :nottoolong
  88                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  89         }
  90 }
  91
  92 entity makeXonoticCampaignList()
  93 {
  94         entity me;
  95         me = NEW(XonoticCampaignList);
  96         me.configureXonoticCampaignList(me);
  97         return me;
  98 }
  99 void XonoticCampaignList_configureXonoticCampaignList(entity me)
 100 {
 101         me.configureXonoticListBox(me);
 102         me.campaignGlob = search_begin("maps/campaign*.txt", true, true);
 103         me.loadCvars(me);
 104         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
 105 }
 106
 107 void XonoticCampaignList_destroy(entity me)
 108 {
 109         if(me.campaignGlob >= 0)
 110                 search_end(me.campaignGlob);
 111 }
 112
 113 void XonoticCampaignList_loadCvars(entity me)
 114 {
 115         // read campaign cvars
 116         if(campaign_name)
 117                 strunzone(campaign_name);
 118         if(me.cvarName)
 119                 strunzone(me.cvarName);
 120         campaign_name = strzone(cvar_string("g_campaign_name"));
 121         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
 122         registercvar(me.cvarName, "", 0); // saved by server QC anyway
 123         CampaignFile_Unload();
 124         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
 125         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
 126         cvar_set(me.cvarName, ftos(me.campaignIndex));
 127         if(me.columnNameSize)
 128                 rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 129         me.nItems = min(me.campaignIndex + 2, campaign_entries);
 130         me.selectedItem = min(me.campaignIndex, me.nItems - 1);
 131         me.scrollPos = me.nItems * me.itemHeight - 1;
 132         if(me.labelTitle)
 133                 me.labelTitle.setText(me.labelTitle, campaign_title);
 134 }
 135
 136 void XonoticCampaignList_saveCvars(entity me)
 137 {
 138         // write campaign cvars
 139         // no reason to do this!
 140         // cvar_set("g_campaign_name", campaign_name);
 141         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 142 }
 143
 144 void XonoticCampaignList_campaignGo(entity me, float step)
 145 {
 146         float canNext, canPrev;
 147         string s;
 148         float i, j, n;
 149
 150         canNext = canPrev = 0;
 151
 152         if(me.campaignGlob >= 0)
 153         {
 154                 n = search_getsize(me.campaignGlob);
 155                 if(n > 0)
 156                 {
 157                         j = -1;
 158                         s = strcat("maps/campaign", campaign_name, ".txt");
 159                         for(i = 0; i < n; ++i)
 160                         {
 161                                 if(search_getfilename(me.campaignGlob, i) == s)
 162                                         j = i;
 163                         }
 164                         if(j < 0)
 165                         {
 166                                 s = strcat("maps/campaign", cvar_defstring("g_campaign_name"), ".txt");
 167                                 for(i = 0; i < n; ++i)
 168                                 {
 169                                         if(search_getfilename(me.campaignGlob, i) == s)
 170                                                 j = i;
 171                                 }
 172                         }
 173                         if(j < 0)
 174                         {
 175                                 if(step >= 0)
 176                                         j = 0;
 177                                 else
 178                                         j = n - 1;
 179                         }
 180                         else
 181                                 j = mod(j + step, n);
 182                         s = search_getfilename(me.campaignGlob, j);
 183                         s = substring(s, 13, strlen(s) - 17);
 184                         cvar_set("g_campaign_name", s);
 185                         me.loadCvars(me);
 186                         canNext = (j != n - 1);
 187                         canPrev = (j != 0);
 188                 }
 189         }
 190
 191         if(me.buttonNext)
 192                 me.buttonNext.disabled = !canNext;
 193         if(me.buttonPrev)
 194                 me.buttonPrev.disabled = !canPrev;
 195 }
 196
 197 void MultiCampaign_Next(entity btn, entity me)
 198 {
 199         me.campaignGo(me, +1);
 200 }
 201 void MultiCampaign_Prev(entity btn, entity me)
 202 {
 203         me.campaignGo(me, -1);
 204 }
 205
 206 void XonoticCampaignList_draw(entity me)
 207 {
 208         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 209                 me.loadCvars(me);
 210         SUPER(XonoticCampaignList).draw(me);
 211 }
 212
 213 void XonoticCampaignList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 214 {
 215         me.itemAbsSize = '0 0 0';
 216         SUPER(XonoticCampaignList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 217
 218         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 219         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 220         me.realUpperMargin1 = 0.5 * me.realFontSize.y;
 221         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize.y;
 222
 223         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 224
 225         me.columnPreviewOrigin = 0;
 226         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 227         me.columnCheckMarkSize = me.checkMarkSize.x;
 228         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize.x;
 229         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 230         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x * 2;
 231
 232         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 233
 234         rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 235 }
 236 void XonoticCampaignList_doubleClickListBoxItem(entity me, float i, vector where)
 237 {
 238         CampaignList_LoadMap(me, me);
 239 }
 240 void XonoticCampaignList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected)
 241 {
 242         string s;
 243         vector theColor;
 244         float theAlpha;
 245         float j, n;
 246         vector o;
 247
 248         if(i < me.campaignIndex)
 249         {
 250                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 251                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 252         }
 253         else if(i == me.campaignIndex)
 254         {
 255                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 256                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 257         }
 258         else
 259         {
 260                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 261                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 262         }
 263
 264         if(isSelected)
 265                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 266
 267         if(draw_PictureSize(strcat("/maps/", campaign_mapname[i])) == '0 0 0')
 268                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 269         else
 270                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 271
 272         if(i < me.campaignIndex)
 273                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 274         if(i <= me.campaignIndex)
 275                 s = campaign_shortdesc[i]; // fteqcc sucks
 276         else
 277                 s = "???";
 278         s = draw_TextShortenToWidth(sprintf(_("Level %d: %s"), i+1, s), me.columnNameSize, 0, me.realFontSize);
 279         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 280
 281         if(i <= me.campaignIndex)
 282         {
 283                 s = campaign_longdesc_wrapped[i];
 284                 n = tokenizebyseparator(s, "\n");
 285                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 286                 for(j = 0; j < n; ++j)
 287                         if(argv(j) != "")
 288                         {
 289                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 290                                 o.y += me.realFontSize.y;
 291                         }
 292                         else
 293                                 o.y += me.realFontSize.y * me.emptyLineHeight;
 294         }
 295 }
 296 void CampaignList_LoadMap(entity btn, entity me)
 297 {
 298         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 299                 return;
 300         CampaignSetup(me.selectedItem);
 301 }
 302
 303 void XonoticCampaignList_setSelected(entity me, float i)
 304 {
 305         // prevent too late items from being played
 306         SUPER(XonoticCampaignList).setSelected(me, min(i, me.campaignIndex));
 307 }
 308
 309 float XonoticCampaignList_keyDown(entity me, float scan, float ascii, float shift)
 310 {
 311         if(scan == K_ENTER || scan == K_SPACE || scan == K_KP_ENTER)
 312                 CampaignList_LoadMap(me, me);
 313         else
 314                 return SUPER(XonoticCampaignList).keyDown(me, scan, ascii, shift);
 315         return 1;
 316 }
 317 #endif