Listbox / Picker: Implement item fading in a different way so that it gets influenced...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / charmap.qc
1 #ifdef INTERFACE
2 CLASS(XonoticCharmap) EXTENDS(XonoticPicker)
3         METHOD(XonoticCharmap, configureXonoticCharmap, void(entity, entity))
4         METHOD(XonoticCharmap, focusLeave, void(entity))
5         METHOD(XonoticCharmap, resizeNotify, void(entity, vector, vector, vector, vector))
6         METHOD(XonoticCharmap, keyDown, float(entity, float, float, float))
7         ATTRIB(XonoticCharmap, inputBox, entity, NULL)
8         ATTRIB(XonoticCharmap, realFontSize, vector, '0 0 0')
9
10         ATTRIB(XonoticCharmap, rows, float, 10)
11         ATTRIB(XonoticCharmap, columns, float, 14)
12
13         METHOD(XonoticCharmap, cellSelect, void(entity, vector))
14         METHOD(XonoticCharmap, cellIsValid, bool(entity, vector))
15         METHOD(XonoticCharmap, cellDraw, void(entity, vector, vector))
16         METHOD(XonoticCharmap, charOffset, vector)
17 ENDCLASS(XonoticCharmap)
18 entity makeXonoticCharmap(entity controlledInputBox);
19 #endif
20
21 #ifdef IMPLEMENTATION
22
23 string CHARMAP =
24         "★◆■▮▰▬◣◤◥◢◀▲▶▼"
25         "🌍🌎🌏🚀🌌👽🔫⌖❇❈←↑→↓"
26         "☠☣☢⚛⚡⚙🔥❌⚠⛔❰❱❲❳"
27         "😃😊😁😄😆😎😈😇😉😛😝😘❤ "
28         "😐😒😕😮😲😞😟😠😣😭😵😴  "
29         "\xEE\x83\xA1\xEE\x83\xA2\xEE\x83\xA3\xEE\x83\xA4\xEE\x83\xA5\xEE\x83\xA6\xEE\x83\xA7"
30         "\xEE\x83\xA8\xEE\x83\xA9\xEE\x83\xAA\xEE\x83\xAB\xEE\x83\xAC\xEE\x83\xAD\xEE\x83\xAE"
31         "\xEE\x83\xAF\xEE\x83\xB0\xEE\x83\xB1\xEE\x83\xB2\xEE\x83\xB3\xEE\x83\xB4\xEE\x83\xB5"
32         "\xEE\x83\xB6\xEE\x83\xB7\xEE\x83\xB8\xEE\x83\xB9\xEE\x83\xBA\xEE\x80\x90\xEE\x80\x91"
33         "\xEE\x82\xB0\xEE\x82\xB1\xEE\x82\xB2\xEE\x82\xB3\xEE\x82\xB4\xEE\x82\xB5\xEE\x82\xB6"
34         "\xEE\x82\xB7\xEE\x82\xB8\xEE\x82\xB9\xEE\x82\xA1\xEE\x82\xBF\xEE\x82\xA6\xEE\x82\xA5"
35         "\xEE\x83\x81\xEE\x83\x82\xEE\x83\x83\xEE\x83\x84\xEE\x83\x85\xEE\x83\x86\xEE\x83\x87"
36         "\xEE\x83\x88\xEE\x83\x89\xEE\x83\x8A\xEE\x83\x8B\xEE\x83\x8C\xEE\x83\x8D\xEE\x83\x8E"
37         "\xEE\x83\x8F\xEE\x83\x90\xEE\x83\x91\xEE\x83\x92\xEE\x83\x93\xEE\x83\x94\xEE\x83\x95"
38         "\xEE\x83\x96\xEE\x83\x97\xEE\x83\x98\xEE\x83\x99\xEE\x83\x9A\xEE\x81\x9B\xEE\x81\x9D";
39
40 string charmap_cellToChar(entity me, vector cell)
41 {
42         string character = substring(CHARMAP, cell.y * me.columns + cell.x, 1);
43
44         if(character != " ")
45                 return character;
46         else
47                 return "";
48 }
49
50 entity makeXonoticCharmap(entity controlledInputBox)
51 {
52         entity me;
53         me = spawnXonoticCharmap();
54         me.configureXonoticCharmap(me, controlledInputBox);
55         return me;
56 }
57
58 void XonoticCharmap_configureXonoticCharmap(entity me, entity controlledInputBox)
59 {
60         me.inputBox = controlledInputBox;
61         me.configureXonoticPicker(me);
62 }
63
64 void XonoticCharmap_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
65 {
66         SUPER(XonoticCharmap).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
67
68         float maxFontWidth = SKINFONTSIZE_NORMAL / absSize.x;
69         float maxFontHeight = SKINFONTSIZE_NORMAL / absSize.y;
70
71         if((me.realCellSize.x * absSize.x) > (me.realCellSize.y * absSize.y))
72         {
73                 me.realFontSize_x = me.realCellSize.y * absSize.y / absSize.x;
74                 me.realFontSize_y = me.realCellSize.y;
75         }
76         else
77         {
78                 me.realFontSize_x = me.realCellSize.x;
79                 me.realFontSize_y = me.realCellSize.x * absSize.x / absSize.y;
80         }
81
82         if(me.realFontSize.x > maxFontWidth || me.realFontSize.y > maxFontHeight)
83                 me.realFontSize = eX * maxFontWidth + eY * maxFontHeight;
84
85         me.charOffset = eX * me.realCellSize.x / 2 + eY * ((me.realCellSize.y - me.realFontSize.y) / 2);
86 }
87
88 float XonoticCharmap_keyDown(entity me, float key, float ascii, float shift)
89 {
90         if(SUPER(XonoticCharmap).keyDown(me, key, ascii, shift))
91                 return 1;
92         return me.inputBox.keyDown(me.inputBox, key, ascii, shift);
93 }
94
95 void XonoticCharmap_cellSelect(entity me, vector cell)
96 {
97         string character = charmap_cellToChar(me, cell);
98         if(character != "")
99                 me.inputBox.enterText(me.inputBox, character);
100 }
101
102 bool XonoticCharmap_cellIsValid(entity me, vector cell)
103 {
104         if(charmap_cellToChar(me, cell) == "")
105                 return false;
106         return true;
107 }
108
109 void XonoticCharmap_cellDraw(entity me, vector cell, vector cellPos)
110 {
111         draw_CenterText(cellPos + me.charOffset, charmap_cellToChar(me, cell), me.realFontSize, SKINCOLOR_CHARMAP_CHAR, SKINALPHA_CHARMAP_CHAR, 0);
112 }
113
114 void XonoticCharmap_focusLeave(entity me)
115 {
116         me.inputBox.saveCvars(me.inputBox);
117 }
118 #endif