qcsrc/menu/xonotic/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include <common/campaign_common.qh>
   4 #include "inputbox.qh"
   5
   6 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
   7
   8 void rewrapCampaign(float w, float l0, float emptyheight, vector theFontSize)
   9 {
  10         int i, j;
  11         int n;
  12         float l;
  13         string r, s;
  14         for(i = 0; i < campaign_entries; ++i)
  15         {
  16                 l = l0;
  17                 if(campaign_longdesc_wrapped[i])
  18                         strunzone(campaign_longdesc_wrapped[i]);
  19                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  20                 r = "";
  21                 for(j = 0; j < n; ++j)
  22                 {
  23                         s = argv(j);
  24                         if(s == "")
  25                         {
  26                                 l -= emptyheight;
  27                                 r = strcat(r, "\n");
  28                                 continue;
  29                         }
  30
  31                         getWrappedLine_remaining = s;
  32                         while(getWrappedLine_remaining)
  33                         {
  34                                 s = getWrappedLine(w, theFontSize, draw_TextWidth_WithoutColors);
  35                                 if(--l < 0) goto toolong;
  36                                 r = strcat(r, s, "\n");
  37                         }
  38                 }
  39                 goto nottoolong;
  40 LABEL(toolong)
  41                 while(substring(r, strlen(r) - 1, 1) == "\n")
  42                         r = substring(r, 0, strlen(r) - 1);
  43                 r = strcat(r, "...\n");
  44 LABEL(nottoolong)
  45                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  46         }
  47 }
  48
  49 entity makeXonoticCampaignList()
  50 {
  51         entity me;
  52         me = NEW(XonoticCampaignList);
  53         me.configureXonoticCampaignList(me);
  54         return me;
  55 }
  56 void XonoticCampaignList_configureXonoticCampaignList(entity me)
  57 {
  58         me.configureXonoticListBox(me);
  59         me.campaignGlob = search_begin("maps/campaign*.txt", true, true);
  60         me.loadCvars(me);
  61         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
  62 }
  63
  64 void XonoticCampaignList_destroy(entity me)
  65 {
  66         if(me.campaignGlob >= 0)
  67                 search_end(me.campaignGlob);
  68 }
  69
  70 void XonoticCampaignList_loadCvars(entity me)
  71 {
  72         // read campaign cvars
  73         if(campaign_name)
  74                 strunzone(campaign_name);
  75         if(me.cvarName)
  76                 strunzone(me.cvarName);
  77         campaign_name = strzone(cvar_string("g_campaign_name"));
  78         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
  79         registercvar(me.cvarName, "", 0); // saved by server QC anyway
  80         CampaignFile_Unload();
  81         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
  82         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
  83         cvar_set(me.cvarName, ftos(me.campaignIndex));
  84         if(me.columnNameSize)
  85                 rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
  86         me.nItems = min(me.campaignIndex + 2, campaign_entries);
  87         me.setSelected(me, min(me.campaignIndex, me.nItems - 1));
  88         if(me.nItems - 1 > me.campaignIndex)
  89                 me.scrollToItem(me, me.nItems - 1);
  90         if(me.labelTitle)
  91                 me.labelTitle.setText(me.labelTitle, campaign_title);
  92 }
  93
  94 void XonoticCampaignList_saveCvars(entity me)
  95 {
  96         // write campaign cvars
  97         // no reason to do this!
  98         // cvar_set("g_campaign_name", campaign_name);
  99         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 100 }
 101
 102 void XonoticCampaignList_campaignGo(entity me, float step)
 103 {
 104         float canNext, canPrev;
 105         string s;
 106         float i, j, n;
 107
 108         canNext = canPrev = 0;
 109
 110         if(me.campaignGlob >= 0)
 111         {
 112                 n = search_getsize(me.campaignGlob);
 113                 if(n > 0)
 114                 {
 115                         j = -1;
 116                         s = strcat("maps/campaign", campaign_name, ".txt");
 117                         for(i = 0; i < n; ++i)
 118                         {
 119                                 if(search_getfilename(me.campaignGlob, i) == s)
 120                                         j = i;
 121                         }
 122                         if(j < 0)
 123                         {
 124                                 s = strcat("maps/campaign", cvar_defstring("g_campaign_name"), ".txt");
 125                                 for(i = 0; i < n; ++i)
 126                                 {
 127                                         if(search_getfilename(me.campaignGlob, i) == s)
 128                                                 j = i;
 129                                 }
 130                         }
 131                         if(j < 0)
 132                         {
 133                                 if(step >= 0)
 134                                         j = 0;
 135                                 else
 136                                         j = n - 1;
 137                         }
 138                         else
 139                                 j = mod(j + step, n);
 140                         s = search_getfilename(me.campaignGlob, j);
 141                         s = substring(s, 13, strlen(s) - 17);
 142                         cvar_set("g_campaign_name", s);
 143                         me.loadCvars(me);
 144                         canNext = (j != n - 1);
 145                         canPrev = (j != 0);
 146                 }
 147         }
 148
 149         if(me.buttonNext)
 150                 me.buttonNext.disabled = !canNext;
 151         if(me.buttonPrev)
 152                 me.buttonPrev.disabled = !canPrev;
 153 }
 154
 155 void MultiCampaign_Next(entity btn, entity me)
 156 {
 157         me.campaignGo(me, +1);
 158 }
 159 void MultiCampaign_Prev(entity btn, entity me)
 160 {
 161         me.campaignGo(me, -1);
 162 }
 163
 164 void XonoticCampaignList_draw(entity me)
 165 {
 166         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 167                 me.loadCvars(me);
 168         SUPER(XonoticCampaignList).draw(me);
 169 }
 170
 171 void XonoticCampaignList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 172 {
 173         me.itemAbsSize = '0 0 0';
 174         SUPER(XonoticCampaignList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 175
 176         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 177         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 178         me.realUpperMargin1 = 0.5 * me.realFontSize.y;
 179         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize.y;
 180
 181         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 182
 183         me.columnPreviewOrigin = 0;
 184         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 185         me.columnCheckMarkSize = me.checkMarkSize.x;
 186         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize.x;
 187         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 188         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x * 2;
 189
 190         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 191
 192         rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 193 }
 194 void XonoticCampaignList_doubleClickListBoxItem(entity me, float i, vector where)
 195 {
 196         CampaignList_LoadMap(me, me);
 197 }
 198 void XonoticCampaignList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 199 {
 200         string s;
 201         vector theColor;
 202         float theAlpha;
 203         float j, n;
 204         vector o;
 205
 206         if(i < me.campaignIndex)
 207         {
 208                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 209                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 210         }
 211         else if(i == me.campaignIndex)
 212         {
 213                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 214                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 215         }
 216         else
 217         {
 218                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 219                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 220         }
 221
 222         if(isSelected)
 223                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 224         else if(isFocused)
 225         {
 226                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 227                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 228         }
 229
 230         if(draw_PictureSize(strcat("/maps/", campaign_mapname[i])) == '0 0 0')
 231                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 232         else
 233                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 234
 235         if(i < me.campaignIndex)
 236                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 237         if(i <= me.campaignIndex)
 238                 s = campaign_shortdesc[i]; // fteqcc sucks
 239         else
 240                 s = "???";
 241         s = draw_TextShortenToWidth(sprintf(_("Level %d: %s"), i+1, s), me.columnNameSize, 0, me.realFontSize);
 242         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 243
 244         if(i <= me.campaignIndex)
 245         {
 246                 s = campaign_longdesc_wrapped[i];
 247                 n = tokenizebyseparator(s, "\n");
 248                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 249                 for(j = 0; j < n; ++j)
 250                         if(argv(j) != "")
 251                         {
 252                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 253                                 o.y += me.realFontSize.y;
 254                         }
 255                         else
 256                                 o.y += me.realFontSize.y * me.emptyLineHeight;
 257         }
 258 }
 259 void CampaignList_LoadMap(entity btn, entity me)
 260 {
 261         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 262                 return;
 263         CampaignSetup(me.selectedItem);
 264 }
 265
 266 void XonoticCampaignList_setSelected(entity me, float i)
 267 {
 268         // prevent too late items from being played
 269         SUPER(XonoticCampaignList).setSelected(me, min(i, me.campaignIndex));
 270 }
 271
 272 float XonoticCampaignList_keyDown(entity me, float scan, float ascii, float shift)
 273 {
 274         if(scan == K_ENTER || scan == K_SPACE || scan == K_KP_ENTER)
 275                 CampaignList_LoadMap(me, me);
 276         else
 277                 return SUPER(XonoticCampaignList).keyDown(me, scan, ascii, shift);
 278         return 1;
 279 }