qcsrc/menu/xonotic/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include <common/campaign_common.qh>
   4 #include "inputbox.qh"
   5
   6 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
   7
   8 void rewrapCampaign(float w, float l0, float emptyheight, vector theFontSize)
   9 {
  10         int i, j;
  11         int n;
  12         float l;
  13         string r, s;
  14         for(i = 0; i < campaign_entries; ++i)
  15         {
  16                 l = l0;
  17                 if(campaign_longdesc_wrapped[i])
  18                         strunzone(campaign_longdesc_wrapped[i]);
  19                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  20                 r = "";
  21                 for(j = 0; j < n; ++j)
  22                 {
  23                         s = argv(j);
  24                         if(s == "")
  25                         {
  26                                 l -= emptyheight;
  27                                 r = strcat(r, "\n");
  28                                 continue;
  29                         }
  30
  31                         getWrappedLine_remaining = s;
  32                         while(getWrappedLine_remaining)
  33                         {
  34                                 s = getWrappedLine(w, theFontSize, draw_TextWidth_WithoutColors);
  35                                 if(--l < 0) goto toolong;
  36                                 r = strcat(r, s, "\n");
  37                         }
  38                 }
  39                 goto nottoolong;
  40 LABEL(toolong)
  41                 while(substring(r, strlen(r) - 1, 1) == "\n")
  42                         r = substring(r, 0, strlen(r) - 1);
  43                 r = strcat(r, "...\n");
  44 LABEL(nottoolong)
  45                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  46         }
  47 }
  48
  49 entity makeXonoticCampaignList()
  50 {
  51         entity me;
  52         me = NEW(XonoticCampaignList);
  53         me.configureXonoticCampaignList(me);
  54         return me;
  55 }
  56 void XonoticCampaignList_configureXonoticCampaignList(entity me)
  57 {
  58         me.configureXonoticListBox(me);
  59         me.campaignGlob = search_begin("maps/campaign*.txt", true, true);
  60         me.loadCvars(me);
  61         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
  62 }
  63
  64 void XonoticCampaignList_destroy(entity me)
  65 {
  66         if(me.campaignGlob >= 0)
  67                 search_end(me.campaignGlob);
  68 }
  69
  70 void XonoticCampaignList_loadCvars(entity me)
  71 {
  72         // read campaign cvars
  73         strcpy(campaign_name, cvar_string("g_campaign_name"));
  74         strcpy(me.cvarName, strcat("g_campaign", campaign_name, "_index"));
  75         registercvar(me.cvarName, "", 0); // saved by server QC anyway
  76         CampaignFile_Unload();
  77         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
  78         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
  79         cvar_set(me.cvarName, ftos(me.campaignIndex));
  80         if(me.columnNameSize)
  81                 rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
  82         me.nItems = min(me.campaignIndex + 2, campaign_entries);
  83         me.setSelected(me, min(me.campaignIndex, me.nItems - 1));
  84         if(me.nItems - 1 > me.campaignIndex)
  85                 me.scrollToItem(me, me.nItems - 1);
  86         if(me.labelTitle)
  87                 me.labelTitle.setText(me.labelTitle, campaign_title);
  88 }
  89
  90 void XonoticCampaignList_saveCvars(entity me)
  91 {
  92         // write campaign cvars
  93         // no reason to do this!
  94         // cvar_set("g_campaign_name", campaign_name);
  95         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
  96 }
  97
  98 void XonoticCampaignList_campaignGo(entity me, float step)
  99 {
 100         float canNext, canPrev;
 101         string s;
 102         float i, j, n;
 103
 104         canNext = canPrev = 0;
 105
 106         if(me.campaignGlob >= 0)
 107         {
 108                 n = search_getsize(me.campaignGlob);
 109                 if(n > 0)
 110                 {
 111                         j = -1;
 112                         s = strcat("maps/campaign", campaign_name, ".txt");
 113                         for(i = 0; i < n; ++i)
 114                         {
 115                                 if(search_getfilename(me.campaignGlob, i) == s)
 116                                         j = i;
 117                         }
 118                         if(j < 0)
 119                         {
 120                                 s = strcat("maps/campaign", cvar_defstring("g_campaign_name"), ".txt");
 121                                 for(i = 0; i < n; ++i)
 122                                 {
 123                                         if(search_getfilename(me.campaignGlob, i) == s)
 124                                                 j = i;
 125                                 }
 126                         }
 127                         if(j < 0)
 128                         {
 129                                 if(step >= 0)
 130                                         j = 0;
 131                                 else
 132                                         j = n - 1;
 133                         }
 134                         else
 135                                 j = mod(j + step, n);
 136                         s = search_getfilename(me.campaignGlob, j);
 137                         s = substring(s, 13, strlen(s) - 17);
 138                         cvar_set("g_campaign_name", s);
 139                         me.loadCvars(me);
 140                         canNext = (j != n - 1);
 141                         canPrev = (j != 0);
 142                 }
 143         }
 144
 145         if(me.buttonNext)
 146                 me.buttonNext.disabled = !canNext;
 147         if(me.buttonPrev)
 148                 me.buttonPrev.disabled = !canPrev;
 149 }
 150
 151 void MultiCampaign_Next(entity btn, entity me)
 152 {
 153         me.campaignGo(me, +1);
 154 }
 155 void MultiCampaign_Prev(entity btn, entity me)
 156 {
 157         me.campaignGo(me, -1);
 158 }
 159
 160 void XonoticCampaignList_draw(entity me)
 161 {
 162         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 163                 me.loadCvars(me);
 164         SUPER(XonoticCampaignList).draw(me);
 165 }
 166
 167 void XonoticCampaignList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 168 {
 169         me.itemAbsSize = '0 0 0';
 170         SUPER(XonoticCampaignList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 171
 172         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 173         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 174         me.realUpperMargin1 = 0.5 * me.realFontSize.y;
 175         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize.y;
 176
 177         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 178
 179         me.columnPreviewOrigin = 0;
 180         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 181         me.columnCheckMarkSize = me.checkMarkSize.x;
 182         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize.x;
 183         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 184         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x * 2;
 185
 186         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 187
 188         rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 189 }
 190 void XonoticCampaignList_doubleClickListBoxItem(entity me, float i, vector where)
 191 {
 192         CampaignList_LoadMap(me, me);
 193 }
 194 void XonoticCampaignList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 195 {
 196         string s;
 197         vector theColor;
 198         float theAlpha;
 199         float j, n;
 200         vector o;
 201
 202         if(i < me.campaignIndex)
 203         {
 204                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 205                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 206         }
 207         else if(i == me.campaignIndex)
 208         {
 209                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 210                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 211         }
 212         else
 213         {
 214                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 215                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 216         }
 217
 218         if(isSelected)
 219                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 220         else if(isFocused)
 221         {
 222                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 223                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 224         }
 225
 226         if(draw_PictureSize(strcat("/maps/", campaign_mapname[i])) == '0 0 0')
 227                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 228         else
 229                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 230
 231         if(i < me.campaignIndex)
 232                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 233         if(i <= me.campaignIndex)
 234                 s = campaign_shortdesc[i]; // fteqcc sucks
 235         else
 236                 s = "???";
 237         s = draw_TextShortenToWidth(sprintf(_("Level %d: %s"), i+1, s), me.columnNameSize, 0, me.realFontSize);
 238         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 239
 240         if(i <= me.campaignIndex)
 241         {
 242                 s = campaign_longdesc_wrapped[i];
 243                 n = tokenizebyseparator(s, "\n");
 244                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 245                 for(j = 0; j < n; ++j)
 246                         if(argv(j) != "")
 247                         {
 248                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 249                                 o.y += me.realFontSize.y;
 250                         }
 251                         else
 252                                 o.y += me.realFontSize.y * me.emptyLineHeight;
 253         }
 254 }
 255 void CampaignList_LoadMap(entity btn, entity me)
 256 {
 257         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 258                 return;
 259         CampaignSetup(me.selectedItem);
 260 }
 261
 262 void XonoticCampaignList_setSelected(entity me, float i)
 263 {
 264         // prevent too late items from being played
 265         SUPER(XonoticCampaignList).setSelected(me, min(i, me.campaignIndex));
 266 }
 267
 268 float XonoticCampaignList_keyDown(entity me, float scan, float ascii, float shift)
 269 {
 270         if(scan == K_ENTER || scan == K_SPACE || scan == K_KP_ENTER)
 271                 CampaignList_LoadMap(me, me);
 272         else
 273                 return SUPER(XonoticCampaignList).keyDown(me, scan, ascii, shift);
 274         return 1;
 275 }