qcsrc/menu/xonotic/colorbutton.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticColorButton) EXTENDS(RadioButton)
   3         METHOD(XonoticColorButton, configureXonoticColorButton, void(entity, float, float, float))
   4         METHOD(XonoticColorButton, setChecked, void(entity, float))
   5         METHOD(XonoticColorButton, draw, void(entity))
   6         ATTRIB(XonoticColorButton, fontSize, float, SKINFONTSIZE_NORMAL)
   7         ATTRIB(XonoticColorButton, image, string, SKINGFX_COLORBUTTON)
   8         ATTRIB(XonoticColorButton, image2, string, SKINGFX_COLORBUTTON_COLOR)
   9
  10         ATTRIB(XonoticColorButton, useDownAsChecked, float, 1)
  11
  12         ATTRIB(XonoticColorButton, cvarPart, float, 0)
  13         ATTRIB(XonoticColorButton, cvarName, string, string_null)
  14         ATTRIB(XonoticColorButton, cvarValueFloat, float, 0)
  15         METHOD(XonoticColorButton, loadCvars, void(entity))
  16         METHOD(XonoticColorButton, saveCvars, void(entity))
  17 ENDCLASS(XonoticColorButton)
  18 entity makeXonoticColorButton(float, float, float);
  19 #endif
  20
  21 #ifdef IMPLEMENTATION
  22 entity makeXonoticColorButton(float theGroup, float theColor, float theValue)
  23 {
  24         entity me;
  25         me = spawnXonoticColorButton();
  26         me.configureXonoticColorButton(me, theGroup, theColor, theValue);
  27         return me;
  28 }
  29 void XonoticColorButton_configureXonoticColorButton(entity me, float theGroup, float theColor, float theValue)
  30 {
  31         switch(theValue)
  32         {
  33                 // rearrange 1..14 for rainbow order
  34                 case  1: theValue = 10; break;
  35                 case  2: theValue =  4; break;
  36                 case  3: theValue =  1; break;
  37                 case  4: theValue = 14; break;
  38                 case  5: theValue = 12; break;
  39                 case  6: theValue =  7; break;
  40                 case  7: theValue =  3; break;
  41                 case  8: theValue =  2; break;
  42                 case  9: theValue =  6; break;
  43                 case 10: theValue =  5; break;
  44                 case 11: theValue = 13; break;
  45                 case 12: theValue = 11; break;
  46                 case 13: theValue =  8; break;
  47                 case 14: theValue =  9; break;
  48                 default:
  49                         // no change
  50                         break;
  51         }
  52         me.cvarName = "_cl_color";
  53         me.cvarValueFloat = theValue;
  54         me.cvarPart = theColor;
  55         me.loadCvars(me);
  56         me.configureRadioButton(me, string_null, me.fontSize, me.image, theGroup, 0);
  57         me.srcMulti = 1;
  58         me.src2 = me.image2;
  59 }
  60 void XonoticColorButton_setChecked(entity me, float val)
  61 {
  62         if(val != me.checked)
  63         {
  64                 me.checked = val;
  65                 me.saveCvars(me);
  66         }
  67 }
  68 void XonoticColorButton_loadCvars(entity me)
  69 {
  70         if not(me.cvarName)
  71                 return;
  72
  73         if(me.cvarPart == 1)
  74                 me.checked = (cvar(me.cvarName) & 240) == me.cvarValueFloat * 16;
  75         else
  76                 me.checked = (cvar(me.cvarName) & 15) == me.cvarValueFloat;
  77 }
  78 void XonoticColorButton_saveCvars(entity me)
  79 {
  80         if not(me.cvarName)
  81                 return;
  82
  83         if(me.checked)
  84         {
  85                 if(me.cvarPart == 1)
  86                         cvar_set(me.cvarName, ftos(cvar(me.cvarName) & 15 + me.cvarValueFloat * 16));
  87                 else
  88                         cvar_set(me.cvarName, ftos(cvar(me.cvarName) & 240 + me.cvarValueFloat));
  89         }
  90         // TODO on an apply button, read _cl_color and execute the color command for it
  91 }
  92 void XonoticColorButton_draw(entity me)
  93 {
  94         me.color2 = colormapPaletteColor(me.cvarValueFloat, me.cvarPart);
  95         SUPER(XonoticColorButton).draw(me);
  96 }
  97 #endif