qcsrc/menu/xonotic/charmap.qc

   1 #ifndef CHARMAP_H
   2 #define CHARMAP_H
   3 #include "picker.qc"
   4 CLASS(XonoticCharmap, XonoticPicker)
   5         METHOD(XonoticCharmap, configureXonoticCharmap, void(entity, entity));
   6         METHOD(XonoticCharmap, focusLeave, void(entity));
   7         METHOD(XonoticCharmap, resizeNotify, void(entity, vector, vector, vector, vector));
   8         METHOD(XonoticCharmap, keyDown, float(entity, float, float, float));
   9         ATTRIB(XonoticCharmap, inputBox, entity, NULL)
  10         ATTRIB(XonoticCharmap, realFontSize, vector, '0 0 0')
  11
  12         ATTRIB(XonoticCharmap, rows, float, 10)
  13         ATTRIB(XonoticCharmap, columns, float, 14)
  14
  15         METHOD(XonoticCharmap, cellSelect, void(entity, vector));
  16         METHOD(XonoticCharmap, cellIsValid, bool(entity, vector));
  17         METHOD(XonoticCharmap, cellDraw, void(entity, vector, vector));
  18         ATTRIB(XonoticCharmap, charOffset, vector, '0 0 0')
  19 ENDCLASS(XonoticCharmap)
  20 entity makeXonoticCharmap(entity controlledInputBox);
  21 #endif
  22
  23 #ifdef IMPLEMENTATION
  24
  25 string CHARMAP =
  26         "★◆■▮▰▬◣◤◥◢◀▲▶▼"
  27         "🌍🌎🌏🚀🌌👽🔫⌖❇❈←↑→↓"
  28         "☠☣☢⚛⚡⚙🔥❌⚠⛔❰❱❲❳"
  29         "😃😊😁😄😆😎😈😇😉😛😝😘❤ "
  30         "😐😒😕😮😲😞😟😠😣😭😵😴  "
  31         "\xEE\x83\xA1\xEE\x83\xA2\xEE\x83\xA3\xEE\x83\xA4\xEE\x83\xA5\xEE\x83\xA6\xEE\x83\xA7"
  32         "\xEE\x83\xA8\xEE\x83\xA9\xEE\x83\xAA\xEE\x83\xAB\xEE\x83\xAC\xEE\x83\xAD\xEE\x83\xAE"
  33         "\xEE\x83\xAF\xEE\x83\xB0\xEE\x83\xB1\xEE\x83\xB2\xEE\x83\xB3\xEE\x83\xB4\xEE\x83\xB5"
  34         "\xEE\x83\xB6\xEE\x83\xB7\xEE\x83\xB8\xEE\x83\xB9\xEE\x83\xBA\xEE\x80\x90\xEE\x80\x91"
  35         "\xEE\x82\xB0\xEE\x82\xB1\xEE\x82\xB2\xEE\x82\xB3\xEE\x82\xB4\xEE\x82\xB5\xEE\x82\xB6"
  36         "\xEE\x82\xB7\xEE\x82\xB8\xEE\x82\xB9\xEE\x82\xA1\xEE\x82\xBF\xEE\x82\xA6\xEE\x82\xA5"
  37         "\xEE\x83\x81\xEE\x83\x82\xEE\x83\x83\xEE\x83\x84\xEE\x83\x85\xEE\x83\x86\xEE\x83\x87"
  38         "\xEE\x83\x88\xEE\x83\x89\xEE\x83\x8A\xEE\x83\x8B\xEE\x83\x8C\xEE\x83\x8D\xEE\x83\x8E"
  39         "\xEE\x83\x8F\xEE\x83\x90\xEE\x83\x91\xEE\x83\x92\xEE\x83\x93\xEE\x83\x94\xEE\x83\x95"
  40         "\xEE\x83\x96\xEE\x83\x97\xEE\x83\x98\xEE\x83\x99\xEE\x83\x9A\xEE\x81\x9B\xEE\x81\x9D";
  41
  42 string charmap_cellToChar(entity me, vector cell)
  43 {
  44         string character = substring(CHARMAP, cell.y * me.columns + cell.x, 1);
  45
  46         if(character != " ")
  47                 return character;
  48         else
  49                 return "";
  50 }
  51
  52 entity makeXonoticCharmap(entity controlledInputBox)
  53 {
  54         entity me;
  55         me = NEW(XonoticCharmap);
  56         me.configureXonoticCharmap(me, controlledInputBox);
  57         return me;
  58 }
  59
  60 void XonoticCharmap_configureXonoticCharmap(entity me, entity controlledInputBox)
  61 {
  62         me.inputBox = controlledInputBox;
  63         me.configureXonoticPicker(me);
  64 }
  65
  66 void XonoticCharmap_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  67 {
  68         SUPER(XonoticCharmap).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  69
  70         float maxFontWidth = SKINFONTSIZE_NORMAL / absSize.x;
  71         float maxFontHeight = SKINFONTSIZE_NORMAL / absSize.y;
  72
  73         if((me.realCellSize.x * absSize.x) > (me.realCellSize.y * absSize.y))
  74         {
  75                 me.realFontSize_x = me.realCellSize.y * absSize.y / absSize.x;
  76                 me.realFontSize_y = me.realCellSize.y;
  77         }
  78         else
  79         {
  80                 me.realFontSize_x = me.realCellSize.x;
  81                 me.realFontSize_y = me.realCellSize.x * absSize.x / absSize.y;
  82         }
  83
  84         if(me.realFontSize.x > maxFontWidth || me.realFontSize.y > maxFontHeight)
  85                 me.realFontSize = eX * maxFontWidth + eY * maxFontHeight;
  86
  87         me.charOffset = eX * me.realCellSize.x / 2 + eY * ((me.realCellSize.y - me.realFontSize.y) / 2);
  88 }
  89
  90 float XonoticCharmap_keyDown(entity me, float key, float ascii, float shift)
  91 {
  92         if(SUPER(XonoticCharmap).keyDown(me, key, ascii, shift))
  93                 return 1;
  94         return me.inputBox.keyDown(me.inputBox, key, ascii, shift);
  95 }
  96
  97 void XonoticCharmap_cellSelect(entity me, vector cell)
  98 {
  99         string character = charmap_cellToChar(me, cell);
 100         if(character != "")
 101                 me.inputBox.enterText(me.inputBox, character);
 102 }
 103
 104 bool XonoticCharmap_cellIsValid(entity me, vector cell)
 105 {
 106         if(charmap_cellToChar(me, cell) == "")
 107                 return false;
 108         return true;
 109 }
 110
 111 void XonoticCharmap_cellDraw(entity me, vector cell, vector cellPos)
 112 {
 113         draw_CenterText(cellPos + me.charOffset, charmap_cellToChar(me, cell), me.realFontSize, SKINCOLOR_CHARMAP_CHAR, SKINALPHA_CHARMAP_CHAR, 0);
 114 }
 115
 116 void XonoticCharmap_focusLeave(entity me)
 117 {
 118         me.inputBox.saveCvars(me.inputBox);
 119 }
 120 #endif