qcsrc/menu/xonotic/charmap.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticCharmap) EXTENDS(Item)
   3         METHOD(XonoticCharmap, configureXonoticCharmap, void(entity, entity))
   4         METHOD(XonoticCharmap, mousePress, float(entity, vector))
   5         METHOD(XonoticCharmap, mouseRelease, float(entity, vector))
   6         METHOD(XonoticCharmap, mouseMove, float(entity, vector))
   7         METHOD(XonoticCharmap, mouseDrag, float(entity, vector))
   8         METHOD(XonoticCharmap, keyDown, float(entity, float, float, float))
   9         METHOD(XonoticCharmap, focusLeave, void(entity))
  10         METHOD(XonoticCharmap, resizeNotify, void(entity, vector, vector, vector, vector))
  11         METHOD(XonoticCharmap, draw, void(entity))
  12         ATTRIB(XonoticCharmap, focusable, float, 1)
  13
  14         METHOD(XonoticCharmap, moveFocus, void(entity, vector, vector))
  15         METHOD(XonoticCharmap, enterChar, void(entity))
  16         ATTRIB(XonoticCharmap, inputBox, entity, NULL)
  17         ATTRIB(XonoticCharmap, realFontSize, vector, '0 0 0')
  18         ATTRIB(XonoticCharmap, realCellSize, vector, '0 0 0')
  19         ATTRIB(XonoticCharmap, focusedCell, vector, '-1 -1 0')
  20         ATTRIB(XonoticCharmap, previouslyFocusedCell, vector, '-1 -1 0')
  21 ENDCLASS(XonoticCharmap)
  22 entity makeXonoticCharmap(entity controlledInputBox);
  23 #endif
  24
  25 #ifdef IMPLEMENTATION
  26
  27 const float CHARMAP_COLS = 14;
  28 const float CHARMAP_ROWS = 10;
  29
  30 string CHARMAP =
  31         "★◆■▮▰▬◣◤◥◢◀▲▶▼"
  32         "🌍🌎🌏🚀🌌👽🔫⌖❇❈←↑→↓"
  33         "☠☣☢⚛⚡⚙🔥❌⚠⛔❰❱❲❳"
  34         "😃😊😁😄😆😎😈😇😉😛😝😘❤ "
  35         "😐😒😕😮😲😞😟😠😣😭😵😴  "
  36         "\xEE\x83\xA1\xEE\x83\xA2\xEE\x83\xA3\xEE\x83\xA4\xEE\x83\xA5\xEE\x83\xA6\xEE\x83\xA7"
  37         "\xEE\x83\xA8\xEE\x83\xA9\xEE\x83\xAA\xEE\x83\xAB\xEE\x83\xAC\xEE\x83\xAD\xEE\x83\xAE"
  38         "\xEE\x83\xAF\xEE\x83\xB0\xEE\x83\xB1\xEE\x83\xB2\xEE\x83\xB3\xEE\x83\xB4\xEE\x83\xB5"
  39         "\xEE\x83\xB6\xEE\x83\xB7\xEE\x83\xB8\xEE\x83\xB9\xEE\x83\xBA\xEE\x80\x90\xEE\x80\x91"
  40         "\xEE\x82\xB0\xEE\x82\xB1\xEE\x82\xB2\xEE\x82\xB3\xEE\x82\xB4\xEE\x82\xB5\xEE\x82\xB6"
  41         "\xEE\x82\xB7\xEE\x82\xB8\xEE\x82\xB9\xEE\x82\xA1\xEE\x82\xBF\xEE\x82\xA6\xEE\x82\xA5"
  42         "\xEE\x83\x81\xEE\x83\x82\xEE\x83\x83\xEE\x83\x84\xEE\x83\x85\xEE\x83\x86\xEE\x83\x87"
  43         "\xEE\x83\x88\xEE\x83\x89\xEE\x83\x8A\xEE\x83\x8B\xEE\x83\x8C\xEE\x83\x8D\xEE\x83\x8E"
  44         "\xEE\x83\x8F\xEE\x83\x90\xEE\x83\x91\xEE\x83\x92\xEE\x83\x93\xEE\x83\x94\xEE\x83\x95"
  45         "\xEE\x83\x96\xEE\x83\x97\xEE\x83\x98\xEE\x83\x99\xEE\x83\x9A\xEE\x81\x9B\xEE\x81\x9D";
  46
  47 string charmap_cellToChar(vector cell)
  48 {
  49         string character = substring(CHARMAP, cell.y * CHARMAP_COLS + cell.x, 1);
  50
  51         if (character != " ")
  52                 return character;
  53         else
  54                 return "";
  55 }
  56
  57 entity makeXonoticCharmap(entity controlledInputBox)
  58 {
  59         entity me;
  60         me = spawnXonoticCharmap();
  61         me.configureXonoticCharmap(me, controlledInputBox);
  62         return me;
  63 }
  64
  65 void XonoticCharmap_configureXonoticCharmap(entity me, entity controlledInputBox)
  66 {
  67         me.inputBox = controlledInputBox;
  68         me.realCellSize = eX / CHARMAP_COLS + eY / CHARMAP_ROWS;
  69 }
  70
  71 void XonoticCharmap_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  72 {
  73         SUPER(XonoticCharmap).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  74
  75         float maxFontWidth = SKINFONTSIZE_NORMAL / absSize.x;
  76         float maxFontHeight = SKINFONTSIZE_NORMAL / absSize.y;
  77
  78         if((me.realCellSize.x * absSize.x) > (me.realCellSize.y * absSize.y))
  79         {
  80                 me.realFontSize_x = me.realCellSize.y * absSize.y / absSize.x;
  81                 me.realFontSize_y = me.realCellSize.y;
  82         }
  83         else
  84         {
  85                 me.realFontSize_x = me.realCellSize.x;
  86                 me.realFontSize_y = me.realCellSize.x * absSize.x / absSize.y;
  87         }
  88
  89         if(me.realFontSize.x > maxFontWidth || me.realFontSize.y > maxFontHeight)
  90                 me.realFontSize = eX * maxFontWidth + eY * maxFontHeight;
  91 }
  92
  93 float XonoticCharmap_mouseMove(entity me, vector coords)
  94 {
  95         me.focusedCell_x = floor(coords.x * CHARMAP_COLS);
  96         me.focusedCell_y = floor(coords.y * CHARMAP_ROWS);
  97
  98         if(me.focusedCell.x < 0 || me.focusedCell.y < 0 ||
  99            me.focusedCell.x >= CHARMAP_COLS || me.focusedCell.y >= CHARMAP_ROWS)
 100         {
 101                 me.focusedCell = '-1 -1 0';
 102                 return 0;
 103         }
 104
 105         return 1;
 106 }
 107
 108 float XonoticCharmap_mouseDrag(entity me, vector coords)
 109 {
 110         return me.mouseMove(me, coords);
 111 }
 112
 113 float XonoticCharmap_mousePress(entity me, vector coords)
 114 {
 115         me.mouseMove(me, coords);
 116
 117         if(me.focusedCell.x >= 0)
 118         {
 119                 me.pressed = 1;
 120                 me.previouslyFocusedCell = me.focusedCell;
 121         }
 122
 123         return 1;
 124 }
 125
 126 float XonoticCharmap_mouseRelease(entity me, vector coords)
 127 {
 128         if(!me.pressed)
 129                 return 0;
 130
 131         me.mouseMove(me, coords);
 132
 133         if(me.focusedCell == me.previouslyFocusedCell)
 134                 me.enterChar(me);
 135
 136         me.pressed = 0;
 137         return 1;
 138 }
 139
 140 float XonoticCharmap_keyDown(entity me, float key, float ascii, float shift)
 141 {
 142         switch(key)
 143         {
 144                 case K_LEFTARROW:
 145                 case K_KP_LEFTARROW:
 146                         me.moveFocus(me, me.focusedCell, '-1 0 0');
 147                         return 1;
 148                 case K_RIGHTARROW:
 149                 case K_KP_RIGHTARROW:
 150                         me.moveFocus(me, me.focusedCell, '1 0 0');
 151                         return 1;
 152                 case K_UPARROW:
 153                 case K_KP_UPARROW:
 154                         me.moveFocus(me, me.focusedCell, '0 -1 0');
 155                         return 1;
 156                 case K_DOWNARROW:
 157                 case K_KP_DOWNARROW:
 158                         me.moveFocus(me, me.focusedCell, '0 1 0');
 159                         return 1;
 160                 case K_HOME:
 161                 case K_KP_HOME:
 162                         me.focusedCell = '0 0 0';
 163                         return 1;
 164                 case K_END:
 165                 case K_KP_END:
 166                         me.focusedCell_x = CHARMAP_COLS - 1;
 167                         me.focusedCell_y = CHARMAP_ROWS - 1;
 168                         return 1;
 169                 case K_ENTER:
 170                 case K_KP_ENTER:
 171                 case K_INS:
 172                 case K_KP_INS:
 173                         me.enterChar(me);
 174                         return 1;
 175                 default:
 176                         return me.inputBox.keyDown(me.inputBox, key, ascii, shift);
 177         }
 178 }
 179
 180 void XonoticCharmap_moveFocus(entity me, vector initialCell, vector step)
 181 {
 182         me.focusedCell_x = mod(me.focusedCell.x + step.x + CHARMAP_COLS, CHARMAP_COLS);
 183         me.focusedCell_y = mod(me.focusedCell.y + step.y + CHARMAP_ROWS, CHARMAP_ROWS);
 184
 185         if(me.focusedCell != initialCell) // Recursion break
 186                 if(charmap_cellToChar(me.focusedCell) == "")
 187                         me.moveFocus(me, initialCell, step);
 188 }
 189
 190 void XonoticCharmap_enterChar(entity me)
 191 {
 192         string character = charmap_cellToChar(me.focusedCell);
 193         if(character != "")
 194                 me.inputBox.enterText(me.inputBox, character);
 195 }
 196
 197 void XonoticCharmap_focusLeave(entity me)
 198 {
 199         me.inputBox.saveCvars(me.inputBox);
 200 }
 201
 202 void XonoticCharmap_draw(entity me)
 203 {
 204         string character;
 205         vector cell, cellPos, charPos;
 206         cell = '0 0 0';
 207         cellPos = '0 0 0';
 208         charPos = '0 0 0';
 209
 210         float CHAR_OFFSET_X = me.realCellSize.x / 2;
 211         float CHAR_OFFSET_Y = (me.realCellSize.y - me.realFontSize.y) / 2;
 212
 213         for(cell_y = 0; cell.y < CHARMAP_ROWS; ++cell.y)
 214         {
 215                 charPos_y = cell.y / CHARMAP_ROWS + CHAR_OFFSET_Y;
 216                 for(cell_x = 0; cell.x < CHARMAP_COLS; ++cell.x)
 217                 {
 218                         character = charmap_cellToChar(cell);
 219
 220                         if(character == "")
 221                                 continue;
 222
 223                         // Draw focused cell
 224                         if(cell == me.focusedCell && me.focused)
 225                         {
 226                                 if(!me.pressed || me.focusedCell == me.previouslyFocusedCell)
 227                                 {
 228                                         cellPos_x = mod(me.focusedCell.x, CHARMAP_COLS) / CHARMAP_COLS;
 229                                         cellPos_y = mod(me.focusedCell.y, CHARMAP_ROWS) / CHARMAP_ROWS;
 230                                         draw_Fill(cellPos, me.realCellSize, SKINCOLOR_CHARMAP_FOCUS, SKINALPHA_CHARMAP_FOCUS);
 231                                 }
 232                         }
 233
 234                         // Draw character
 235                         charPos_x = cell.x / CHARMAP_COLS + CHAR_OFFSET_X;
 236                         draw_CenterText(charPos, character, me.realFontSize, SKINCOLOR_CHARMAP_CHAR, SKINALPHA_CHARMAP_CHAR, 0);
 237                 }
 238         }
 239 }
 240 #endif